[文本处理] 求助，那个大神帮忙写个统计文件数的bat

ldw1982

一个大目录下有很多文件夹，每个文件夹下有2个子文件夹，就是要统计每个文件夹下面的子文件夹里面有多少个文件数。

cmd1152

没有显示的话等一下，记得评分。

@echo off
setlocal enabledelayedexpansion
echo;
(for /l %%i in (1,1,64) do (set "Ts=!Ts!"))
set/p=!Ts! Number of documents:Wait...<nul
for /f %%i in ('dir /a-d-h/b/s *') do (set /a a+=1
set/p=!Ts! Number of documents:!a!     <nul
)
echo;
set/p=!Ts! Press any key to exit ...<nul
pause>nul
复制代码

qixiaobin0715

@echo off
setlocal enabledelayedexpansion
for /d %%a in (*) do (
    for /d %%b in (%%a\*) do (
        set n=0
        for %%c in (%%b\*) do set /a n+=1
        echo,文件夹%%b中有!n!个文件。
    )
)
pause
复制代码

qixiaobin0715

修改了一下，可以统计子文件夹和上层文件夹（2个子文件夹总计）文件数量：

@echo off
setlocal enabledelayedexpansion
for /d %%a in (*) do (
    set m=0
    for /d %%b in (%%a\*) do (
        set n=0
        for %%c in (%%b\*) do (
            set /a n+=1
            set /a m+=1
        )
        echo,%%b：!n!
    )
    echo,%%a：!m!
    echo,
)
pause
复制代码

ldw1982

回复 2# cmd1152


    先谢谢了。脚本一直 在那里不会动。

ldw1982

回复 4# qixiaobin0715


    谢谢帮助，你这个  可以看出来，就是 有的文件夹是   3级 的  帮忙在修改一下

ldw1982

回复 4# qixiaobin0715


    谢谢了  可以显示，但是有的文件是3级文件，帮忙再修改一下。

qixiaobin0715

@echo off
setlocal enabledelayedexpansion
for /d %%a in (*) do (
    pushd "%%a"
    set m=0
    for /f "delims=" %%b in ('dir /b /s /a-d') do set /a m+=1
    echo,%%a：!m!
    popd
)
pause
复制代码

cmd1152

回复 5# ldw1982


    这可能是因为文件太多，需要等一下

ldw1982

回复 8# qixiaobin0715


    好的   谢谢

ldw1982

回复 9# cmd1152


    好的 谢谢

aloha20200628

:: 屏显统计结果
dir /s D:\大目录\*.* | findstr /r /b /c:" "
:: 保存统计结果
dir /s D:\大目录\*.* | findstr /r /b /c:" " > 统计结果.txt