[文本处理] 批处理BAT如何按某字符多少排序？

yhsean

Toolpath\q\
Toolpath\q\fdf\
Toolpath\q\ewr\
Toolpath\eqwfqf\aff
Toolpath\2

有如上一文档，请问如何按照 \ 字符出现次数排序。排序后成如下：

Toolpath\q\ewr\                               \出现3次
Toolpath\eqwfqf\aff                          \出现2次
Toolpath\q\fdf\                                 \出现2次
Toolpath\q\                                      \出现2次
Toolpath\2                                       \出现1次

xxpinqz

凑合着用

@echo off&setlocal enabledelayedexpansion
%1(for /f "tokens=1*" %%a in ('%0 :^|sort /r^|more /t40')do set/am=%%a%%10000&echo,%%b!m!次)&pause&goto :eof
for /f "delims=U" %%a in ('cmd /u /c echo 唉') do set "tab=%%a"
for /f "delims=" %%a in (1.txt) do (
    set "str=%%a"&set "str=!str:\= a!"&set n=99999
    for %%b in (!str!) do set/an+=1
    echo,!n! %%a%tab%\出现
)
复制代码

yhsean

set/a n=-1

set mystr=aa\bb\vv\cc\dd\aaa\

setlocal enabledelayedexpansion 
   FOR /L %%i in (0,1,1000) do (                                                    
      if "!mystr:~%%i,1!"=="\" set/a n=!n!+1                                            
      if "!mystr:~%%i,1!"==""  echo !n!-%mystr%>>C:\dcam\before_sort && goto _endbefore_sort 
    )
endlocal
:_endbefore_sort
复制代码

谢谢，用自己的办法已经解决，没行前加上统计该字符的数字，然后用 sort/R 排序并去掉统计数字输出

CrLf

一如既往贴简单暴力的另类解...适用于行数不太多的文件，若要兼容特殊字符需改造，偷懒了：

@echo off&setlocal enabledelayedexpansion >结果.txt
(rd tmp&md tmp) >nul

set /a n=10000
for /f "delims=" %%a in (原文件.txt) do set /a n+=1&echo %%a>tmp\!n:~-4!
(for /f "delims=" %%a in ('dir /o-s /b tmp\*) do type tmp\%%a)>结果.txt

rd tmp >nul
复制代码

CrLf

这个用第三方挺爽的，兼容性和效率都没得说：

awk "{print length($0),$0}" a.txt|gnu_sort -knr|sed "s/.....//"
复制代码

length 是 ps 文本对象的自带属性，因为能 sort 所以比 shell 更方便，不过会慢一点：

get-content a.txt|sort-object length|%{$_.length," ",$_}
复制代码

CrLf

js 的文本也是对象，相比之下会长一点，好处是很容易内嵌 bat 而且兼容性极佳，速度方面应该介于 5 楼的那两个方案之间。

@set @n=0;/*
@echo off
cscript -nologo -e:javascript %0 <a.txt
pause&exit /b
*/

var str=WScript.StdIn.ReadAll().split('\n')
str.sort(function(a,b){return a.length - b.length;})
WScript.Echo(str.join('\n'))
复制代码

CrLf

vbs 略显操蛋，原本想找找有没简单的办法，最后又绕回 ado...

[原文件] = "a.txt"
[最大行长度] = 65535

Set fso = WScript.CreateObject("Scripting.Filesystemobject")
text = fso.OpenTextFile([原文件],1).ReadAll

Set rec=CreateObject("ADODB.Recordset")
rec.Fields.Append "String",200,[最大行长度]
rec.Fields.Append "Length",200,Len([最大行长度])
rec.Open
For Each str In Split(text,vbCrLf)
	rec.AddNew
	rec.Fields("String") = str
	rec.Fields("Length") = Len(str)
Next

rec.Sort = "Length ASC"

Do Until rec.EOF
	Wscript.Echo rec.Fields("String")
	rec.MoveNext
Loop
复制代码

terse

觉得应该按 字符 "\" 的多少排列  不是字符哦

apang

@set @n=0;/*
@echo off
cscript -nologo -e:javascript %0 <a.txt >b.txt
pause&exit /b
*/

var str=WScript.StdIn.ReadAll().split('\n')
str.sort(function(a,b){return b.split('\\').length-a.split('\\').length});
WScript.Echo(str.join('\n'))
复制代码

terse

发个 PS脚本

$Hash = @{}
get-content .\a.txt | ? {
   $Hash.ADD($_,$_.split("\").Count)
}
$hash.GetEnumerator()| Sort -Descending Value | select -ExpandProperty name
复制代码

CrLf

回复 8# terse


    没注意，既然这样...
    不贴另类解简直对不起党中央，简单方便妥妥的，go on：
for /l %%a in ""

@echo off
(rd tmp&md tmp) >结果.txt 2>nul
set "list=\29\28\27\26\25\24\23\22\21\20\19\18\17\16\15\14\13\12\11\10\09\08\07\06\05\04\03\02\01\00"
for /f "delims=" %%a in (原文件.txt) do (
	for /f "tokens=31 delims=\" %%b in (".%%a.%list%") do echo %%a>>tmp\%%b.txt
)
type tmp\*.txt>结果.txt 2>nul
pause
复制代码

二号另类解，快速有效：

@echo off&setlocal enabledelayedexpansion
set "原文件=原文件.txt"
set "结果=结果.txt"
set "pattern=[^\\]*"
for %%a in ("%原文件%") do set size=%%~za
(for /l %%a in (1 1 50) do (
	for %%b in ("%结果%") do if %%~zb geq %size% exit/b
	findstr "^^!pattern!$" "%原文件%"
	set "pattern=!pattern!\\[^^\\]*"
))>"%结果%"
复制代码

CrLf

回复 9# apang


    话说感觉用 match 可能会比 split 快，只是猜测，未测试

CrLf

高冷的 linux 舶来品实现起来如此简单，shell 真是文本专家（如需顺序，把  -nrk 1 换成 -nk 1）：

gawk -F"\\" "{print NF,$0}" 原文件.txt | gnu_sort.exe -nrk 1 | sed "s/[0-9] //" >结果.txt
复制代码

再来个纯 gawk 的（如需顺序，把 for(i=asort(ar);i;i--) 换成 for(i=1;i<asort(ar);i++)） ：

gawk -F "\\" "{ar[NF+100]=ar[NF+100] RS $0}END{for(i=asort(ar);i;i--) print ar[i];}" 原文件.txt
复制代码

xxpinqz

给几位大佬请安问好。。。。

terse

因10楼不能处理重复路径  再发个PS的
话说效率不怎么样

$regex = [RegEx] '\\'
$Filelist = get-content .\a.txt | % {
      New-Object PSObject -Property @{
         Name = $_
         Value = $regex.Matches($_).Count
      }
} | sort -Descending Value
$Filelist | group name|%{$_.Group}|%{$_.Name}|out-file -encoding ASCII "b.txt"
复制代码