返回列表 发帖

[文本处理] 批处理如何对比两个文本?

测试1是原文,
测试1跟测试2里面的内容对比
对比后的结果导出保存到测试结果

测试2个内容排列顺序依据测试1为准
测试1和测试2对比后按照顺序保存到“测试结果”里面

比如测试2里面的第一行的内容 在测试1里面是第三行
经过批处理处理后 导出的结果是前2行是空行 第3行是内容

相关文本我已经上传到附件中 麻烦高手帮忙写个批处理 谢谢


我是win7   64位操作系统

麻烦高手帮忙写一下  谢谢

TOP

囧,这么绕的事情为什么不用 Excel ?
『千江有水千江月』千江有水,月映千江;万里无云,万里青天。    http://yu2n.qiniudn.com/

TOP

本帖最后由 tmplinshi 于 2015-1-5 02:41 编辑
@echo off
(for /f "tokens=1,2" %%a in (测试1.txt) do (
findstr "^%%a$" 测试2.txt >nul && (
echo %%a %%b
) || (  echo;  )
)) >测试结果.txtCOPY
2

评分人数

    • pengyou86: 成功技术 + 1
    • 慕夜蓝化: 昨天,看到问题之后直接就懵了...心里想着要 ...技术 + 1

TOP

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in (测试2.txt) do set $%%i=a
for /f "tokens=1*" %%i in (测试1.txt) do (
    if defined $%%i (echo %%i %%j) else echo,
)
pauseCOPY
@echo off&setlocal enabledelayedexpansion
set n=1
for /f "tokens=1*delims=:" %%a in ('findstr /ibng:测试2.txt 测试1.txt') do (
    for /l %%i in (!n!,1,%%a) do (
        if %%a equ %%i (echo %%b)else echo,
        set /a n=%%a+1
    )
)
pauseCOPY
1

评分人数

TOP

回复 4# tmplinshi

昨天看到问题之后,直接就懵了。。。想着要用到findstr 就是不知道该怎么去写,最后连用了几个for 也没解决问题,就卡在那走不动,&&,和||也总是弄混>_<、
踏实一些点.不要着急.你想要的时间都会给你.2

TOP

tmplinshi 发表于 2015-1-5 02:17

谢谢测试成功就是运行起来速度有点慢

TOP

terse 发表于 2015-1-5 02:20



谢谢你,麻烦你再修改一下 把对比后的结果保存到“测试结果.txt”中
本人小菜  请谅解

TOP

terse 发表于 2015-1-5 02:20


测试不能使用  谢谢

TOP

tmplinshi 发表于 2015-1-5 02:17



    测试1文本内容很大有20多万行内容  批处理运行起来速度太慢。还有别的方法可以快速对比吗?

TOP

回复 9# pengyou86


    你需要举例说明什么叫做“不能使用”,否则人家没有办法继续帮助你。

TOP

回复 11# DAIC


    都快一个小时了  批处理还没有对比完毕

TOP

回复 12# pengyou86


    所以嘛,你应该先找两个小文件验证一下功能是否正常。如果是效率不够高,人家可以优化。你留下一句“不能使用”人家怎么知道你遇到了啥问题。

TOP

本帖最后由 terse 于 2015-1-5 14:14 编辑
测试不能使用  谢谢
pengyou86 发表于 2015-1-5 09:08

两个都不能使用吗
大文件个话 下面这段能否处理呢
@if(0)==(0) echo off
cscript -nologo -e:javascript %0<测试1.txt >测试结果.txt "测试2.txt"
pause&goto :eof
@end
Array.prototype.arr_ay = function(obj) {
   var i = this.length;
   while (i--) {
      if (this[i] === obj) {
        return true;
      }
   }
   return false;
}  
var arr=new ActiveXObject('Scripting.FileSystemObject').OpenTextFile(WScript.Arguments.Item(0)).readall().split('\r\n');
var re = /(\w+).*/ig;
while (!WScript.StdIn.AtEndOfStream){
    var str = WScript.StdIn.Readline();
    arr.arr_ay(str.replace(re,'$1')) ? WSH.echo(str) : WSH.echo('')
}COPY
增加个临时文件 看能否提高点效率
@echo off&setlocal enabledelayedexpansion
findstr /ibng:测试2.txt 测试1.txt>$
set n=2
(for /f "tokens=1*delims=:" %%a in ($) do (
    for /l %%i in (!n!,1,%%a) do echo,
    echo %%b
    set /a n=%%a+2
))> 测试结果.txt
del $
pauseCOPY
再给个 三方的
@gawk "ARGIND==1{a[$0]=1}ARGIND>1{if (a[$1]){print $0}else{print a[$1]}}" 测试2.txt 测试1.txt >测试结果.txtCOPY

TOP

如果只是用来检查文本有哪些不同,而不一定要输出 txt 的话,也可以使用 BeyondCompare,比较直观,用很久了,用来对比 code 妥妥的,妈妈再也不用担心我不知道改了什么地方了

TOP

返回列表