[数值计算] [已解决]批处理使用goto跳出for循环，等待慢，如何解决？

gapkiller

参考下面的代码:

 
@echo off
for /L %%i in (1,1,1000000) do (
    echo %%i
    goto end
)

:end
复制代码

上面的代码在第一次循环的时候就应该跳出来
可是从实际结果来看, 代码(goto end)却执行了挺长时间, 让我感到很困惑.
而且loop越多, 所需时间越长, 也就是与那个1000000有关系.

求解惑~~

===================================================================
看了很多人的回复, 虽然原理还不清楚, 但也差不多明白是怎么个事. 不想把这个问题挂着了.标志为[已解决]

搜索了一下论坛, 关于分解质因数的问题, 得到了改善, 效率应该很快了. 见28L

[ 本帖最后由 gapkiller 于 2010-12-31 11:31 编辑 ]

gapkiller

回复  gapkiller
poter 发表于 2012-5-17 12:55

    1不是=1吗?

poter

回复 36# gapkiller

poter

回复 36# gapkiller

兄弟，你自己执行一下吧，如果N＝1。我就没那么头痛了

gapkiller

回复  gapkiller


    兄弟你没懂我意思

如果这段代码单独输出，输入1进去，为何n的值为“1＝1”？ ...
poter 发表于 2012-5-16 21:16

n=1 啊

gapkiller

回复  gapkiller


    兄弟你没懂我意思

如果这段代码单独输出，输入1进去，为何n的值为“1＝1”？ ...
poter 发表于 2012-5-16 21:16

不是1=1吧

poter

回复 33# gapkiller


    兄弟你没懂我意思

如果这段代码单独输出，输入1进去，为何n的值为“1＝1”？？？

@echo off
set /p n=Please input a number:
set /p p=%n%=<nul
echo %n%
set n=
set p=

gapkiller

兄弟你的代码里这一句是什么意思？

set /p p=%n%=
poter 发表于 2012-5-16 19:23

不是*n*  你理解错了啊

poter

兄弟你的代码里这一句是什么意思？

set /p p=%n%=<nul

为何变量n的值最后会是*＝* ??

gapkiller

以前没注意看到这个问题，确实有点……
不过，我想大大们应该可以解释，这似乎是FOR  /L的预处理吧。
在第 ...
cjiabing 发表于 2011-4-28 14:02

    一年多之后再看到这个帖子, 有种说不出的感觉~
谢谢关注!

cjiabing

以前没注意看到这个问题，确实有点……
不过，我想大大们应该可以解释，这似乎是FOR  /L的预处理吧。
在第一个命令时没见它进行预处理，只对第一个数字进行了排序，它按照原过程进行。而在第二行它就进入对所有数字的 FOR /L 分析了，这种分析似乎不受其它命令的控制，用&无效，|也解释不了。
call可以解释，但call本身有点特殊，况且，每个call都意味着设置一个返回命令，比如goto :eof，否则，cmd就会一直挂着这个call的名字。
一直想写一篇关于中止批处理过程的文章的，可惜没空。
从楼主的代码看，楼主这样用一个for产生一个100000000位的数字，然后只取第一个数字就自动跳出（goto），显然楼主的思路也是缺乏效率的，简直是浪费。
goto 的本意是跳出、跳至，我们通常认为它是有去无回的。
而call的常用来调用、呼叫某程序，呼叫完了它遇到goto :eof时自动返回，如果没有goto :eof似乎它就一直挂在那里，除非遇到其它退出命令。
在for中，试图跳出for循环，再想跳回来，那只能用call。用goto是回不来的。而试图用goto中止进程，需要if等的判断。
在for /l中，即使没有任何多余命令，直接goto也无法阻止该命令进行预处理。在for中，我们通常这样理解，首先从集合中挑选因素处理，然后执行do后面的命令。这个过程反复进行，直到for中的内容被抽取完毕。但在for /l中，这个解释似乎站不住脚，因为for /l更像一次性从集合中抽取元素，然后才逐个去执行do后面的命令。试验如下：

@echo off
for /L %%i in (2,2,103333333333333) do goto end
echo.
echo   game over
echo.
pause
exit

:end
echo.
echo   SORRY! STOP!
echo.
pause
复制代码

然后将goto end换成pause，该命令又变回正常的for过程。看来，这个又是具体命令的区别了。cmd常把命令划成三五六等，然后给它们赋予不同的优先权。
在这里看来，只要不跳出for/l的进程，命令是不会出错的，否则for/l死活都要吃完那点草。这是从上面推理下来，唯一合理的解释。

for /L %%i in (2,2,1033333) do (
echo %%i
dir
)
复制代码

再补充一点：
是不是cmd把 for/l和call捆绑到一起了，也就是专门给call预留了空间？
只要for/l跳出进程，for/l就会进入具体的全面的预处理（前面没有进行的），然后设定一个点，以期call出去后能够找到这个回来的点。所以，我们就看到，for /l在跳出前进行了全部处理。

linqing8

我也在做质数因子分解的题目，在for中用了goto语句，数字越大的效率越低，逐条指令分析了良久，终于发现问题出在goto上，试着换成call后便好了。
这真是个奇怪的问题，百度了一下，发现bathome里的这个帖子有这个现象的深刻讨论，goto真是让人感觉莫名其妙。

gapkiller

@echo off
setlocal enabledelayedexpansion

:input
set /p input=Please input a number:
if .%input%==.0 goto exit
set /a n=input

if %n% lss 1 (
  echo Out of range!!
  goto input
)
if %n% gtr 999999999 (
  echo Out of range!!
  goto input
)
set /p p=%n%=<nul
set i=2

call:sqrt %n%

:start
::echo .%sqrtn%.&pause>nul
if %i% gtr %sqrtn% goto end
set /a t=%n%%%%i%

if .%t%==.0 (
  set /p "p=%i%"<nul
  set /a n/=%i%
  if not .!n!==.1 set /p "p=*"<nul
  call:sqrt !n!
) else (
  set /a i=%i%+1
)
goto start

:end
set /p "p=%n%"<nul
echo.
set input=
goto input

::=============runing sqrt=================================
:sqrt
set type=%1
set/a xn=type
set/a times=1
if %type% geq 99 set/a times=2
if %type% geq 9999 set/a times=3
if %type% geq 999999 set/a times=4
if %type% geq 99999999 set/a times=5

for /l %%a in (1,1,4) do (
  set/a yn=!xn!*100
  set/a zn=!yn!/100
  if not !yn! lss 0 (
    if !xn!==!zn! (
    set/a xn=!yn!
    )
  )
)

set/a sn=xn
set sqn=1
for /l %%a in (1,1,20) do (
  set/a sqn=sn/sqn+sqn
  set/a sqn=sqn/2
)

::echo.
::echo √%type% ≈ !sqn:~0,%times%!.!sqn:~%times%!
set sqrtn=!sqn:~0,%times%!
goto :eof
::=============runing sqrt=================================

:exit
复制代码

tmplinshi

只有 for /L 是这样的，所有数都要循环。而直接的 for 和 for /f 可以跳出。以下可以看出：

for /l %%a in (1 1 5) do if %%a==3 goto 1
:1
echo 1

for %%a in (1 2 3 4 5) do if %%a==3 goto 2
:2
echo 2

for /f %%a in ('"echo 1&echo 2&echo 3&echo 4&echo 5"') do (
    if %%a==3 goto 3
)
:3
echo 3
pause
复制代码

g:\我的文档\桌面>for /L %a in (1 1 5) do if %a == 3 goto 1 g:\我的文档\桌面>if 1 == 3 goto 1 g:\我的文档\桌面>if 2 == 3 goto 1 g:\我的文档\桌面>if 3 == 3 goto 1 g:\我的文档\桌面>if 4 == 3 goto 1 g:\我的文档\桌面>if 5 == 3 goto 1 g:\我的文档\桌面>echo 1 1 g:\我的文档\桌面>for %a in (1 2 3 4 5) do if %a == 3 goto 2 g:\我的文档\桌面>if 1 == 3 goto 2 g:\我的文档\桌面>if 2 == 3 goto 2 g:\我的文档\桌面>if 3 == 3 goto 2 g:\我的文档\桌面>echo 2 2 g:\我的文档\桌面>for /F %a in ('"echo 1&echo 2&echo 3&echo 4&echo 5"') do (if %a == 3 goto 3 ) g:\我的文档\桌面>(if 1 == 3 goto 3 ) g:\我的文档\桌面>(if 2 == 3 goto 3 ) g:\我的文档\桌面>(if 3 == 3 goto 3 ) g:\我的文档\桌面>echo 3 3 g:\我的文档\桌面>pause 请按任意键继续. . .

[ 本帖最后由 tmplinshi 于 2010-12-22 19:36 编辑 ]

gapkiller

可能这就是for的一个特点吧~
针对这个问题, 只好放弃for了..
使用goto写了一个~

@echo off
setlocal enabledelayedexpansion
:input
set /p n=Please input a number:
if .%n%==. goto exit
set /p p=%n%=<nul
set i=2
set /a n2=%n%/2
:start
if %i% gtr %n2% goto end
set /a t=%n%%%%i%
if .%t%==.0 (
  set /p "p=%i%"<nul
  set /a n/=%i%
  if not .!n!==.1 set /p "p=*"<nul
  set /a n2=!n!/2
) else (
  set /a i=%i%+1
)
goto start
:end
set /p "p=%n%"<nul
echo.
set n=
goto input
:exit
复制代码