【练习-034】批处理浮点计算

batman

出题目的：
　掌握批处理浮点计算的方法
加分标准：
　视情形加分，满分20分
解题限制：
　版主级的暂请观看，但可以做解题提示
题目如下：
　输入任意两个小数（小数点后最多为两位数），通过批处理输出两数的和、差、积、商
（积、商均保留两位小数）。

[ 本帖最后由 batman 于 2009-2-13 17:22 编辑 ]

LTSC1809

调用powershell运算就可以了

yhcfsr

调用powershell来做数学计算吧，纯BAT光计算就很复杂了，若还要实现其他功能，真是难以想象。
时间效率不高，胜在代码简单。

set/p "input=输入表达示：
for /f "delims=" %%a in ('powershell "%input%"') do echo %%a
pause
复制代码

taofan712

回复 20# batman

最开始我也这样想，后来觉得太多意外，需要很多if。
然后我选择先把数字放大到没有小数点再计算，计算完毕再缩小倍数。
为了追求根据输入算式直接得出答案（而不是列举加减乘除4种结果），导致代码多了一半，不然代码应该在48行左右。

@echo off&setlocal enabledelayedexpansion
title 批处理小数运算。
set /p input=输入算式(如 2.96+0.907) ：
for /f "tokens=1,2 delims=+-*/" %%a in ("%input%") do (
	set x=%%a & set y=%%b
	call set symbol=%%input:%%a=%%
	call set symbol=%%symbol:%%b=%%
)
set /p precision=自定义精度(默认为3)：
if not defined precision set precision=3
set /a xsd=1
for /l %%a in (1 1 %precision%) do set /a xsd*=10
echo;
rem echo;思路：先将数字放大%xsd%倍，得到结果再缩小%xsd%倍。
set/p=%x%  %symbol% %y% 的值为:<nul 
call :largen x %precision%
call :largen y %precision%
if "%symbol%"=="*" set expression=x*y & set /a z=!expression!/%xsd%
if "%symbol%"=="/" set expression=x/y & set /a z=!expression!*%xsd%
if "%symbol%"=="+" set expression=x+y & set /a z=!expression!
if "%symbol%"=="-" set expression=x-y & set /a z=!expression!
call :output z 
echo;
pause&exit /b

:largen              
setlocal
set bignum=!%~1!
set /a _precision=%~2 + 1
for /l %%n in (1,1,%_precision%) do set zero=!zero!0
set multiple=1%zero%
for /f "tokens=1,2 delims=. " %%a in ("%bignum%") do (
	set bignum_b=%%a&set bignum_e=%%b%zero%
)
set bignum_e=1!bignum_e:~0,%_precision%!
set /a smallnum=bignum_b*multiple+bignum_e
set /a smallnum+=5
set /a smallnum-=multiple
set smallnum=%smallnum:~0,-1%
endlocal & set %~1=%smallnum%
goto :eof
  
:lessen 
setlocal
set smallnum=!%~1!
set _precision=%~2
for /l %%n in (1,1,%_precision%) do set zero=!zero!0
set multiple=1%zero%
set /a bignum_b=smallnum/multiple
set /a bignum_e=smallnum%%multiple
set bignum_e=%zero%%bignum_e%
set bignum_e=!bignum_e:~-%_precision%!
set bignum=%bignum_b%.%bignum_e%
endlocal & set %~1=%bignum%
goto :eof

:output
call :lessen %~1 %precision%
set/p=	!z!<nul
goto :eof
复制代码

dengyuli

我发一个自己做的，是除法运算，被除数，除数都可以为小数，支持负数。
最小分度值为10^-8，可以酌情提升，不过效率会降低。
主要思路：
1、将小数化为整数，具体做法是计算被除数和除数小数部分字串的长度，若被除数的小数部分长度大于除数的小数部分的长度，则在除数的小数部分后补上0，直到除数的小数部分的长度与被除数的小数部分的长度一样，反之亦然，再去掉小数点，将被除数和除数前面的0去掉。
2、开始运算：商=被除数 整除 除数
             余数=被除数 取余 除数
             如果余数不等于0，商=商. 否则 完成
             计数器=0
             循环体
             如果余数等于0，跳出循环体
              循环嵌套，8次，循环变量为a
               如果余数比除数小，(
                       余数*=10
                       如果循环变量大于2，商=商0
                       判断结束
              循环嵌套结束
             余数与除数的商=余数 整除 除数
             余数=余数 取余 除数
             商=商余数与除数的商       ::两个字符串连接
             计数器加1
                    如果计数器大于10，跳出循环体
             循环体结束

@echo off
rem 已封装
setlocal enabledelayedexpansion
set ctr=0
set "bc=%~1"
set "c=%~2"
set f=false
if "!bc:~0,1!"=="-" if "!c:~0,1!"=="-" (
 set bc=!bc:-=!
 set c=!c:-=!
 set bc=!bc: =!
 set c=!c: =!
 set f=false
) else (
 rem nothing
)
if "!bc:~0,1!"=="-" if "!c:~0,1!" neq "-" (
 set bc=!bc:-=!
 set bc=!bc: =!
 set f=true
) else (
 rem nothing
)
if "!bc:~0,1!" neq "-" if "!c:~0,1!"=="-" (
 set c=!c:-=!
 set c=!c: =!
 set f=true
) else (
 rem nothing
)
set tbc=!bc!
set tc=!c!
set tbc=!tbc:.=!
set tc=!tc:.=!
set tbc=!tbc: =!
set tc=!tc: =!
if !"tbc!" neq "!bc!" if  "!tc!" neq "!c!" (
 for /f "delims=. tokens=1-3 eol=a" %%a in ('echo !bc!') do (
  call :len %%b
  set lenbcx=!zz!
 )
 for /f "delims=. tokens=1-3 eol=a" %%a in ('echo !c!') do (
  call :len %%b
  set lencx=!zz!
 )
) else (
 goto :r
)
if !lenbcx! gtr !lencx! (
 set /a cz=lenbcx-lencx
 for /l %%a in (1,1,!cz!) do (set c=!c!0)
 set c=!c:.=!
 set c=!c: =!
 set bc=!bc:.=!
 set bc=!bc: =!
) else (
 if !lenbcx!==!lencx! set bc=!bc:.=! & set c=!c:.=! & set bc=!bc: =! & set c=!c: =! & goto :r
 set /a cz=lencx-lenbcx
 for /l %%a in (1,1,!cz!) do (set bc=!bc!0)
 set c=!c:.=!
 set c=!c: =!
 set bc=!bc:.=!
 set bc=!bc: =!
)
:r
for /l %%a in (1,1,9) do (if "!bc:~0,1!"=="0" set bc=!bc:~1!)
for /l %%a in (1,1,9) do (if "!c:~0,1!"=="0" set c=!c:~1!)
set /a "s=bc/c"
set /a "m=bc %% c"
if !m!==0 goto :f
set s=!s!.
:main
if !m!==0 goto :f
for /l %%a in (1,1,8) do (
 if !m! lss !c! (
  set /a m=m*10
  if %%a geq 2 set s=!s!0 & set /a ctr+=1
 ) else (
 rem nothing
 )
)
set /a "ss=m/c"
set /a "m=m %% !c!"
set s=!s!!ss!
set s=!s: =!
set /a ctr+=1
if !ctr! gtr 10 goto :f
goto :main
:f
if !f!==false (
 echo !s!
) else (
 echo -!s!
)
goto :eof
:len
set "t=%1"
set zz=0
for /l %%a in (0,1,11) do (
 if "!t:~%%a,1!"=="" goto :eof
 set /a zz+=1
)
goto:eof
复制代码

Batcher

回复 30# zhengdalu


如果你觉得不支持，为何还有25楼的疑问呢？

zhengdalu

我觉得不支持，可是楼主...怎么这么问啊

Batcher

回复 28# zhengdalu


嗯，根据你试的结果，你觉得支持吗？

zhengdalu

回复 26# Batcher


    我试过，窗口只给显示整数位，小数没有啊。

guaiwu

@echo off
setlocal enabledelayedexpansion
set /p q=请输入两个小数：
for %%i in (%q%) do (
set /a a+=1
set a!a!=%%i
)
set /a a=%a1%+%a2%
set /a b=%a1%-%a2%
set /a c=%a1%*%a2%
set /a d=%a1%/%a2%
echo 两个小数的和为%a%
echo 两个小数的差为%b%
echo 两个小数相乘为%c%
echo 两个小数相除为%d%
pause
复制代码

Batcher

回复 25# zhengdalu


你自己试试就知道啦

zhengdalu

这...我新手，请问不是批处理不支持浮点吗

Hello123World

回复 5# BBCC
for /f "delims=" %%a in ('%0') do (echo %%a)
是你搞错了('%0'因为"%0")，还是有什么其他的意思——我运行后批处理就不动了。

qq506657335

商的取值不怎么准确。。
如23/36 你写的批处理的结果是0.63
但实际上是0.638888循环。。。
所以取值应该是0.64

inittab

练练手。基本思路是化小数为整数运算，得到结果后再恢复成小数。
不支持大数字运算。特别是乘法部分有待完善，需要考虑的成分的确太多了。可能有批漏之处

@echo off&setlocal enabledelayedexpansion
:begin
set /p m=输入(q退出):
if "!m!"=="q" goto :eof
set /p n=输入:
for /f "tokens=1,2 delims=." %%i in ("%m%") do set m1=%%j00&if not "%%j"=="" (set mm=%%i!m1:~0,2!) else set mm=%%i00
for /f "tokens=1,2 delims=." %%i in ("%n%") do set n1=%%j00&if not "%%j"=="" (set nn=%%i!n1:~0,2!) else set nn=%%i00

if "!mm:~0,1!"=="-" (set mm=!mm:~1!&set /a num=2!mm!-1!mm!,mm=1!mm!-num&set mm=-!mm!) else set /a num=2!mm!-1!mm!,mm=1!mm!-num
if "!nn:~0,1!"=="-" (set nn=!nn:~1!&set /a num=2!nn!-1!nn!,nn=1!nn!-num&set nn=-!nn!) else set /a num=2!nn!-1!nn!,nn=1!nn!-num

set /a add=mm+nn
call :check !add! num1
echo 两值之和是: !num1!

set /a sub=mm-nn
call :check !sub! num2 
echo 两值之差是: !num2!


set /a mul=mm*nn
if !mul! lss 100 (set num3=0.00) else (
set mul=!mul:~0,-2!
call :check !mul! num3
)
echo 其积为:!num3!

set /a div=100*mm/nn
call :check !div! num4
echo 其商为:%num4%

goto begin

:check
set var=%1&set "_="
if !var! lss 0 (set /a var=-1*var&set _=-)
if !var! lss 10 (set var=00!var!) else if !var! lss 100 set var=0!var!
if "!var:~-2!"=="00" (set var=!var:~0,-2!) else if "!var:~-1!"=="0" (set var=!var:~0,-2!.!var:~-2,1!) else set var=!var:~0,-2!.!var:~-2!
set %2=!_!!var!&goto :eof
复制代码