[原创] 批处理for命令通俗解释(2007-11-4日更新)

BatHome

作者:youxi01  转载请注明  温馨提示：如果你初次接触批处理这可以先到这里。

对所有的批处理初学者来说，for的应用是最难理解以及掌握的。本文由浅入深，为大家专门讲解for的用法，希望大家喜

欢。

首先应该明确的是,for不是一个简单的命令，它的用法比较复杂,它还可以带四个参数(/L /D /R /F),其中:/L和/F参数是

最经常用到的。当然，它本身也可以不带参数，下面我们通过具体的例子来讲解for的运用。

一、不带参数的for：
让我们先来看一个示例：

@echo off
for %%i in (1 2 3 4 5) do echo %%i
pause
复制代码

将以上代码保存为批处理文件(如何保存?)，然后运行，可以发现屏幕上显示1 2 3 4 5(每字一行)
是不是明白了一些？它的整个运行机制我们可以这样看：for不停的从括号中拿出5个“东西”来（以空格做间隔），并将这5个“东西”依次传给临时变量%%i，同时把这个变量echo出来....

从这个例子我们可以看出，for的基本用法是：
for 变量 in (目标) do 干什么?

变量常用%%i 来表示，当然也可以换成%%j；目标就是待处理的对象集合，比如这里的1 2 3 4 5；这里的干什么的内容为：批处理命令。
【相关习题：】将你的名字用for命令分三行显示出来！！！

二、带参数 /L 的for (这里的 参数/L 可以理解为 "list" 的意思，代表一个数列)
先看测试代码：

@echo off
for /l %%i in (1 1 5) do echo %%i
pause
复制代码

显示结果也为：1 2 3 4 5(每字一行)
它的意思和上面的意思差不多，但是括号中的对象却不需要 写成 1 2 3 4 5 的形式了，而是：1 1 5，因为它启用了参数 /L ，就是告诉for，这个括号里的对象是个数列，怎样的数列？就是以 1 开始，步长 为1 ，结束值为5的一个等差数列，再举个实例：

::显示 从 10 - 20 的所有偶数：
@echo off
for /l %%i in (10 2 20) do echo %%i
pause
复制代码

【相关习题：】显示 1~20 间能被5整 除的整数

三、带参数 /f 的for（这里的参数/F可以理解为“file”的意思，代码处理对象为文本串）
参考教程：for 命令 /f 参数 通俗讲解

四、for的 /D 和/R 参数（这两个参数个人比较少用）
1>/D参数（常用来查询 当前目录 或者 指定目录的文件夹)
基本用法：FOR /D %variable IN (set) DO command [command-parameters]
如：查询F盘根目录下的文件夹

@echo off
for /d %%i in (f:\*) do echo %%i
pause>nul
复制代码

如果省略 括号中的 "f:\"，则会直接查询 批处理 所在目录的文件夹
假设 本批处理文件 保存在：F:\test下
运行以下批处理代码，将会查询 F：\test下的文件夹

@echo off
for /d %%i in (*) do echo %%i
pause>nul
复制代码

2> /r参数
基本用法：FOR /R [[drive:]path] %variable IN (set) DO command [command-parameters]
检查以 [drive:]path 为根的目录树中，所有符合（set）的文件或者文件夹。如果在 /R 后没有指定目录，则使用当前
目录。如果集仅为一个单点(.)字符，则枚举该目录树。
用法示例：
枚举F：盘下所有的 文件

@echo off
for /r f:\ %%i in (*) do echo %%i
pause>nul
复制代码

枚举F：盘下所有的 .bat文件(包括子目录），则：

@echo off
for /r f:\ %%i in (*.bat) do echo %%i
pause>nul
复制代码

如果省略以上代码中的F:\，则会列举当前目录 所有符合（set）的文件
如：列举批处理所在目录的 所有 批处理文件（包括子目录）

@echo off
for /r %%i in (*.bat) do echo %%i
pause>nul
复制代码

完...

23618342

请教一下 in 后面的括号里面能否含有变量

lizixian

回复 30# a1b2dd

帮忙看一下，四则运算在for循环中无法正常执行。
@echo off
setlocal enabledelayedexpansion
set /a a ...
a1b2dd 发表于 2009-2-7 23:26

虽然我是来挖坟的,晚辈在此献丑了
括弧不对称是因为do 后边的 ( 与 !a!* 后面的(相对应 而2+1后边的) 却与！b！后面的)相对应  所以造成两个括符不对称
只需要给 需要对应的对称括号两边加双引号即可 如下

@echo off
setlocal enabledelayedexpansion
set /a a=3
for /l %%i in (1,1,2) do (
set /a " b=!a!*(!a!*2+1) "
echo,!b!
)
set /a b=!a!*(!a!*2+1)
echo !b!

unknown_world

for是我学习过程感觉最难的一部分，现在总算理清了一些

cjiabing

回复 71# sch106338


    多看，多练，多想就懂了

sch106338

有点不懂···

xpw

个人感觉计算1至20能被5整除的应该这样写：
@echo off
for /l %%i in (20 -5 1) do echo %%i
pause
毕竟条件是1至20这20个数，与(5 5 20)只是结果一样，但条件不一样

haiping518

好东西。值得学习。。。。

xiaopo

回复 65# HAT


    真不好意思，当前目录无文件夹，粗心大意了。

Batcher

回复 61# ggehuliang


试试这个：
http://www.bathome.net/thread-2189-1-1.html
http://www.bathome.net/thread-2336-1-1.html

HAT

回复 62# yinzzi


都行
逗号是可选的命令分隔符之一

HAT

回复 64# xiaopo


在代码所在的目录下新建几个文件夹，再试试。

xiaopo

@echo off
for /d %%i in (*) do echo %%i
pause>nul
复制代码

此处代码在我这儿不显示任何内容，怎么回事呢？winxp pro sp3

yinzzi

@echo off
for /l %%i in (5 5 20) do echo %%i
pause

看来真的要多练才行了，有一些空格还是没有注意到。。不过不知道为什么在括号里面为什么要用上逗号。不加逗号不是也一样可以吗？

ggehuliang

复杂？？？看不懂啊！