批处理获取当前目录名

foxJL

如本批处理所在的当前目录是:"C:\Documents and Settings\All Users"
要求只显示当前目录名:All Users

梦想种子

@echo off
call :get "%cd%"
pause>nul
exit
:get
echo %~n1
复制代码

[ 本帖最后由 梦想种子 于 2008-3-29 20:55 编辑 ]

foxJL

参考二楼兄弟的思路:

@echo off
for %%i in ("%cd%") do echo %%~ni
pause
复制代码

笨方法:

@echo off
set a=%cd: =:%
set a=%a:\= %
for %%j in (%a%) do (set a=%%j)
set a=%a::= %
echo %a%
pause
复制代码

youxi01

呵呵，笨办法还有

@echo off 
set "path=C:\Documents and Settings\All Users"
for /l %%i in (1 1 10) do call set "path=%%path:*\=%%"
echo %path%
pause>nul
复制代码

youxi01

@echo off 
set "path=C:\Documents and Settings\All Users"
set "path=%path: =#%"
set "path=%path:\= %"
for %%i in (%path%) do set "path=%%i"
echo %path:#= %
pause>nul
复制代码

随风

这么热闹，我也来一个
:

@echo off
call :loop "c:\1334 \459sdf fdh8\40958345\aaa.bbb.ccc"
echo %a%
pause&exit
:loop
for /f "tokens=1* delims=\" %%a in ("%~1") do (
  set a=%%a
  if not "%%b"=="" call :loop "%%b"
)
goto :eof
复制代码

youxi01

注：以下“函数”并不完善，请勿随便套用！

@echo off  & setlocal enabledelayedexpansion
set "path=C:\Documents and Settings\All Users"
call :GetTheStr "%path%"
echo %res%
pause>nul

:GetTheStr str
set "var=%~1"
if not "%var:~-1%"=="\" (
   set path=%var:~0,-1%
   set res=%var:~-1%%res%
   call :GetTheStr "!path!"
)
复制代码

youxi01

呵呵，搞的跟 随风兄的机理一样了！

不过比你的还“傻”，哈哈

foxJL

呵呵,好热闹啊.

fastslz

补充2楼不足之处

@echo off
call :get "%cd%.tmp"
pause&exit
:get
echo %~n1
复制代码

梦想种子

噢，对...否则遇到名字类似“bathome.files”的文件夹时就会错误输出。

a5417871

学习学习中。嘿

zqz0012005

回复 4楼 的帖子
path是系统环境变量，不要随便用它作为一般变量名哦，小心无意中惹出麻烦来而难以检测（当然只是影响这个bat，不会改变系统设置）


回复 10楼 的帖子
无需%cd%.tmp，下面可以直接用echo %~nx1

keen

@echo off
set "a=%cd%"
:loop
set "v=%a:~0,1%"
if "%v%"=="\" set /a n+=1
set a=%a:~1%
if "%a%"=="" goto xianshi
goto loop
:xianshi
set /a n+=1
for /f "tokens=%n% delims=\" %%i in ("%cd%") do echo %%i&pause>nul
复制代码

lxb1117

C:\1\2\3\
for %%i in (.) do @echo %%~ni
pause
取3

for %%i in (..) do @echo %%~ni
pause
取2