[数值计算] 本人感觉批处理冒泡排序法比sort效率高

applba

这个代码是昨天晚上捣鼓出来的，感觉效果还不错……

1000个排序也是瞬间，10000个开始卡了，估计是查询变量耗时严重了

@echo off
setlocal enabledelayedexpansion
rem 默认产生100个随机数
set n=100
for /l %%i in (1,1,!n!) do set /a _%%i=!random!+1
rem 开始排序并输出结果
for /l %%i in (1,1,!n!) do (
        for /l %%j in (%%i+1,1,!n!) do (
                if !_%%i! gtr !_%%j! (
                        set var=!_%%i!
                        set _%%i=!_%%j!
                        set _%%j=!var!
                )        
        )
echo !_%%i!
)
pause
复制代码

Batcher

感觉有时候可能不靠谱哦，为何不做个试验来对比一下呢？

applba

2# Batcher


真的不靠谱呀。

看来还是自带命令效率高。

但是sort排序需要统一数字位数……………………

terse

这样用 %%i+1 ?

applba

有问题了，编辑中

CrLf

可以是可以，但是没有算术效果啊...昨天看到这个用法时激动万分，以为是新大陆，结果一测试才发现(1+5,1,5)和(1,1,5)结果一样

applba

汗，+1确实失效了。

不过这对结果没有影响，效率上就差了点。

正常的比较次数是n(n-1)/2，而这样后成了n(n+1)/2。

batman

跟风：

@echo off&setlocal enabledelayedexpansion
for /l %%a in (1,1,500) do set "str=!str! !random!"
for %%a in (%str%) do (
    if defined .!_%%a! (
       for %%b in (.!_%%a!) do set "%%b=!%%b! %%a"
       ) else (
       for %%b in (%str%) do if %%a geq %%b set /a _%%a+=1
       set ".!_%%a!=%%a"
    )
)
for /l %%a in (1,1,500) do set "var=!var! !.%%a!"
echo !var!
pause>nul
复制代码

batman

再来个效率高的：

@echo off&setlocal enabledelayedexpansion
for /l %%a in (1,1,500) do set "str=!str! !random!"
for %%a in (%str%) do (
    set /a n+=1
    set "str=0000000000%%a"&set "str=!str:~-10!"
    set "_!str!_!n!=%%a"
)
for /f "tokens=2 delims==" %%a in ('set _') do set "var=!var! %%a"
echo !var!
pause>nul
复制代码

batman

这个不通用：

@echo off&setlocal enabledelayedexpansion
for /l %%a in (1,1,500) do set "str=!str! !random!"
for %%a in (%str%) do (
    for %%b in (min max) do (
        if not defined %%b (
           set /a %%b=%%a
           ) else (
           if %%b equ min if %%a lss !min! set /a min=%%a
           if %%b equ max if %%a gtr !max! set /a max=%%a
        )
    )
    if not defined _%%a (
       set "_%%a=%%a"
       ) else (
       set "_%%a=!_%%a! %%a"
    )
)
for /l %%a in (%min%,1,%max%) do (
    for %%b in (!_%%a!) do set "var=!var! %%a"
)
echo !var!
pause>nul
复制代码

wc726842270

9# batman
老大的set /a n+=1这步实在没看出来用意
如果去掉的话好像也可以，以下是改篇老大的

@echo off&setlocal enabledelayedexpansion
for /l %%a in (1,1,100) do set "str=!str! !random!"
for %%a in (%str%) do (
    set a=00000%%a&&set _!a:~-5!=%%a
)
for /f "tokens=1* delims==" %%i in ('set _') do echo %%j
pause>nul
复制代码

batman

11# wc726842270
你试下当str中有数值重复的情况看。。。

wc726842270

哦，这点倒是没想，呵呵，明白了

applba

set a=00000%%a&&set _!a:~-5!=%%a

你写5个0我明白了，超级版主的10个0一下子把我蒙了……

感情这set也是个不错的东西，居然还能这样用，你们真是太油菜了……

terse

老东西翻出来

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1,1,500) do set var=!var! !random!
set "var=!var! "
for /l %%i in (1,1,500) do (
    for %%j in (!var!) do (
        if defined str (   
           if !str! gtr %%j (
              set str=%%j&set d=%%j
           ) else if !str! equ %%j set "d=!d! %%j"
        ) else set str=%%j&set d=%%j
    )
    for %%j in (!str!) do set "var= !var: %%j = ! "
    set var=!var:  = !
    set var1=!var1! !d!&set str=
)
echo!var1!
pause
复制代码