【已解决】求批处理提取姓名和身份证号码 酬劳80

jixingshuo

格式是TXT   内容是下面这样的
姓名：王二狗
证件号：1100110011001100Xx
地址：某某某某
手机：13666666666
邮箱：66666@21cn.com

想提取为
1100110011001100Xx王二狗

jixingshuo

回复 11# Batcher

行

Batcher

回复 9# jixingshuo


请到微信群给大家发红吧：
http://bbs.bathome.net/thread-3473-1-1.html

zaqmlp

@echo off
set "outfile=xxx.log"
type nul>"%outfile%"
for /f "delims=" %%a in ('dir /a-d/b *.txt') do (
    for /f "tokens=1* delims=:：" %%b in ('type "%%a"^|findstr /i "姓名 证件号"') do (
        if "%%b" equ "姓名" (
            set "name=%%c"
            setlocal enabledelayedexpansion
        ) else (
            >>"%outfile%" echo;%%c!name!
            endlocal
        )
    )
)
pause
exit
复制代码

jixingshuo

回复 8# Batcher


    厉害了我的哥！ 给你转哪里？

Batcher

回复 5# jixingshuo


再次假设是一个txt里面有多段内容需要【批量提取】

@echo off
setlocal enabledelayedexpansion
type nul >"结果.log"
for /f "tokens=1-2 delims=：" %%i in ('type "1.txt"') do (
    if "%%i" equ "姓名" (
        set "Name=%%j"
    ) else if "%%i" equ "证件号" (
        set "ID=%%j"
        >>"结果.log" echo,!ID!!Name!
    )
)
复制代码

Batcher

回复 5# jixingshuo


假设你有多个txt文件

@echo off
setlocal enabledelayedexpansion
type nul >"结果.log"
for /f "delims=" %%a in ('dir /b /a-d *.txt') do (
    echo 正在处理文件 %%a
    for /f "tokens=1-2 delims=：" %%i in ('type "%%a"') do (
        if "%%i" equ "姓名" (
            set "Name=%%j"
        ) else if "%%i" equ "证件号" (
            set "ID=%%j"
        )
    )
    >>"结果.log" echo,!ID!!Name!
)
复制代码

jixingshuo

回复 4# wujunkai


    要批量提取 然后生成新文件

jixingshuo

回复 3# Batcher


    不行要批量提取 然后生成新文件

wujunkai

回复 2# jixingshuo

@echo off
set "file=a.txt"

for /F "tokens=1,2" %%i in ('findstr "姓名" "%file%"') do set "name=%%j"
for /F "tokens=1,2" %%i in ('findstr "证件号" "%file%"') do set "id=%%j"

echo %id%%name%
pause
复制代码

Batcher

回复 1# jixingshuo


test.bat

@echo off
for /f "tokens=1-2 delims=：" %%i in ('type "1.txt"') do (
    if "%%i" equ "姓名" (
        set "Name=%%j"
    ) else if "%%i" equ "证件号" (
        set "ID=%%j"
    )
)
echo %ID%Name%
pause
复制代码

jixingshuo

谢谢八楼的大哥