[文本处理] 求助一个修改文件夹名称的批处理，求大佬帮忙

blueskyforme

1. 遍历当前路径下的所有目录

2. 对于每个目录，截取子目录文件名 (名称格式为[XXXXXXX] YYYY.MM.DD XXXXX) 中符号‘]’（后面有一个空格）后面的日期，格式为比如2021.01.05

3. 定义一个变量，赋值上面的日期，但格式为 YYYYMMDD，比如20210105

4. 重命名这个目录，加上前缀 20210105_<原目录名>

5. 处理下一个目录，直到重命名完所有当前路径下的目录

Batcher

回复 1# blueskyforme


    请给出几个真实的目录名称，随意举的例子可能会导致代码无法处理你真实的文件夹。

qixiaobin0715

我猜你所说的“子目录文件名”应当是“子文件夹名”，每个目录下只有一个子文件夹。

@echo off
for /f "delims=" %%a in ('dir /b /ad') do (
    for /f "tokens=2-4 delims=. " %%i in ('dir /b /ad "%%a"') do ren "%%a" "%%i%%j%%k_%%a"
)
pause
复制代码

blueskyforme

回复 2# Batcher


    比如在当前路径下，有多三个文件夹:  <AAA>, <BBB>, <CCC>
    在这三个文件夹中各有一个子目录，比如 <AAA>的子目录名称叫<[子目录A] 2020.12.01 VOL.001 AAA>
                                                        <BBB>的子目录名称叫<[子目录B] 2020.12.02 VOL.001 BBB>
                                                        <CCC>的子目录名称叫<[子目录C] 2020.12.03 VOL.001 CCC>


   我想有个批处理程序，能够把三个文件夹:  <AAA>, <BBB>, <CCC> 分别命名成 <20201201_AAA>, <20201202_BBB>, <20201203_CCC>

   当然，前面可以加个判断，是否有子目录，或者是否有这个日期格式就更好。

qixiaobin0715

加个判断，是否有日期格式：

@echo off
for /f "delims=" %%a in ('dir /b /ad') do (
    for /f "tokens=2-4 delims=. " %%i in ('dir /b /ad "%%a"^|findstr /r "[0-9][0-9][0-9][0-9]\.[0-9][0-9]\.[0-9][0-9]"') do (
ren "%%a" "%%i%%j%%k_%%a"
)
)
pause
复制代码

blueskyforme

回复 5# qixiaobin0715


    谢谢兄弟，我试着运行了一下。问题是，可能是for循环的问题，文件名修改后，日期重复了三次。。。，修改的目录变成了<20210105_20210105_20210105_AAA>

   这个可以麻烦帮忙调整下么？另外是不是判断是不是有子目录，可以用if exist? 但我不知道语法该怎么写。。。

qixiaobin0715

回复 6# blueskyforme
是不是在AAA文件夹下有3个子文件夹啊，我这测试没问题。要不是运行了3次。

Batcher

回复 6# blueskyforme

@echo off
for /d %%a in (*) do (
    call :ExecRen "%%a"
)
goto :eof

:ExecRen
for /f "tokens=2-4 delims=. " %%i in ('dir /b /ad "%~1"^|findstr /r "[0-9][0-9][0-9][0-9]\.[0-9][0-9]\.[0-9][0-9]"') do (
    ren "%~1" "%%i%%j%%k_%~1"
    goto :eof
)
复制代码

代码保存为 test.bat
不要用 ren.bat 等跟代码内命令重复的文件名

qixiaobin0715

回复 6# blueskyforme
3楼5楼均修改了第2行代码。for /d一直搞不懂运行机制，换成for /f试试

lifei259

回复 9# qixiaobin0715


   for /d %%a in (*) do (和for /f " delims=" %%a in ('dir/b/ad') do (
是一样的作用

qixiaobin0715

回复 10# lifei259
绝大部分情况下一样，本人遇到过不同的情况，修改文件夹名（特别是与子文件夹有关系的情形）和创建文件夹时就不一样，可惜当时未深究。for /d:比如改名后又会当做新文件夹搜索循环一次。

qixiaobin0715

回复 8# Batcher
老大，论坛里介绍dir的教程没大看见，感觉挺复杂的，好多细节不是太清楚。

Batcher

回复 11# qixiaobin0715


你说的可能是类似for命令教程第8页的问题吧
http://bbs.bathome.net/thread-31727-1-1.html

Batcher

回复 12# qixiaobin0715


我觉得 dir 命令用到比较多的参数是 /b /s /a /o /t
会找个机会总结一下常见的例子

qixiaobin0715

回复 14# Batcher
还有/l，以小写字母显示？