[文件操作] 求助！以数字命名的文件批量重命名，新名字用老名字做加减法得来

luoye2010

文件名都是数字，如何做个批处理把所有的数字都统一加10或者减10作为新名字，比如原来的100变成110，原来的150变成160，谢谢各位大神

xczxczxcz

转成数字则可以数学运算了。

netdzb

回复 2# xczxczxcz

读入的变量是%%i怎么转数字?

wujunkai

回复 3# netdzb

set /A name=%%~ni+10
rename %%i !name!%%~xi
复制代码

netdzb

回复 1# luoye2010


for /f %%i in (*.png) do (
set /A name=%%~ni+10
rename %%i !name!%%~xi
)

大概是这样的，你再改改。

luoye2010

各位大神能不能给个成品 小弟零基础不会改   上面两位兄台给的都试了 不行 文件名没有变动

netdzb

回复 4# wujunkai

发个用awk方法的脚本，这个感觉可以用awk来做。

went

ANSI保存,加减操作修改第6行,dir是png文件夹

@echo off
REM png文件所在文件夹
set "dir=G:\test"
for /f "delims=" %%i in ('dir /b "%dir%\*.png"') do (
	REM 加10
	set /a "newName=%%~ni+10"
	REM 重命名
	call echo %%i -- %%newName%%%%~xi
	call rename "%dir%\%%i" "%%newName%%%%~xi"
	echo ---------------------------------------
)
pause&exit
复制代码

luoye2010

楼上大神正解  已经弄好了 谢谢大神出手 感激之心无以言表 感谢 感谢

zaqmlp

+由大到小
-由小到大

netdzb

回复 9# luoye2010

我漏掉了delims,我手机发的，没有测试，汗。

netdzb

回复 6# luoye2010

不好意思，由于是手机，漏一个delims
耽误你时间了。

WHY

需先排序再重命名。
假设同时存在 120.png 和 130.png，如果不排序，120.png 重命名为 130.png 肯定失败。

@echo off & setlocal enabledelayedexpansion
if "%~1" EQU "ARG" (
    for /f %%i in ( 'dir /b *.png ^| findstr /i /b /e "[1-9][0-9]*\.png 0\.png"') do (
        set "s=0000000000%%~ni"
        set /a n=%%~ni+10
        echo;!s:~-10! %%i !n!
    )
) else (
    for /f "tokens=2,3" %%i in ('"%~f0" ARG ^| sort /r') do ren "%%i" %%j%%~xi"
    pause & exit
)
复制代码

netdzb

回复 13# WHY

这个改成awk就不用排序了。

WHY

回复 14# netdzb


    是谁告诉你 awk 或 gawk 不需要排序的？