[文本处理] [已解决]求助批处理查找多音字替换对应拼音及拼音缩写的方法

thp2008

DuoYinZi.txt
藏，zang，Z
.......

BirdNamePYSX.txt内容示例如下：
花尾榛鸡，Hua Wei Zhen Ji ，HWZJ
黑琴鸡，Hei Qin Ji ，HQJ
雪鹑，Xue Chun ，XC
黄喉雉鹑，Huang Hou Zhi Chun ，HHZC
藏雪鸡，Cang Xue Ji ，CXJ
石鸡，Shi Ji ，SJ
大石鸡，Da Shi Ji ，DSJ
斑翅山鹑，Ban Chi Shan Chun ，BCSC
高原山鹑，Gao Yuan Shan Chun ，GYSC
.......

要求根据DuoYinZi.txt中的内容格式，将BirdNamePYSX.txt里，对应汉字的位置，对应拼音和拼音缩写进行替换。

如上例替换后，应该为：
藏雪鸡，Zang Xue Ji ，ZXJ

替换后，生成一个新文本文件保存即可。
主要是要确定汉字的位置，拼音的对应位置，缩写的字母的位置，才能进行对应替换，不知道怎么处理。
还请高手指导一下。

感谢！

idwma

#@&cls&powershell "type '%~0'|out-string|iex"&pause&exit

$1='BirdNamePYSX.txt'
$2='DuoYinZi.txt'

$f=@'
$b=$_ -split '，'
$c=$b[1]-split ' '
0..($b[0].length-1)|%{$h[$b[0][$_]]=$c[$_]}
'@

$a=gc $1
$h=@{}
$a|%{
    iex $f
    $arr+=,$b[0]
}

gc $2|%{iex $f}

$arr|%{
    $a=$_
    $b=$c=''
    $d=@()
    0..($a.length-1)|%{
	$b+=$a[$_]
	$c+=([string]$h[$a[$_]][0]).toupper()
        $e=$h[$a[$_]]
	$d+=,($e.substring(0,1).toupper()+$e.substring(1))
    }
'{0}，{2}，{1}' -f $b,$c,($d -join ' ').trim()
}
复制代码

thp2008

感谢idwma的帮助，我测试了一下，报错信息如下，很长，我截取了一段
iex : 所在位置 行:2 字符: 18
+ $c=$b[1]-split ' '
+                  ~
字符串缺少终止符: '。
所在位置 行:2 字符: 18
+ $c=$b[1]-split ' '
+                  ~
表达式或语句中包含意外的标记“'
0..($b[0].length-1)|%{$h[$b[0][$_]]=$c[$_]}”。
所在位置 D:\Birds\test.ps1:15 字符: 5
+     iex $f
+     ~~~~~~
    + CategoryInfo          : ParserError: ( [Invoke-Expression], ParseException
    + FullyQualifiedErrorId : TerminatorExpectedAtEndOfString,Microsoft.PowerShell.Commands.InvokeExpressionCommand

无法对 Null 数组进行索引。
所在位置 D:\Birds\test.ps1:16 字符: 5
+     $arr+=,$b[0]
+     ~~~~~~~~~~~~
    + CategoryInfo          : InvalidOperation: (:) []，RuntimeException
    + FullyQualifiedErrorId : NullArray

iex : 所在位置 行:2 字符: 18
+ $c=$b[1]-split ' '
+                  ~
字符串缺少终止符: '。
所在位置 行:2 字符: 18
+ $c=$b[1]-split ' '
+                  ~
表达式或语句中包含意外的标记“'
0..($b[0].length-1)|%{$h[$b[0][$_]]=$c[$_]}”。
所在位置 D:\Birds\test.ps1:15 字符: 5
+     iex $f
+     ~~~~~~
    + CategoryInfo          : ParserError: (:) [Invoke-Expression], ParseException
    + FullyQualifiedErrorId : TerminatorExpectedAtEndOfString,Microsoft.PowerShell.Commands.InvokeExpressionCommand

无法对 Null 数组进行索引。
所在位置 D:\Birds\test.ps1:16 字符: 5
+     $arr+=,$b[0]
+     ~~~~~~~~~~~~
    + CategoryInfo          : InvalidOperation: (:) []，RuntimeException
    + FullyQualifiedErrorId : NullArray

77七

@echo off
rem 批处理和文本全部保存为utf-8编码格式
chcp 65001 >nul
cd /d "%~dp0"
setlocal enabledelayedexpansion
for /f "useback tokens=1-3 delims=，" %%a in ("DuoYinZi.txt") do (
	set b0=%%b
	set b1=!b0:~0,1!
	for %%x in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
		set b1=!b1:%%x=%%x!
	)
	set _%%a=!b1!!b0:~1!
)
set n=-1
(for /f "useback tokens=1-3 delims=，" %%a in ("BirdNamePYSX.txt") do (
	set a=%%a
	setlocal
	for %%x in (%%b) do (
		set /a n+=1
		set #!n!=%%x
	)
	for /l %%l in (0,1,!n!) do (
		set t=!a:~%%l,1!
		if defined _!t! (
			call set u=%%_!t!%%
		) else (
			set u=!#%%l!
		)
		set c=!c!!u:~0,1!
		set "b=!b!!u! "
	)
	echo !a!，!b!，!c!
	endlocal
))>BirdNamePYSX_2.txt
endlocal
pause
复制代码

877

回复 4# 77七


    大佬，求助~执行下面代码后想继续执行后面的命令，goto应该怎样改呢？

rem 第二步
set "OutputName=output.mp4"
for %%i in (*.wav) do (
    set "InputWav=%%i"
)
for %%i in (*.mp4) do (
    set "InputMp4=%%i"
)

for /f "tokens=2-5 delims=:., " %%a in ('ffmpeg.exe -i "%InputWav%" 2^>^&1 ^| find "Duration:"') do (
    call :Time2SS %%a %%b %%c %%d
)
set "SecondWav=%CS%"
for /f "tokens=2-5 delims=:., " %%a in ('ffmpeg.exe -i "%InputMp4%" 2^>^&1 ^| find "Duration:"') do (
    call :Time2SS %%a %%b %%c %%d
)
set "SecondMp4=%CS%"

set "VideoFactor=%SecondWav%/%SecondMp4%"
set "AudioFactor=%SecondMp4%/%SecondWav%"

ffmpeg.exe -i "%InputMp4%" -vf "setpts=%VideoFactor%*PTS" -af "atempo=%AudioFactor%" "%OutputName%"
goto :eof

:Time2SS
set /a HH=1%1-100,MM=1%2-100,SS=1%3-100
set "CS=(%HH%*3600+%MM%*60+%3.%4)"
goto :eof

想执行第三步
复制代码

thp2008

77七 发表于 2023-10-24 08:29

测试基本可以。非常感谢！高手。

1、只是两点小问题，因为文本文件里，有些汉字较生僻，用ANSI保存，这部分汉字就会乱码，只能用UTF-8保存才不会乱码.
2、就是拼音缩写部分，我原来拼音缩写部分全是大写字母，替换后，全部变成了小写字母。拼音部分小写没关系。

77七

回复 6# thp2008


   已在4楼修改。

thp2008

回复  thp2008


   已在4楼修改。
77七 发表于 2023-10-24 10:37

感谢！我测试了一下，1、UTF-8编码，没有问题了。
2、大写的问题，输出变成了这样显示  藏雪鸡，Zang xue ji ，Zxj  正确应该是 ： 藏雪鸡，zang xue ji ，ZXJ 其它的缩写还是小写。而且其它没有被替换的拼音缩写也全部变成了小写。或者你能不能在替换完成后，将最后的所有拼音缩写转换为大写，就可以了。

77七

回复 8# thp2008


  

@echo off
rem 批处理和文本全部保存为utf-8编码格式
chcp 65001 >nul
cd /d "%~dp0"
for /f "useback tokens=1-3 delims=，" %%a in ("DuoYinZi.txt") do (
	set _%%a=%%b
)
set n=-1
(for /f "useback tokens=1-3 delims=，" %%a in ("BirdNamePYSX.txt") do (
	set a=%%a
	setlocal enabledelayedexpansion
	for %%x in (%%b) do (
		set /a n+=1
		set #!n!=%%x
	)
	for /l %%l in (0,1,!n!) do (
		set t=!a:~%%l,1!
		if defined _!t! (
			call set u=%%_!t!%%
		) else (
			set u=!#%%l!
		)
		set c=!c!!u:~0,1!
		set "b=!b!!u! "
	)
	for %%x in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
		set c=!c:%%x=%%x!
	)
	echo !a!，!b!，!c!
	endlocal
))>BirdNamePYSX_2.txt
endlocal
pause
复制代码

qixiaobin0715

要是拼音之间没有空格该如何解决呢？

buyiyang

回复 10# qixiaobin0715
我简单写了一个进行拼音分词的批处理，由于是最大匹配，有时会有问题

@echo off
set /p input=请输入拼音:
set "input=%input: =%"
if "%input%"=="" (echo,输入为空&exit)
call :dict
setlocal enabledelayedexpansion
call :split "!%input:~0,1%!"
echo,%result%
pause

:split
if /i "%~1"=="" goto :eof
set "qstring=%~1"
for /l %%a in (5,-1,0) do if not "!input:~%%a,1!"=="" (
    set /a in=%%a+1
    call set "py=%%input:~0,!in!%%"
    goto :next
)
:next
if /i "!qstring:%py% =!"=="%qstring%" (
    set "py=%py:~0,-1%"
    goto :next) else (
    set "result=!result! %py%"
    set "input=!input:%py%=!"
    if "!input!"=="" goto :eof
    call :split "%%!input:~0,1!%%"
    )
goto :eof


:dict
set "a=a ai an ang ao "
set "b=ba bai ban bang bao bei ben beng bi bian biao bie bin bing bo bu "
set "c=ca cai can cang cao ce ceng cha chai chan chang chao che chen cheng chi chong chou chu chuai chuan chuang chui chun chuo ci cong cou cu cuan cui cun cuo "
set "d=da dai dan dang dao de deng di dian diao die ding diu dong dou du duan dui dun duo "
set "e=e en er "
set "f=fa fan fang fei fen feng fo fou fu "
set "g=ga gai gan gang gao ge gei gen geng gong gou gu gua guai guan guang gui gun guo "
set "h=ha hai han hang hao he hei hen heng hong hou hu hua huai huan huang hui hun huo "
set "j=ji jia jian jiang jiao jie jin jing jiong jiu ju juan jue jun "
set "k=ka kai kan kang kao ke ken keng kong kou ku kua kuai kuan kuang kui kun kuo "
set "l=la lai lan lang lao le lei leng li lia lian liang liao lie lin ling liu long lou lu lv luan lue lun luo "
set "m=ma mai man mang mao me mei men meng mi mian miao mie min ming miu mo mou mu "
set "n=na nai nan nang nao ne nei nen neng ni nian niang niao nie nin ning niu nong nu nv nuan nue nuo "
set "o=o ou "
set "p=pa pai pan pang pao pei pen peng pi pian piao pie pin ping po pu "
set "q=qi qia qian qiang qiao qie qin qing qiong qiu qu quan que qun "
set "r=ran rang rao re ren reng ri rong rou ru ruan rui run ruo "
set "s=sa sai san sang sao se sen seng sha shai shan shang shao she shen sheng shi shou shu shua shuai shuan shuang shui shun shuo si song sou su suan sui sun suo "
set "t=ta tai tan tang tao te teng ti tian tiao tie ting tong tou tu tuan tui tun tuo "
set "w=wa wai wan wang wei wen weng wo wu "
set "x=xi xia xian xiang xiao xie xin xing xiong xiu xu xuan xue xun "
set "y=ya yan yang yao ye yi yin ying yo yong you yu yuan yue yun "
set "z=za zai zan zang zao ze zei zen zeng zha zhai zhan zhang zhao zhe zhen zheng zhi zhong zhou zhu zhua zhuai zhuan zhuang zhui zhun zhuo zi zong zou zu zuan zui zun zuo "
复制代码

。

qixiaobin0715

回复 11# buyiyang
是的，不过绝大部分没有问题。

qixiaobin0715

如果按照77七的办法，应当也能解决，思路如下：
1.汉字数可用第三列拼音缩写获取。示范如下

setlocal enabledelayedexpansion
set str=HWGS
set letters=A B C D ... Z
for %%i in (!letters!) do set str=!str:%%i=%%i !
for %%i in (!str!) do set /a n+=1
复制代码

2.获得第x个汉字是多音字后，可以找出第二列第x个大写字母来确定需要替换的拼音，进行替换。
3.也可以提前找出哪些行存在多音字，只对这些行进行替换，其它行原样显示即可，可以提高效率。