[游戏娱乐] 宗(Zung)氏抑郁/焦虑自评---心情不好来评评

foxJL

宗(Zung)氏抑郁自评

@echo off
setlocal enabledelayedexpansion
title 宗(Zung)氏抑郁自评量 code  by foxJL
color 37
echo,Zung氏抑郁自评量表(SDS)由美国的Zung编制于1965年，因使用简便，应用颇广，是目前精神医学界最常用的抑郁自测量表之一。读者应根据过去一周内自身的情况作答。
echo,
for %%i in (
1.我觉得闷闷不乐，情绪低沉
2.我觉得一天中早晨最好
3.我一阵阵哭出来或觉得想哭
4.我晚上睡眠不好
5.我吃得跟平常一样多
6.我与异性密切接触时和以往一样感到愉快
7.我发觉我的体重在下降
8.我有便秘的苦恼
9.我心跳比平常快
10.我无缘无故地感到疲乏
11.我的头脑跟平常一样清楚
12.我觉得经常做的事情并没有困难
13.我觉得不安而平静不下来
14.我对将来抱有希望
15.我比平常容易生气激动
16.我觉得做出决定是容易的
17.我觉得自己是个有用的人，有人需要我
18.我的生活过得很有意思
19.我认为如果我死了，别人会生活得好些
20.平常感兴趣的事我仍然照样感兴趣
) do (echo,&echo,%%i&echo,
  echo,1.没有    2.有时    3.经常    4.总是
  set/a n+=1
  echo,&set "sin="
  set/p sin=输入答案[1\2\3\4]:
  if "!sin!" equ "" goto QUIT
  if !sin! equ 0 goto QUIT
  if !sin! geq 5 goto QUIT
  set "flag="
  for %%j in (1 3 4 7 8 9 10 13 15 19) do (if !n! equ %%j set flag=1)
  if defined flag (set /a amount+=!sin!) else (set /a amount=amount+5-!sin!)
  for /l %%a in (1,1,80) do (set/p=_<nul)
)
set/a amount=!amount!*125
echo,&echo,你的最后得分:[!amount:~0,-2!.!amount:~-2!]分
echo,&echo,注意:最后得分在50分以下为正常，50-59分为轻度抑郁，60-69分为中度抑郁，70分以上为重度抑郁。
echo,&echo,该量表仅仅用于抑郁症的自评提示，并不能作为诊断依据。如果自测分数较高，不一定就患上了抑郁症，可前往专业医生处咨询。
pause>nul&exit
:quit
echo,答案错误,按任意键退出.&pause>nul&exit
复制代码

宗(Zung)氏焦虑自评

@echo off
setlocal enabledelayedexpansion
title 宗(Zung)氏焦虑自评量 code  by foxJL
color 37
echo,测试简介：“焦虑自评量表分析系统”是根据Zung于1971年编制的“焦虑自评量表（Self—Rating Anxiety Scale，SAS）改编而成。该系统集心理学、精神病学、多元统计学、人工智能、计算机网络技术于一体。准确-迅速地反映伴有焦虑倾向的被试的主观感受。为临床心理咨询、诊断、治疗以及病理心理机制的研究提供科学依据。本测验应用范围颇广，适用于各种职业、文化阶层及年龄段的正常人或各类精神病人。包括青少年病人、老年病人和神经症病人。
echo,
for %%i in (
1.我觉得平常容易紧张和着急
2.我无缘无故地感到害怕
3.我容易心里烦乱或觉得惊恐
4.我觉得我可能将要发疯
5.我觉得一切都很好
6.我手脚发抖打颤
7.我因为头痛、头颈痛和背痛而苦恼
8.我感觉容易衰弱和疲乏
9.我觉得心平气和，并且容易安静坐着
10.我觉得心跳得很快
11.我因为一阵阵头晕而苦恼
12.我有晕倒发作或觉得要晕倒似的
13.我吸气呼气都感到很容易
14.我手脚麻木和刺痛
15.我因为胃痛和消化不良而苦恼
16.我常常要小便
17.我的手常常是潮湿的
18.我脸红发热
19.我容易入睡并且一夜睡得很好
20.我作恶梦
) do (echo,&echo,%%i&echo,
  echo,1.无或很少有   2.有时有   3.大部分时间有   4.绝大多数时间有
  set/a n+=1
  echo,&set "sin="
  set/p sin=输入答案[1\2\3\4]:
  if "!sin!" equ "" goto QUIT
  if !sin! equ 0 goto QUIT
  if !sin! geq 5 goto QUIT
  set "flag="
  for %%j in (5 9 13 19) do (if !n! equ %%j set flag=1)
  if defined flag (set /a amount=amount+5-!sin!) else (set /a amount+=!sin!)
  for /l %%a in (1,1,80) do (set/p=_<nul)
)
echo,&echo,你的最后得分:[!amount!]分
echo,&echo,注意:20以下分完全镇定,20-35分适度焦虑,35-40分中度焦虑,40-80分严重焦虑。
echo,&echo,该量表仅仅用于焦虑症的自评提示，并不能作为诊断依据。如果自测分数较高，不一定就患上了焦虑症，可前往专业医生处咨询。
pause>nul&exit
:quit
echo,答案错误,按任意键退出.&pause>nul&exit
复制代码

plp626

50分，40分，看来我中度焦虑