[文件操作] 【已解决】批处理AB文件夹俩相比较，多出则存放C文件夹

zhengzhenhui

目前这个代码，希望改进一下，显示是语法错误，未能复制文件。。
就是--A文件比B文件多出来则复制到C,

@echo off
rem 批处理保存为ansi编码格式
set f1=A文件
set f2=B文件
set f3=A比B文件多的会存放到C文件

for /f "tokens=1-2* delims=	 " %%a in ('robocopy "%f1%" "%f2%" /e /xc /xn /xo /l /x /fp ^|findstr /rb /c:"	 *新文件" /c:"	 *新目录"') do (
	echo 新文件\目录 [%%c]
	set file=%%c
	setlocal enabledelayedexpansion
	for /f "delims=" %%x in ("!file:%f1%=%f3%!") do (
		endlocal
		if exist "%%c\" (
			md "%%x" 2>nul
		) else (
			md "%%~dpx" 2>nul
			copy "%%c" "%%x"
		)
	)
)
pause
复制代码

zhengzhenhui

是这样吗

for /f "tokens=1*" %%a in ('robocopy "%路径1%" "%路径2%" /e /xc /xn /xo /l /x /fp /NS /NJH /NJS ^| findstr /rb /c:"[	 ]*新文件" /c:"[	 ]*新目录"') do (
     set file=%%b
     setlocal enabledelayedexpansion
     call set "file2=%%file:!路径1!=!路径3!%%"
     for /f "tokens=*" %%f in ("!file2!") do (
          endlocal
          XCOPY "%%b" /Y /H /R "%%~dpf"
    )
)
复制代码

回复 17# terse

terse

回复 16# zhengzhenhui

set f1=A文件
set f2=B文件
set f3=A比B文件多的会存放到C文件

zhengzhenhui

回复 15# terse


    A-B-C三个文件夹路径该如何填写进去。。

terse

如果特殊字符处理后，改用xcopy可行不

for /f "tokens=1*" %%a in ('robocopy "%f1%" "%f2%" /e /xc /xn /xo /l /x /fp /NS /NJH /NJS ^| findstr /rb /c:"[	 ]*新文件" /c:"[	 ]*新目录"') do (
     set file=%%b
     setlocal enabledelayedexpansion
     call set "file2=%%file:!f1!=!f3!%%"
     for /f "tokens=*" %%f in ("!file2!") do (
          endlocal
          XCOPY "%%b" /Y /H /R "%%~dpf"
    )
)
复制代码

zhengzhenhui

回复 13# 77七


不好意思找到原因了，是特殊字符引起的识别错误导致的文件缺失，，我规范一下文件夹名字
文件夹为（2024-3月21日）就识别不到文件夹的

77七

@echo off
rem 批处理保存为ansi编码格式
set f1=d:\1
set f2=d:\2
set f3=d:\3

robocopy "%f1%." "%f2%." /e /xc /xn /xo /l /x /fp |findstr /rb /c:"	 *新文件" /c:"	 *新目录" >#.txt
pause
复制代码

执行这段代码，看看漏掉的文件是否在 #.txt 中出现，及该文件完整路径是否含有特殊符号

zhengzhenhui

回复 10# 77七


    已测试，我这边是30G的文件，AB比较后存入C文件夹，会出现运行结束后部分文件漏掉的情况
比如--A文件是30G   B文件拿空文件夹测试   C文件只有28G
（A文件是作为增量对比B，然后存入C的，这段代码B其实是不动的）

zhengzhenhui

回复 10# 77七


    奇怪了，，，应该是我代码粘贴错了 ，晚上我用大文件跑一下代码看看

77七

回复 9# zhengzhenhui


   8楼代码点 copy 按钮复制，代码中已经固定打印 [盘符:]，不应该会出现 [m后跟空格的

zhengzhenhui

回复 8# 77七


   
还是提示文件名  目录卷标语法不正确，漏掉一些文件了

77七

当时测试的时候用的小文件，没有考虑到文件大小单位，修改如下：

@echo off
rem 批处理保存为ansi编码格式
set f1=d:\1
set f2=d:\2
set f3=d:\3

set "_f1=%f1:~0,1%"
for /f "tokens=1* delims=:" %%a in ('robocopy "%f1%." "%f2%." /e /xc /xn /xo /l /x /fp ^|findstr /rb /c:"	 *新文件" /c:"	 *新目录"') do (
	echo 新文件\目录 [%_f1%:%%b]
	set "file=%_f1%:%%b"
	setlocal enabledelayedexpansion
	for /f "delims=" %%x in ("!file:%f1%=%f3%!") do (
		endlocal
		if exist "%_f1%:%%b\" (
			md "%%x" 2>nul
		) else (
			md "%%~dpx" 2>nul
			copy "%_f1%:%%b" "%%x"
		)
	)
)
pause
复制代码

wanghan519

回复 6# Batcher


    多谢指出，大意了
是要增量备份，类似rsync从a复制到c对比b忽略已经存在于b里的文件对吗

rsync -av --ignore-existing --compare-dest=../b --dry-run a/ c
复制代码

Batcher

回复 3# wanghan519


在楼主的这个需求里面，使用Windows的findstr或Linux的grep差别不大，他遇到的难点不是比较两个文本内容，而是文件夹的比较。

hnfeng

回复 4# Batcher


    哦，明白，谢谢指正