[游戏娱乐] 批处理无聊之作：弹珠

随风

无聊之作２、弹珠

• @echo off&setlocal enabledelayedexpansion
  
• mode con: cols=81 lines=30&color 1f
  
• :: code by 随风@bbs.bathome.net 2008/01/03
  
• :loop
  
• for /l %%a in (1 1 40) do (
  
•   if defined sang (
  
•   cls&set /a di-=1
  
•   for /l %%i in (1 1 !di!) do echo.
  
• ) else (echo.&set /a di+=1)
  
•   if defined zuo (set ko=!ko:~1!) else set ko=　!ko!
  
•   set /p=!ko!●<nul
  
•   for /l %%i in (1 1 80) do ver>nul
  
•   set /p=  <nul
  
•   if not "!ko:~38,1!"=="" set zuo=ok
  
•   if "!ko!"=="" set zuo=&set "ko=　"
  
•   if !di! lss 0 set sang=&goto loop
  
•   if !di! geq 29 set sang=ok&goto loop
  
• )
  

     随风 发表于：  2008-07-16  01:07

youxi01

效果非常不错,狂加分!哈哈

不过,这里提点建议,有关版权说明的:
::   作者：随风　出至：bbs.bathome.net    2008/01/03
可不可以统一都弄成这样呢?
:: code by 随风@bbs.bathome.net 2008/01/03

Frank

呀,效果相当好..  强.

wuditom100

好玩啊!!!太强了

coffechicken

好东西...下下来学习..

骚鸡

非常不错~！牛啊，可以不可以教教我啊？
斑竹。。。

batman

与随风的区别在于，我的不是固定轨迹：

@echo off&mode con cols=60 lines=20
setlocal enabledelayedexpansion
title 调皮的汉字-zw19750516
set code=23456789abcdef我是调皮的汉字&set "b= "
set code1=%code:~14%&set d=-1
:begin
set n=0&set m=0&set x=+
set /a lm=%random%%%59,lr=%random%%%2,c=%random%%%14,d+=1
if %d% equ 7 set d=0
set a=!code1:~%d%,1!&set c=!code:~%c%,1!
color 0%c%
if %lm% equ 0 (
   set z=+
   ) else (
   if %lm% equ 57 (
      set z=-
      ) else (
      if %lr% equ 0 (
         set z=-
         ) else (
         set z=+
)))
:contin
cls&for /l %%i in (1,1,%n%) do echo.
set "kong="
set /a n%x%=1,lm%z%=1,m+=1
if %n% equ 0 if %m% geq 100 goto begin
if %lm% equ 0 set z=+
if %lm% equ 57 set z=-
for /l %%i in (1,1,%lm%) do set kong=!kong!%b%
set str=%kong%%a%
if %n% equ 20 set x=-&goto contin
if %n% equ 0 set x=+&goto contin
echo %str%&ping /n 127.1>nul
goto contin
复制代码

foxJL

随风兄的也不是固定轨迹呵~!

骚鸡

斑竹~你的这个调皮的文字可以不可以让文字运动的速度变快点啊？
可以的话告诉我一下方法好吗？（半天才跳完一个字```）

碧海蓝天

真好玩，漂亮极了！楼主真厉害！

cbw1982

啥也不说了，真的很佩服

523066680

来参与啦。

@echo off &setlocal enabledelayedexpansion
color 17 &mode con cols=60 lines=30
for /l %%a in (1,1,60) do (set space= !space!)
set /a La=14,Lb=28,Ca=29,Cb=56,r=1,r2=2
:loop
 if %La% lss 28 (set /a La+=r2,line=La) else (set /a Lb-=r2,line=Lb)
 if %Lb% leq 1 (set /a La=-1,Lb=29,r=%random%%%3+2,r2=r%%2+1)
 
 if %Ca% lss 55 (set /a Ca+=r,col=Ca) else (set /a Cb-=r,col=Cb)
 if %Cb% leq 4 (set /a Ca=0,Cb=56,r=%random%%%3+1)
    cls
    for /l %%a in (1,1,%line%) do echo,
    echo,!space:~0,%col%!●
    ping -n 1 127.1>nul
goto :loop
复制代码

keen

回复1楼
请问随风斑竹,下面这句
if defined zuo (set ko=!ko:~1!) else set ko=　!ko!
中的ko=   !ko!等号后面的是空格吗?一个空格还是两个,还是TAB?我觉得怎么都不是,但又不知是什么
请赐教!

netbenton

来个“珠联璧合”，“群珠乱舞”，多个珠同时弹跳。。。

 
@echo off&setlocal enabledelayedexpansion
mode con: cols=81 lines=30&color 1f
for /l %%i in (1 1 39) do set "spa=  !spa!"
::在这个变量定义弹珠个数
set curs=a1 a2 a3 a4 a5 a6 a7
::随机定位
for %%a in (%curs%) do (
 set /a %%as=1,%%ah=1
 set /a %%av=!random!%%40*2,%%ai=!random!%%30
)
:loop
(
for %%a in (%curs%) do (
 set/a %%ai+=%%as,%%av+=%%ah,#v=%%av+2
 for /f "tokens=1,2,3" %%b in ("!%%av! !#v! ec!%%ai!") do (
  if defined %%d (set ec!%%ai!=!%%d:~,%%b!●!%%d:~%%c!) else (set ec!%%ai!=!spa:~,%%b!●!spa:~%%c!)
 )
)
cls&for /l %%i in (0 1 28) do echo;!ec%%i!
set/p=!ec29!<nul
for %%a in (%curs%) do (
  set ec!%%ai!=
  if !%%av! geq 78 set %%ah=-2
  if !%%av! leq 0 set %%ah=2
  if !%%ai! leq 0 set %%as=1
  if !%%ai! geq 29 set %%as=-1
)
for /l %%i in (1 1 120) do ver>nul
goto :loop
)
复制代码

[ 本帖最后由 netbenton 于 2009-6-1 22:49 编辑 ]

Batcher

用UltraEdit之类的十六进制编辑器打开看看，在查一下ASCII码对照表就知道了。