[文本处理] 求助改进循环将一个文本的每一行重复指定次数后按每隔指定行数插入到另一个文本

q4911

我有一个bat，但是处理时间太长了，如何让这个bat处理速度变快

@echo off&setlocal enabledelayedexpansion
set/p file=拖入需要修改的文件并回车：
set/p src=拖入需要增加的文件并回车：
set/p count=输入每隔多少行插入：
set/p blank=输入插入多少行：
for /f "delims=" %%i in ('type %src%')do set/ai+=1&set "#!i!=%%i"
(for /f "usebackq delims=" %%a in (%file%) do (
  echo,%%a
  set/a n+=1,m=n%%count
  if !m! equ 0 set/aj+=1&for /l %%b in (1 1 %blank%)do for %%i in (!j!)do echo,!#%%i!
  if !j! equ !i! set j=0
))>new.txt
start new.txt
复制代码

这个bat数据处理速度太慢了，请教一下大神怎么样才能变成快速？

BAT1

文件有多大？搞个样本试试.

q4911

这个是插入数据
这个是源文件
都是随便写的，测试用

q4911

回复 2# BAT1


看楼上。。

q4911

求帮忙。

gawk

回复 3# q4911


    真实的“原文件.txt”和“插入数据.txt”分别有多大？使用顶楼的代码处理需要多长时间？

q4911

回复 6# gawk


   真实原文件大概是10~20MB，插入数据大概是几十KB。
  因为上传文件不能提交超过一定MB的文件，只要把源文件的内容随便一直往下复制到一定大小就可以测试了。插入数据也可以随便写。
  之前我的处理时间至少要十分钟吧。

gawk

回复 7# q4911


    传到百度网盘吧

xxpinqz

纯批来处理这么大文件，不死机算好了。。。

q4911

回复 8# gawk


测试的文本我上传到百度网盘了 http://pan.baidu.com/s/1eQ90DPK

CrLf

这么大的变量表，读写起来非常慢的
尤其是你的代码中以 # 开头的一大坨变量在变量表中太靠前，严重影响 j、n 等高频变量的引用耗时，简单的办法是把 # 改成 x、y、z 之类比较靠后的变量，并在引用之后立即把没用的变量删除，就会快多了

@echo off&setlocal enabledelayedexpansion
set/p file=拖入需要修改的文件并回车：
set/p src=拖入需要增加的文件并回车：
set/p count=输入每隔多少行插入：
set/p blank=输入插入多少行：

for /f "delims=" %%i in ('type %src%')do set/ai+=1&set "z!i!=%%i"

set "n=%count%"

(for /f "usebackq delims=" %%a in ("%file:"=%") do (
  echo,%%a
  set/a n-=1

  if !n! leq 0 (
    for %%i in (!j!)do set "str=!#%%i!"&set "#%%i="
    for /l %%b in (1 1 %blank%)do echo !str!
    set "n=%count%"
  )

))>new.txt

start new.txt
复制代码

q4911

回复 11# CrLf


  如何通过  gawk 或者 sed 来加速处理bat呢？

CrLf

这样可能更好，避开大坨变量：

@echo off&setlocal enabledelayedexpansion
set/p file=拖入需要修改的文件并回车：
set/p src=拖入需要增加的文件并回车：
set/p count=输入每隔多少行插入：
set/p blank=输入插入多少行：

set "n=%count%"

(for /f "usebackq delims=" %%a in ("%file:"=%") do (
  echo,%%a
  set/a n-=1

  if !n! leq 0 (
    set "str="
    set /p "str="
    for /l %%b in (1 1 %blank%)do echo !str!
    set "n=%count%"
  )
))>new.txt <%src%

start new.txt
复制代码

CrLf

实测13楼方案隔2行插入2次耗时如下：

start at 16:43:49.16
end at 16:47:12.32
复制代码

合计约3分半钟

同样设置下，顶楼方案的日志：

start at 16:50:16.46
复制代码

截至发此帖时（17:35）仍在运行...

提升后的效率应该达到楼主的要求吧

q4911

回复 14# CrLf


    确实快了 很多 谢谢大神