Zhanggli

太赞了，我试了好几次循环都没成功，底子还是太弱了，再次感谢

qixiaobin0715

回复 21# Zhanggli
已修改

77七

回复 16# Zhanggli


  

@echo off
for /f "delims=" %%i in ('dir /b /a-d *.txt') do (
	call :1 "%%i"
)
pause & exit

	:1
	setlocal
	for /f "tokens=1* delims=:" %%a in ('findstr /nxr /c:"M05" /c:"T2" "%~1"') do (
		if not defined s (
			set s=%%a
		) else (
			set e=%%a
		)
	)
	(for /f "tokens=1* delims=:" %%a in ('findstr /n .* "%~1"') do (
		if %%a lss %s% (
			echo=%%b
		) else if %%a equ %e% (
			echo=%%b
			echo=M55
		) else if %%a gtr %e% (
			echo=%%b
		)
	))>$
	move /y $ "%~1"
	endlocal
	exit /b
复制代码

Zhanggli

不过如果是多个文件同样处理的话需要引入临时文件变量temp吧？

Zhanggli

我之前的思路也是和前面的定义了两个字符串变量来处理反倒没搞好

Zhanggli

感谢qixiaobin，真的很简洁明了，再次感谢

qixiaobin0715

@echo off
for /f "delims=" %%x in ('dir /b /a-d *.txt') do (
    set n=0
    (for /f "delims=" %%i in ('type "%%x"') do (
        if "%%i"=="T2" set n=
        if defined n echo,%%i
        if "%%i"=="M05" (
            set n=0
            echo,%%i
            echo,M55
        )
    ))>"New-%%x"
)
pause
复制代码

hfxiang

回复 15# Zhanggli
可用第3方工具sed（ http://bcn.bathome.net/tool/4.9/sed.exe ）

sed -e"/T2/,/M05/{/M05/!d;s/M05/M05\nM55/;}" 1.txt>2.txt
复制代码

Zhanggli

现在需要删除的是T2-M05之间的代码，包括T2行，但是不包括M05，不同文件这两者之间的代码会有不同行数，另外在M05后面加一个指令M55，多个文件需要同样处理，我总是循环不起来。

Zhanggli

T1
G00 Y48.62 F7500
G01 X9.8 F5000
G00 Y52.17 F7500
G01 X-15 F5000
G00 Y201.0 F7500
G01 X23.2 F3000
G01 X-15 F3000
G00 Y239.62 F7500
G01 X9.8 F5000
G00 Y243.17 F7500
G01 X-15 F5000
T2
G00 X-15 Y241.4 F7500
G01 X25 F5000
G01 X-15 F5000
G00 Y50.4 F7500
G01 X25.0 F5000
G01 X-15 F5000
M05
M30

Zhanggli

请教：我也是需要删除某一段代码，有点不同的是只是删除str1至str2之间代码包括str1，而str2不删除，多个文件需要处理

lovekix

回复 11# 77七






https://im.ge/i/9D1sha

无法打开    （15行的）
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* "appxmanifest.xml"') do
加了两行命令   解决了

@echo off
xcopy "C:\Windows\SystemApps\MicrosoftWindows.Client.CBS_cw5n1h2txyewy\appxmanifest.xml" "%cd%\" /k /c /q /r /y
rem http://bbs.bathome.net/redirect.php?goto=findpost&ptid=12042&pid=76476
set "str1=		<Application Id="WindowsBackup" Executable="WindowsBackupClient.exe" EntryPoint="WindowsBackup.App" uap10:TrustLevel="mediumIL" uap10:RuntimeBehavior="windowsApp">"
set "str2=		</Application>"
rem setlocal enabledelayedexpansion
set "str1=%str1:"="""%"
for /f "tokens=1 delims=:" %%a in ('findstr /nxr /c:"%str1%" "C:\Windows\SystemApps\MicrosoftWindows.Client.CBS_cw5n1h2txyewy\appxmanifest.xml"') do set start=%%a
for /f "tokens=1 delims=:" %%a in ('findstr /nxr /c:"%str2%" "C:\Windows\SystemApps\MicrosoftWindows.Client.CBS_cw5n1h2txyewy\appxmanifest.xml"') do (
	if %%a gtr %start% (
		set end=%%a
		goto :next
	)
)
:next
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* "appxmanifest.xml"') do (
	set "str=%%b"
	setlocal enabledelayedexpansion
	if %%a lss %start% echo=!str!
	if %%a gtr %end% echo=!str!
	endlocal
))>"C:\Windows\SystemApps\MicrosoftWindows.Client.CBS_cw5n1h2txyewy\appxmanifest.xml"
endlocal
del "appxmanifest.xml"
pause
复制代码

lovekix

回复 11# 77七

谢谢
    刀工完美

@echo off
rem http://bbs.bathome.net/redirect.php?goto=findpost&ptid=12042&pid=76476
set "str1=		<Application Id="WindowsBackup" Executable="WindowsBackupClient.exe" EntryPoint="WindowsBackup.App" uap10:TrustLevel="mediumIL" uap10:RuntimeBehavior="windowsApp">"
set "str2=		</Application>"
rem setlocal enabledelayedexpansion
set "str1=%str1:"="""%"
for /f "tokens=1 delims=:" %%a in ('findstr /nxr /c:"%str1%" "appxmanifest.xml"') do set start=%%a
for /f "tokens=1 delims=:" %%a in ('findstr /nxr /c:"%str2%" "appxmanifest.xml"') do (
	if %%a gtr %start% (
		set end=%%a
		goto :next
	)
)
:next
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* "appxmanifest.xml"') do (
	set "str=%%b"
	setlocal enabledelayedexpansion
	if %%a lss %start% echo=!str!
	if %%a gtr %end% echo=!str!
	endlocal
))>"appxmanifest-2.xml"
endlocal
pause
复制代码

77七

回复 10# lovekix


  

@echo off
rem http://bbs.bathome.net/redirect.php?goto=findpost&ptid=12042&pid=76476
set "str1=		<Application Id="WindowsBackup" Executable="WindowsBackupClient.exe" EntryPoint="WindowsBackup.App" uap10:TrustLevel="mediumIL" uap10:RuntimeBehavior="windowsApp">"
set "str2=		</Application>"
rem setlocal enabledelayedexpansion
set "str1=%str1:"="""%"
for /f "tokens=1 delims=:" %%a in ('findstr /nxr /c:"%str1%" "appxmanifest.xml"') do set start=%%a
for /f "tokens=1 delims=:" %%a in ('findstr /nxr /c:"%str2%" "appxmanifest.xml"') do (
	if %%a gtr %start% (
		set end=%%a
		goto :next
	)
)
:next
(for /f "tokens=1* delims=:" %%a in ('findstr /n .* "appxmanifest.xml"') do (
	set "str=%%b"
	setlocal enabledelayedexpansion
	if %%a lss %start% echo=!str!
	if %%a gtr %end% echo=!str!
	endlocal
))>"appxmanifest-2.xml"
endlocal
pause
复制代码

lovekix

回复 9# 77七


   

！丢了