飛雪

回复 15# pcl_test


感謝版主回覆

好像只能判斷第一個 DISK 是 GPT，第二個 DISK 就會判斷成 MBR 了...

pcl_test

回复 16# 飛雪

6楼94、95行改为

Call TxtFile(sLogFile, 1, 0, sText)
  If InStrRev(sText, "*", -1, 1)>0 Then IsGPT = "GPT"
复制代码

如果还不行，把temp临时文件夹里的diskpart.log上传附件看看

飛雪

回复 17# pcl_test


還是不行， %TMP% 底下的 log 只有一行

  Disk 0    Online           60 GB      0 B

飛雪

反覆運行後

我發現 disk 2 有時可以正常判斷為 GPT，但大多數都是判斷成 MBR


所以應該是 log 部分的寫入有問題

pcl_test

回复 19# 飛雪
vbs

Set ws = CreateObject("Wscript.Shell")
Set fso = CreateObject("Scripting.FileSystemObject")

If LCase(Right(WSH.FullName, 11)) = "wscript.exe" Then
    ws.run "cscript.exe -nologo """ & WSH.ScriptFullName & """", 0
    WSH.Quit
End If

Dim arr()
Set oExec = ws.Exec("cmd /c ""(echo;list disk|diskpart)|findstr /irc:""[0-9][0-9]*  *[tgmk]b"" "" ")

Do While oExec.StdOut.AtEndOfStream <> true
    str = Trim(oExec.StdOut.ReadLine)
    num = CInt(Split(str, " ")(1))
    ReDim Preserve arr(num)
    If InStrRev(str, "*") >0 Then
        arr(num) = "GPT"
    Else
        arr(num) = "MBR"
    End If
Loop

Dim objWMI, colDisks
Set objWMI = GetObject("winmgmts:\\.\root\cimv2")
Set colDisks = objWMI.ExecQuery("select * from Win32_DiskDrive where MediaType like 'fixed%'")
For Each objDisk in colDisks
    s = s & "硬盘" & objDisk.Index & ":" & vbTab
    s = s & "大小:" & GetSize(objDisk.Size) & vbTab
    s = s & "型号:" & objDisk.Caption & vbTab
    s = s & "分区表:" & arr(CInt(objDisk.Index)) & vbCrLf
    strDiskID = Replace(objDisk.DeviceID, "\", "\\")
    Set colPartitions = objWMI.ExecQuery _
        ("ASSOCIATORS OF {Win32_DiskDrive.DeviceID=""" & strDiskID & """}" _
        & " where AssocClass=Win32_DiskDriveToDiskPartition")
    For Each objPartition in colPartitions
      strPartId = objPartition.DeviceID
      Set colLogicalDisks = objWMI.ExecQuery _
          ("ASSOCIATORS OF {Win32_DiskPartition.DeviceID=""" & strPartId & """}  where AssocClass=Win32_LogicalDiskToPartition")
      For Each objLogicalDisk in colLogicalDisks
        size = objLogicalDisk.Size
        free = objLogicalDisk.Freespace
        used = FormatNumber((size - free) / size * 100, 2, true) & "%"
        s = s & "分区" & objLogicalDisk.DeviceID & vbTab
        s = s & "大小:" & GetSize(size) & vbTab
        s = s & "剩余:" & GetSize(free) & vbTab
        s = s & "使用率:" & used & vbCrLf
      Next
    Next
    s = s & vbCrLf
Next
Msgbox s


Function GetSize(intSize)
  If intSize/1024/1024 > 1024 Then
    GetSize = FormatNumber(intSize/1024/1024/1024, 2, true) & "GB"
  Else
    GetSize = FormatNumber(intSize/1024/1024, 2, true) & "MB"
  End If
End Function
复制代码

飛雪

回复 20# pcl_test


非常感謝，很完滿的正確顯示 MBR 跟 GPT 了

但是我使用批處理 cscript //Nologo 調用 vbs，變成彈窗了

有辦法直接在批處理中顯示嗎?

謝謝

飛雪

已解決

將 Msgbox s mark 掉
下面加一行 WScript.Echo s 就可以了

謝謝版主