[文本处理] 【已解决】如何批量将文件名插入到文本第1行和第2行之间？

wzf1024

有很多txt文本，文件名不同，如何批处理把文件名插入成为第2行，其他内容后退，
比如有文本名为hello.txt，内容是：
1111111111111
2222222222222
3333333333333
……
操作后实现：
1111111111111
hello
2222222222222
3333333333333
……
哪位大侠帮忙菜鸟，谢谢

happy886rr

回复 1# wzf1024

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%A in ('dir /a-d /b /s *.txt') do (
	(for /f "tokens=1* delims=:" %%a in ('type "%%A"^|findstr /n .*') do (
		if %%a equ 2 (echo,%%~nA)
		echo,%%b
	))>"%%A.bak"
	del "%%A"
	ren "%%A.bak" "%%~nxA"
)
set /p =执行完毕!
复制代码

pcl_test

@echo off
::取决more的限制
for /f "delims=" %%a in ('dir /a-d /b *.txt') do (
    (
      set/pa=
      setlocal enabledelayedexpansion
      echo;!a!
      endlocal
      echo;%%~na
      more +1
    )<"%%a">$
    move $ "%%a"
)
pause
复制代码

pcl_test

回复 2# happy886rr


要是首字符为:呢

CrLf

回复 3# pcl_test


    不需要用 more +1 吧，因为 set /p 已经取走一行了，另外，建议把 set /p a= 放到 setlocal 之后，否则应事先 set "a="

wzf1024

happy886rr大虾的处理的确会把行首的：删除，但容易扩展成把文件名插入任意行间；
pcl_test大虾的处理考虑周到，但只能把文件名插入1行和2行间，似乎扩展不了（可能我菜，不懂扩展）。
但目的达到，非常感谢各位大虾！！

CrLf

gawk 也是个好选择：

@echo off
for /f "delims=" %%a in ('dir /a-d /b *.txt') do (
   gawk "FNR==2{print FILENAME};1" "%%a" >$
   ren $ "%%a"
)
复制代码

pcl_test

回复 5# CrLf

什么鬼

pcl_test

/*&cls
@echo off
::指定在第一行之后插入
set n=1
dir /a-d /b *.txt|cscript -nologo -e:jscript "%~f0" %n%
pause&exit
*/
var fso = new ActiveXObject('Scripting.FileSystemObject');
while(!WScript.StdIn.AtEndOfStream){
    var file = WScript.StdIn.ReadLine();
    var i = 0, s = '', f = fso.OpenTextFile(file, 1);
    while(!f.AtEndOfStream){
    if(i == WScript.Arguments(0))s += fso.GetFile(file).Name.replace(/\.[^\.]+$/, '') + '\r\n';
        var str = f.ReadLine();
        s += str + '\r\n';
        i++;
    }
    f.Close();
    var f = fso.OpenTextFile(file, 2);
    f.Write(s);
    f.Close();
}
复制代码

CrLf

回复 8# pcl_test


比如这样：

@echo off
for /f "delims=" %%a in ('dir /a-d /b *.txt') do (
    (
      setlocal enabledelayedexpansion
      set/pa=
      echo;!a!
      endlocal
      echo;%%~na
      find /v ""
    )<"%%a">$
    move $ "%%a"
)
pause
复制代码

---------------------------------------
实测发现 3 楼 more +1 的用法无误
那么问题来了，set /p 已经取走第一行了，为什么 more 还能再得到一个首行？

CrLf

hta 版：

mshta http://bathome.net/s/hta/ "var n=1; dir().files().grep(/\.txt$/i)._each(function(f){var a=type(f).split('\r\n');a.splice(n,0,f.replace(/\.[^.]+$/,''));save(a.join('\r\n'),f)})"
复制代码

wzf1024

喔，大家讨论激烈，看来我们论坛很有活力啊

xp3000

顶一下帖子上去，貌似以后要用到

CrLf

回复 12# happy886rr


    可以改用 "delims=" ... set "str=%%a" & setlocal enabledelayedexpansion & echo !str:*:=! & endlocal，一样可以兼容特殊字符

happy886rr

回复 15# CrLf
不错，看来这招可行。