[文本处理] 求助BAT脚本数据处理问题

Bieber

变量A=ja-jp,en-us,zh-cn
规则1：ja-jp,en-us,zh-cn(满足规则，变量*10)
规则2：ja-jp,zh-cn(满足规则，变量*20)
规则3：zh-cn,en-us(满足规则，变量*30)

就是要依次检查变量A中语言是否存在于规则1规则2规则3中，如果在，则执行指定命令

ja-jp需要执行变量*10
en-us需要执行变量*20
zh-cn需要执行变量*30

变量是各种语言，比如en-us,zh-cn,ja-jp等等

Batcher

回复 8# Bieber


第34行下面加一行：
goto :eof

Bieber

回复 7# Batcher

请教下，如果我想将所有的语言安装完毕后，去安装驱动，我在goto处跳转至安装驱动的部分，但是这样写后，驱动安装那里会在每个Input语言下，都安装一次，问题出在哪里？

@echo off
set "Input=ja-jp,zh-cn"
for %%i in (%Input%) do (
    echo --- Checking %%i
    call :CheckRule %%i
)
pause
goto :installDriver
 
:CheckRule
set "Rule1=ja-jp,en-us,zh-cn"
set "Rule2=ja-jp,zh-cn"
set "Rule3=zh-cn,en-us"
 
echo %Rule1% | findstr /i "%1" >nul
if errorlevel 1 (
    echo %Rule1% : Not match
) else (
    echo %Rule1% : Install
)
 
echo %Rule2% | findstr /i "%1" >nul
if errorlevel 1 (
    echo %Rule2% : Not match
) else (
    echo %Rule2% : Install
)
 
echo %Rule3% | findstr /i "%1" >nul
if errorlevel 1 (
    echo %Rule3% : Not match
) else (
    echo %Rule3% : Install
)

:installDriver
echo :InstallDriver for lang
复制代码

Batcher

回复 1# Bieber

@echo off
set "Input=ja-jp,zh-cn"
for %%i in (%Input%) do (
    echo --- Checking %%i
    call :CheckRule %%i
)
pause
goto :eof

:CheckRule
set "Rule1=ja-jp,en-us,zh-cn"
set "Rule2=ja-jp,zh-cn"
set "Rule3=zh-cn,en-us"

echo %Rule1% | findstr /i "%1" >nul
if errorlevel 1 (
    echo %Rule1% : Not match
) else (
    echo %Rule1% : Install
)

echo %Rule2% | findstr /i "%1" >nul
if errorlevel 1 (
    echo %Rule2% : Not match
) else (
    echo %Rule2% : Install
)

echo %Rule3% | findstr /i "%1" >nul
if errorlevel 1 (
    echo %Rule3% : Not match
) else (
    echo %Rule3% : Install
)
复制代码

terse

@echo off&setlocal enabledelayedexpansion
set "lang=ja-jp,en-us,zh-cn"
set "lang1=,ja-jp,en-us,zh-cn,"
set "lang2=,ja-jp,zh-cn,"
set "lang3=,zh-cn,en-us,"
for %%a in (%lang%) do  (
     for /l  %%i in (1,1,3) do (
          if "!lang%%i!" neq "!lang%%i:,%%a,=!" (
              echo %%a fnc%%i
          )
     )
)
pause
复制代码

Bieber

回复 4# czjt1234
可以整理成txt，也可以是字符串，比如en-us,zh-cn,ja-jp等等

语言规则1：ja-jp,en-us,zh-cn(满足规则，安装fnc1)
语言规则2：ja-jp,zh-cn(满足规则，安装fnc2)
语言规则3：zh-cn,en-us(满足规则，安装fnc3)

需要安装的语言：ja-jp,en-us,zh-cn

ja-jp需要安装fnc1和fnc2
en-us需要安装fnc1和fnc3
zh-cn需要安装fnc1 fnc2和fnc3

czjt1234

数据表是啥格式？
文本文件，excel文件，access数据库，还是什么？

还有，表1表2都有5，怎么处理

Bieber

回复 2# Batcher
就是想安装语言包(变量A)，比如语言包1，语言包5，语言包9，语言包13
如果语言包在数据表1中，则执行语言包*10
如果语言包在数据表2中，则执行语言包*20
如果语言包在数据表3中，则执行语言包*30
数据表1，数据表2，数据表3分别对应不同的语言规则

Batcher

回复 1# Bieber


    以顶楼数据为例，需要得到的结果是什么？