【练习-003】批处理实现文本左右对齐排版

pusofalse

如1.txt内容如下。

111111111111111111111    98912 张三
222222222222222222    150020 李四四
  333333333333333333333    360000 王五
444444444444444444    2332 赵六六
  555555555555555555    222 田七
666666666666666666666    999999 舞吧
复制代码

通过批处理输出为：

 
111111111111111111111      98912 张三
222222222222222222        150020 李四四
333333333333333333333     360000 王五
444444444444444444          2332 赵六六
555555555555555555           222 田七
666666666666666666666     999999 舞吧
复制代码

代码要求，不生成任何临时文件。
代码简洁，视思路与代码加分！
------------------------------------------------------------------------------------------
本题只是给出一个简单的文本通过批处理排版，而要求代码的通用，正如batman版主所说，会是一个繁琐的过程，于是就题解题，不必考虑代码的通用。

[ 本帖最后由 batman 于 2008-7-27 23:57 编辑 ]

batman

我来帮大家理思路吧：
所有的列其实都是左右对齐，大家想下为什么吧。

[ 本帖最后由 batman 于 2008-7-26 01:25 编辑 ]

浅默

@echo off
Setlocal Enabledelayedexpansion
set n=0
for /f "tokens=1,2*" %%i in (1.txt) do (
      set "ke=%%i %%j"
      set m=0
      call :1              
)
for /f "tokens=1,2*" %%i in (1.txt) do (
      set "ke1=%%i %%j"
      set ke2=%%i            
      set m1=0
      call :2
      echo !ke2! %%j %%k            
)
pause
goto :eof
:1
  if not "!ke:~%m%,1!"=="" set /a m+=1&goto 1
  if %m% gtr %n% set n=%m%
  goto :eof  

:2
  if not "!ke1:~%m1%,1!"=="" set /a m1+=1&goto 2
  set /a dd=n-m1
  for /l %%a in (1,1,%dd%) do set "ke2=!ke2! "     
  goto :eof

fastslz

不知道大家发现没？其实cmd文本排版是有潜规则的！

youxi01

呵呵，是

pusofalse

是。^_^

pusofalse

我本人的解，还是很繁琐，思路跟浅默的差不多。望更多人参与此题，求得更多的解！

 
@echo off&setlocal enabledelayedexpansion
set length=0
for /f "tokens=1,2" %%a in (1.txt) do (
     set x=0
     call :lp %%a%%b
     if !x! gtr !length! set length=!x!
)
set/a length+=4
for /f "tokens=1,2,*" %%a in (1.txt) do (
 set x=0
 set/p=%%a <nul
 call :lp %%a%%b
 set/a s=length-x
 for /l %%i in (1 1 !s!) do set/p= <nul
 set/p=%%b<nul
 set/p= %%c<nul
 echo.
)
pause&exit/b
:lp
set str=%1
:lp1
if defined str set str=!str:~1!&set/a x+=1&goto lp1
复制代码

fastslz

这个是潜规则默认排版方式

@echo off
for /f "delims=*" %%a in (1.txt) do call :xxx %%a
pause&exit

:xxx
    set "str=%*"
    REM 注意：等号左侧是制表符
    set "str=%str: =	%"
    echo.%str%
goto:eof
复制代码

pusofalse

原帖由 fastslz 于 2008-7-26 18:11 发表
这个是潜规则默认排版方式
@echo off
for /f "delims=*" %%a in (1.txt) do call :xxx %%a
pause&exit

:xxx
    set "str=%*"
    set "str=%str: =        %"
    echo.%str%
goto:eof

第一次看到如此的方法，还没弄明白怎么回事，在我电脑上测试着不正确。但仍旧学习了！~

fastslz

是论坛字符问题
方法其实很简单call标签删除前面及后面的空格字符，替换空格字符为Tab键字符set "str=%str: =这里是Tab键字符%"
附上附件

pusofalse

原帖由 fastslz 于 2008-7-26 18:35 发表
是论坛字符问题
方法其实很简单call标签删除前面及后面的空格字符，替换空格字符为Tab键字符set "str=%str: =这里是Tab键字符%"
附上附件

测试文本：

1111111    aaaaaaaaaaaa 张三
222222sdf222222222222    150020 李四四
  3333333sfd33333333333333    0 王五
44444444444aa4444444    2332 赵sdfafa六六
  555555555    222 田七
666666666666666666666asaaaaaaaaa    9999999999999 舞
复制代码

batman

个人认为如本题要充分考虑代码通用性的话，就会是一个相当复杂的过程，
于是，就题解题：

@echo off&setlocal enabledelayedexpansion
set "kong=           "
for /f "delims=" %%a in (1.txt) do (
    for %%i in (%%a) do (
        set "str=%%i"&set /a n+=1
        if !n! equ 2 (
           set "str=%kong%!str!"
           set /p=!str:~-10! <nul
           ) else (
           set "str=!str!%kong%"
           set /p=!str:~,20! <nul
    ))
    set "n=0"&echo.
)
pause>nul
复制代码

batman

原帖由 fastslz 于 2008-7-26 18:35 发表
是论坛字符问题
方法其实很简单call标签删除前面及后面的空格字符，替换空格字符为Tab键字符set "str=%str: =这里是Tab键字符%"
附上附件

使用制表符是默认的左对齐分列，主要用来从文本向excel中导数据。

风行者

@echo off & setlocal enabledelayedexpansion
for /f "tokens=1-3 delims= " %%a in (1.txt) do (
set /a n+=1
if !n!==1 echo %%a      %%b   %%c
if !n!==2 echo %%a         %%b  %%c
if !n!==3 echo %%a      %%b  %%c
if !n!==4 echo %%a         %%b    %%c
if !n!==5 echo %%a         %%b     %%c
if !n!==6 echo %%a      %%b  %%c
)
pause
复制代码

pusofalse

可以直接这样。。
echo 111111111111111111111      98912 张三
echo 222222222222222222        150020 李四四
echo 333333333333333333333     360000 王五
...
...
加分鼓励！一同进步！