随风

10/2008/10
这样的话，哪个是月哪个是日呢？
这个是必须知道的前提啊？

terse

用个临时文件取日期

@echo off
set n=-1&set m=+1
echo wscript.echo date>tmp.vbs
for /f "tokens=1,2,3* delims=-" %%i in ('cscript /nologo tmp.vbs^&del tmp.vbs') do set "ymda=10%%k 10%%i 10%%j"
:lp
echo wscript.echo dateadd("d",%n%,date)>tmp.vbs
for /f "tokens=1,2,3* delims=-" %%i in ('cscript /nologo tmp.vbs^&del tmp.vbs') do set "ymdb=10%%k 10%%i 10%%j"
for  %%i in (%ymda%) do set %%i=%%i
for  %%i in (%ymdb%) do if %%i gtr 1031 (set yyyy=%%i)else (
if not defined %%i (set/a dd=%%i%m%,t+=2)else set mm=%%i)
)
if %t% gtr 3 set n=+1&set t=&set m=-1&goto lp
   set yyyy=%yyyy:~-4%
   set mm=%mm:~-2%
   set dd=%dd:~-2%
   set .y=%yyyy%
   set .m=%mm%
   set .d=%dd%
   set/p str=请输入:
   setlocal enabledelayedexpansion
:lp1
   set v=!str:~,1!
     if not defined .%v% (
       if not defined var (set var=!v!)else set var=!var!!v!
        ) else (
          call set var=!var!%%.%v%:~!_%v%!,1%%
          set/a _!v!+=1
)
set str=!str:~1!
if defined str goto lp1
echo !var!
pause
复制代码

pusofalse

sorry，刚刚脑子短路了。。。
因为我的代码是先获取一个yyyymmdd格式的标准格式的日期（所谓标准，即是别的机子上也是如此），所以没有考虑太过关于日/年/月格式该如何区分日、月的问题就说了出来。
依次看来，随风兄的代码算得上完美代码了，期待更多好代码的出现。

pusofalse

VBS那里能知道个大概意思。lp1标签里的变量嵌套实在太经典了。
出这题的有一部分目的也在于熟悉“变量的嵌套”吧。

terse

这个问题用纯P 有点复杂了
因为毕竟要考虑日期格式的全面性 虽然有的格式并不会出现
就象 我开始问的  2008-01-03 也可以说是一月三号  也可以理解三月一号
我上面的代码 就是取得当天日期的前一天或后一天 有变化的判断为日
判断YYYY的方法是大于4位 余下是年
期待完善版本了

pusofalse

有变化的判断为日？
特意把日期改为10月1日后再运行，虽然也能正确输出。但“有变化的判断为日”这种说法是否不严谨？因为10月1日前一天是9月30日，月份也变化了。或许是我误解了。
------------------------------------------------------------------
明白了~只看到-1，没看到+1。

[ 本帖最后由 pusofalse 于 2008-10-21 23:49 编辑 ]

随风

还有个办法就是通过改变系统日期来实现判断 月或日。

terse

恩  可以试 DATE 改
不知道这样行得通否？

发现有错误  修改
复制代码

[ 本帖最后由 terse 于 2008-10-22 02:26 编辑 ]

batman

@echo off&setlocal enabledelayedexpansion
for %%a in (y1#0#1 y2#1#1 y3#2#1 y4#3#1 m1#5#1 m2#6#1 d1#8#1 d2#9#1) do (
    for /f "tokens=1,2,3 delims=#" %%i in ("%%a") do set "%%i=!date:~%%j,%%k!"
)
set /p code=请输入格式：
:lp
set "a=!code:~,1!"&set "code=!code:~1!"
set /a n+=1
for %%i in (d m y) do (
    if /i "%%i" equ "%a%" set /a .%%i+=1&call,set "_%n%=%%%%i!.%%i!%%"
)
if not defined _%n% set "_%n%=%a%"    
if defined code goto lp
for /l %%i in (1,1,%n%) do set /p=!_%%i!<nul
pause>nul
复制代码

测试格式为d/m m-y y,d y-y

batman

@echo off&setlocal enabledelayedexpansion
set "d=%date%"
:lp1
set "a=!d:~,1!"&set "d=!d:~1!"
for %%i in (0 1 2 3 4 5 6 7 8 9) do if "%%i" equ "%a%" set "str=!str!%a%"&goto next
:next
if defined d goto lp1
set "com=reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate"
for /f "skip=4 tokens=3" %%i in ('%com%') do set "ymd=%%i"
set "ymd=%ymd:mm=m%"&set "ymd=!ymd:dd=d!" 
set "ymd=%ymd:m=mm%"&set "ymd=!ymd:d=dd!"
:lp2
set "a=!ymd:~,1!"&set "ymd=!ymd:~1!"
for %%i in (y m d) do (
    if /i "%%i" equ "%a%" (
       set /a .%%i+=1&set "%%i!.%%i!=!str:~,1!"&set "str=!str:~1!"
    )
)
if defined ymd goto lp2
set /p code=请输入格式：
:lp3
set "a=!code:~,1!"&set "code=!code:~1!"&set "ok=a"
for %%i in (y m d) do (
    if /i "%%i" equ "%a%" set /a _%%i+=1&call,set /p=%%%%i!_%%i!%%<nul&set "ok="
)
if defined ok set /p=%a%<nul
if defined code goto lp3
pause>nul
复制代码

[ 本帖最后由 batman 于 2008-10-22 17:39 编辑 ]

Batcher

Win2k没有reg.exe
^_^

pusofalse

贴出我的代码，可能存在通用性问题。希望大家测试并指出其中问题：

@echo off&setlocal enabledelayedexpansion
for /f %%a in ('wmic path win32_operatingsystem get localdatetime') do set "CurrentDate=%%a"
rem 用wmic获取日期标准格式(yyyymmdd)，代码、思路来自于论坛巡查BATCHER。
rem 标准化获取当前日期：http://www.cn-dos.net/forum/viewthread.php?tid=41857&fpage=1&highlight=%2Bhat
set "CurrentDate=%CurrentDate:~0,8%"
set "Format=yyyymmdd"
for %%a in (Y M D) do set "%%a=defined"
for %%a in (4 2 2) do call :LOOP %%a
set /p DateFormat=Input the format：
:LP
set "Char=%DateFormat:~,1%"
if defined !Char! (
   set /a !Char! += 1
   <nul call call set /p=%%%%!Char!%%!Char!%%%%%%
   ) else (
   <nul set /p=!DateFormat:~,1!
)
set "DateFormat=!DateFormat:~1!"
if defined DateFormat goto :LP
pause>nul &exit /b

:LOOP
for /l %%a in (1 1 %1) do (
     set "!Format:~,1!%%a=!CurrentDate:~,1!"
     for %%i in (Format CurrentDate) do set "%%i=!%%i:~1!"
)
复制代码

[ 本帖最后由 pusofalse 于 2008-10-22 17:43 编辑 ]

shqf

　　先从注册表获得日期格式，把它保存到一个文件,再设置日期格式为yyyy-mm-dd,然后再交由主体程序按输入的格式去输出，最后恢复原先的日期格式。这样可不管原系统是什么日期格式了（3句语句可解决）。这样应该可行吧？可惜　按输入的格式去输出　我理解错了。

[ 本帖最后由 shqf 于 2008-10-22 19:57 编辑 ]

keen

只能显示三种格式：1.用空格隔开的格式，例如mm dd yyyy;2.用/隔开的格式，例如：dd/mm/yyy;3.用-隔开的格式，例如：yyyy-dd-mm

@echo off&setlocal enabledelayedexpansion
set "str=%date%"
for /f "delims=0123456789-/" %%i in ("%str%") do set var=!str:%%i=!
for /f "tokens=1-3 delims=-" %%i in ("%var%") do (
    if "%%j" neq "" (
       set yyyy=%%i&set mm=%%j&set dd=%%k
    ) else (
       for /f "tokens=1-3 delims=/" %%a in ("%var%") do (set mm=%%a&set dd=%%b&set yyyy=%%c)
    )
)
set /p input=请输入：
for /f "tokens=1-3" %%i in ("%input%") do if "%%j" neq "" call,echo %%%%i%% %%%%j%% %%%%k%%
for /f "tokens=1-3 delims=-" %%i in ("%input%") do if "%%j" neq "" call,echo %%%%i%%-%%%%j%%-%%%%k%%
for /f "tokens=1-3 delims=/" %%i in ("%input%") do if "%%j" neq "" call,echo %%%%i%%/%%%%j%%/%%%%k%%
pause>nul
复制代码

netbenton

真的很难！
不过还是做出来了，纯批的，适用多种情况

@echo off&setlocal enabledelayedexpansion
set n=1
for /f "tokens=2 delims=:" %%a in ('echo^;^|date') do (set str!n!=%%a&set/a n+=1)
set str2=!str2:~2,-2!
for %%a in (!str1!) do (set var=%%a
        if "!var:-=!" neq "!var!" set fen=-&set str=%%a
        if "!var:/=!" neq "!var!" set fen=/&set str=%%a

)
set n=3
for %%a in (!str2:%fen%^= !) do (set str!n!=%%a&set/a n+=1)
set n=3
if not defined str4 for %%a in (0 1 2) do (set str!n!=!str2:~%%a,1!&set/a n+=1)
set n=3
for %%a in (!str:%fen%^= !) do (
        for %%b in (str!n!) do (
                set !%%b!=%%a&set/a n+=1
        )
)

for %%a in ("年 月 日" "yyyy mm dd" "yy mm dd") do (
        for /f "tokens=1,2,3" %%b in (%%a) do (
                if defined %%b (
                for /f "tokens=1,2,3" %%e in ("!%%b! !%%c! !%%d!") do (
endlocal&setlocal enabledelayedexpansion
                        set #y=%%e
                        set #m=%%f
                        set #d=%%g
                ))
        )
)

:loop
set in=
set str=
set/p in=输入日期格式：
for %%a in (y m d) do (set in=!in:%%a=" "%%a" "!)
set/a .y=0,.m=0,.d=0
for %%a in ("!in!") do (
        if defined #%%~a (
                for %%b in (!.%%~a!) do (
                        set str=!str!!#%%~a:~%%b,1!
                )
                set/a .%%~a+=1
        ) else (set str=!str!%%~a)
)
echo 分解："!in!"
echo 处理结果：!str!
goto :loop
复制代码