[问题求助] [已解决]VBS如何实现同一对话框显示几段代码的执行结果并可选择是否输出结果到文本

doswork

网上不同地方找的代码，希望实现如下功能，帮忙看怎么整合到一起输出，多谢！

1、由于不同代码不同功能，输出是好几个界面，现希望将这几个功能的输出内容界面合并输出到一个界面来显示；
2、将最终合并输出的内容以文本方式写入当前目录下的output.txt，带（是/否 输出）选项。

k=1
Set wmiService = GetObject("winmgmts:\\.\root\cimv2")
Set wmiObjects = wmiService.ExecQuery("SELECT * FROM Win32_OperatingSystem")

'第一部分：希望在一个界面输出显示的内容
For Each wmiObject In wmiObjects
    msgbox "系统"&k&vblf&"" _
 &vblf&"计算机名： 不知道在这里显示的代码" _
 &vblf&"WinProductID： 不知道在这里显示的代码" _
 &vblf&"" _
 &vblf&"系统版本： "&wmiObject.Caption _
 &vblf&"安装时间： "&wmiObject.InstallDate  _ 
 &vblf&"最后启动： "&wmiObject.lastbootuptime  _
 &vblf&"能不能让时间格式显示为：2016-05-05 21:08:55 ？" _
 &vblf&"" _
 &vblf&"ip地址： 不知道在这里显示的代码" _
 &vblf&"MAC地址： 不知道在这里显示的代码" 
next 

'第二部分：显示“计算机名”（如果 第一部分 可以实现显示的话，这里就不用了）
Set colSettings = wmiService.ExecQuery _
    ("Select * from Win32_ComputerSystem")
For Each objComputer in colSettings 
    Wscript.Echo "System Name: " & objComputer.Name

next 

'第三部分：显示“IP、MAC地址”（如果 第一部分 可以实现显示的话，这里就不用了）
Function GetIPMAC(ComputerName) 
Dim objWMIService,colItems,objItem,objAddress
Set objWMIService = GetObject("winmgmts://" & ComputerName & "/root/cimv2")
Set colItems = objWMIService.ExecQuery("Select * From Win32_NetworkAdapterConfiguration Where IPEnabled = True")
For Each objItem in colItems
 For Each objAddress in objItem.IPAddress
  If objAddress <> "" then
  GetIPMAC = "IP 地址：  " & objAddress  & vbNewLine &  "MAC地址：  " & objItem.MACAddress
  Exit For
 End If  
 Next
 Exit For
Next
End Function

WScript.Echo GetIPMAC(".")

'第四部分：win10 序列号查看器（如果 第一部分 可以实现显示的话，这里就不用了）
Set WshShell = CreateObject("WScript.Shell")
regKey = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
DigitalProductId = WshShell.RegRead(regKey & "DigitalProductId")

WinProductName = "Windows Product Name: " & WshShell.RegRead(regKey & "ProductName") & vbNewLine
WinProductID = "Windows Product ID: " & WshShell.RegRead(regKey & "ProductID") & vbNewLine
WinProductKey = ConvertToKey(DigitalProductId)
strProductKey ="Windows Key: " & WinProductKey 
WinProductID = WinProductName & WinProductID & strProductKey


MsgBox(WinProductID)


Function ConvertToKey(regKey)
    Const KeyOffset = 52
    isWin8 = (regKey(66) \ 6) And 1
    regKey(66) = (regKey(66) And &HF7) Or ((isWin8 And 2) * 4)
    j = 24
    Chars = "BCDFGHJKMPQRTVWXY2346789"
    Do
        Cur = 0
        y = 14
        Do
            Cur = Cur * 256
            Cur = regKey(y + KeyOffset) + Cur
            regKey(y + KeyOffset) = (Cur \ 24)
            Cur = Cur Mod 24
            y = y -1
        Loop While y >= 0
        j = j -1
        winKeyOutput = Mid(Chars, Cur + 1, 1) & winKeyOutput
        Last = Cur
    Loop While j >= 0
    If (isWin8 = 1) Then
        keypart1 = Mid(winKeyOutput, 2, Last)
        insert = "N"
        winKeyOutput = Replace(winKeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
        If Last = 0 Then winKeyOutput = insert & winKeyOutput
    End If
    a = Mid(winKeyOutput, 1, 5)
    b = Mid(winKeyOutput, 6, 5)
    c = Mid(winKeyOutput, 11, 5)
    d = Mid(winKeyOutput, 16, 5)
    e = Mid(winKeyOutput, 21, 5)
    ConvertToKey = a & "-" & b & "-" & c & "-" & d & "-" & e
End Function
复制代码

pcl_test

Set wmiService = GetObject("winmgmts:\\.\root\cimv2")
Set fso = CreateObject("Scripting.FileSystemObject")

'第一部分：显示“系统相关信息”
Set wmiObjects = wmiService.ExecQuery("SELECT * FROM Win32_OperatingSystem")
For Each wmiObject In wmiObjects
    caption=wmiObject.Caption
    version=wmiObject.Version
    osarchitecture=wmiObject.OSArchitecture
    installdate=wmiObject.InstallDate
    lastbootuptime=wmiObject.LastBootUpTime
Next

'第二部分：显示“计算机名”
Set colSettings = wmiService.ExecQuery("Select * from Win32_ComputerSystem")
For Each objComputer in colSettings
    computername=objComputer.Name
Next

'第三部分：显示“IP、MAC地址”
Set colItems = wmiService.ExecQuery("Select * From Win32_NetworkAdapterConfiguration Where IPEnabled = True")
For Each objItem in colItems
    For Each objAddress in objItem.IPAddress
      If objAddress <> "" then
          ipaddress=objAddress 
          macaddress=objItem.MACAddress
      Exit For
      End If
    Next
    Exit For
Next

'第四部分：查看系统ID、密钥
Set WshShell = CreateObject("WScript.Shell")
regKey = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
DigitalProductId = WshShell.RegRead(regKey & "DigitalProductId")

productid = WshShell.RegRead(regKey & "ProductID")
productkey = ConvertToKey(DigitalProductId)

'输出
file ="系统信息.txt"
info = "系统："& caption &" "& osarchitecture _
    & vbCrLf &"版本：" & version _
    & vbCrLf &"计算机名：" & computername _
    & vbCrLf &"安装时间："& FormatDT(installdate) _
    & vbCrLf &"最后启动："& FormatDT(lastbootuptime) _
    & vbCrLf &"IP地址："& ipaddress _
    & vbCrLf &"MAC地址："& macaddress _
    & vbCrLf &"产品ID："& productid _
    & vbCrLf &"产品密钥："& productkey

IF msgbox(info &vbCrLf&vbCrLf&"是否保存以上信息到文本文件 "& file &"？", vbYesNo, "系统信息")=6 Then
    fso.OpenTextFile(file, 2, true).Write info
End If
WSH.quit

Function ConvertToKey(regKey)
    Const KeyOffset = 52
    isWin8 = (regKey(66) \ 6) And 1
    regKey(66) = (regKey(66) And &HF7) Or ((isWin8 And 2) * 4)
    j = 24
    Chars = "BCDFGHJKMPQRTVWXY2346789"
    Do
        Cur = 0
        y = 14
        Do
            Cur = Cur * 256
            Cur = regKey(y + KeyOffset) + Cur
            regKey(y + KeyOffset) = (Cur \ 24)
            Cur = Cur Mod 24
            y = y -1
        Loop While y >= 0
        j = j -1
        winKeyOutput = Mid(Chars, Cur + 1, 1) & winKeyOutput
        Last = Cur
    Loop While j >= 0
    If (isWin8 = 1) Then
        keypart1 = Mid(winKeyOutput, 2, Last)
        insert = "N"
        winKeyOutput = Replace(winKeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
        If Last = 0 Then winKeyOutput = insert & winKeyOutput
    End If
    a = Mid(winKeyOutput, 1, 5)
    b = Mid(winKeyOutput, 6, 5)
    c = Mid(winKeyOutput, 11, 5)
    d = Mid(winKeyOutput, 16, 5)
    e = Mid(winKeyOutput, 21, 5)
    ConvertToKey = a & "-" & b & "-" & c & "-" & d & "-" & e
End Function

'格式化日期时间
Function FormatDT(dt)
    FormatDT=left(dt, 4)&"-"&mid(dt, 5, 2)&"-"&mid(dt, 7, 2) _
        &" "&mid(dt, 9, 2)&":"&mid(dt, 11, 2)&":"&mid(dt, 13, 2)
End Function
复制代码

doswork

回复 2# pcl_test


    非常感谢版主帮忙修改！学习了~
   
    希望效果那个代码是用注册表的方式，有些项结果不太准确，代码很长看不懂，您的还可以学习进行相关的修改，感谢！

   第9行“   osarchitecture=wmiObject.OSArchitecture” 报错，提示：“对象不支持此属性或方法”，注释后其它正常，这句是什么意思？（xp系统）

pcl_test

OSArchitecture表示系统位数32/64，不支持说明xp系统的Win32_OperatingSystem没有该属性

doswork

回复 4# pcl_test


    明白了，多谢版主！

    加分机制好像一天有限制，现在还无法加分，晚些时候再加分~

doswork

回复 4# pcl_test


    还有一个问题请教版主：怎么在输出的界面增加“空行”？我尝试原来代码不行，您的代码修改还是不行（总报错）……

'输出
file ="系统信息.txt"
info = " 系统简易信息："  _
&vblf&"" _
        & vbCrLf &"" _
    "系统："& caption &" "& osarchitecture _
    & vbCrLf &"版本：" & version _

pcl_test

info = " 系统简易信息："& vbCrLf _
    & vbCrLf &"系统："& caption & osarchitecture _
    & vbCrLf &"版本：" & version _
    & vbCrLf &"计算机名：" & computername _
    & vbCrLf &"安装时间："& FormatDT(installdate) _
    & vbCrLf &"最后启动："& FormatDT(lastbootuptime) _
    & vbCrLf &"IP地址："& ipaddress _
    & vbCrLf &"MAC地址："& macaddress _
    & vbCrLf &"产品ID："& productid _
    & vbCrLf &"产品密钥："& productkey
复制代码

doswork

回复 7# pcl_test


    明白了，多谢版主！

doswork

请教版主，这个输出的界面一页显示不完整（又加入网卡等信息），是不是可以通过参数设置让可显示的字数（内容）更多些？

没有显示全的内容在输出的文本中是存在的，也就是说一页没有显示全，但输出文本有。

pcl_test

回复 9# doswork

Set fso = CreateObject("Scripting.FileSystemObject")
Set shell = CreateObject("WScript.Shell")

'获取系统相关信息
Set wmiService = GetObject("winmgmts:\\.\root\cimv2")
Set Items = wmiService.ExecQuery("SELECT * FROM Win32_OperatingSystem")
For Each Item In Items
    caption=Item.Caption
    version=Item.Version
    installdate=Item.InstallDate
    lastbootuptime=Item.LastBootUpTime
Next

osinfo = "系统："& caption _
    & vbCrLf &"版本：" & version _
    & vbCrLf &"安装时间："& FormatDT(installdate) _
    & vbCrLf &"最后启动："& FormatDT(lastbootuptime)

'输出
outfile ="保存信息.txt"
allinfo = "msgbox并没有参数可设置对话框的大小或控制显示信息内容的多少。" _
    &vbCrLf& "可以调用hta实现自定义对话框，实际可把vbs代码写到hta里，" _
    &vbCrLf& "完全可做出一个带美观界面的桌面应用程序，结合css或js可玩性更高" _
    &vbCrLf&vbCrLf& osinfo & vbCrLf & vbCrLf & GetMemory()
    
ShowInfo(replace(allinfo,VbCrLf,"<br/>"))

'自定义对话框
Function ShowInfo(info)
    Set htafile = fso.OpenTextFile("$temp.hta",2,true)
    htafile.Write "<title>提示</title><script>" & _
        "window.resizeTo(600,600);" & _
        "function writetxt(){" & _
        "var txt=document.getElementById('info').innerText.replace(/<br\/>/g, '\r\n');" & _
        "(new ActiveXObject('Scripting.FileSystemObject')).OpenTextFile('"& outfile &"',2,true).write(txt);close();}" & _
        "</script><div>是否保存以下信息到文本文件&nbsp;<font color='#FF0000'>"& outfile &"</font>？" & _
        "<input type='button' value='是(Y)' onclick='writetxt()'>&nbsp;&nbsp;&nbsp;&nbsp;" & _
        "<input type='button' value='否(N)' onclick='window.close()'></div><br/><div id='info'><font style='font-weight:bold' color='#008200'>"& info &"</font></div>"
    htafile.Close
    shell.Run "$temp.hta", 1, True
    fso.DeleteFile "$temp.hta"
End Function

'格式化日期时间
Function FormatDT(dt)
    FormatDT=left(dt, 4)&"-"&mid(dt, 5, 2)&"-"&mid(dt, 7, 2) _
        &" "&mid(dt, 9, 2)&":"&mid(dt, 11, 2)&":"&mid(dt, 13, 2)
End Function

'内存信息
Function GetMemory()
    mtotal=0
    num=0
    s=""
    Set colMemory = wmiService.execquery("select * from win32_physicalmemory",,48)
    For Each objitem In colMemory
        mtotal = mtotal+objitem.capacity
        num = num + 1
        s=s&"内存"& num &"："&(objitem.capacity/1048576)&"M "
    Next  
    GetMemory="总计内存"& num & "条，共" & (mtotal/1048576) & "M " &s 
End Function 
复制代码

doswork

多谢版主！

这个好多了，大小可以自定义，我再拼接原来的

另：能帮忙处理个识别内存的代码吗？多谢！内存处理完这个VBS就算完工了~
希望效果：内存共计： xx mb    内存1：XX mb   内存2：xx mb ……

我找的一个识别内存的，但调用不出来（代码单独可用，调用就无效）……
代码如下：

Function MemoryWrite()  
                '函数，写入内存信息  
mtotal        = 0  
num         = 0  
mill         = 0  
        Set colMemory = objswbemservices.execquery("select * from win32_physicalmemory",,48)  
        For Each objitem In colMemory  
                mill = objitem.capacity/1048576  
'                WriteTable "单根内存容量",mill & "M"  
                mtotal = mtotal+mill  
                num = num + 1  
        Next  
'        WriteTable "总计内存",num & "条" & "一共" & mtotal & "M"  
End Function 
复制代码

pcl_test

回复 11# doswork


10L已整合

doswork

回复 12# pcl_test

    多谢版主帮助，不过原来能用的一小段儿代码在这个新的版本里不能用了，提示：类型不匹配 ' ConvertToKey '

代码：

'第四部分：查看系统ID、密钥
Set WshShell = CreateObject("WScript.Shell")
regKey = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
DigitalProductId = WshShell.RegRead(regKey & "DigitalProductId")

WinProductName = WshShell.RegRead(regKey & "ProductName")
productid = WshShell.RegRead(regKey & "ProductID")
productkey = ConvertToKey(DigitalProductId)
复制代码

pcl_test

回复 13# doswork

指定回应某楼层的在相应楼层点回复，少引用

测试没有问题

doswork

回复 10# pcl_test


    好的，是10楼您最后给调整的hta版本，我加入后报错，之前msgbox版本里面没有报错