[ 新手习题 6 ] 批处理添加汉字行号

wxcute

a.txt

要怎么学好批处理？
可潜水看帖，静静研究；
可看教程做习题，然后解决实际的问题；
也可二者并用取其优，当然还有其他方法。
你是怎么做的呢？
复制代码

以上文本有五行，要求显示如下：（行号可为大写，但必须是汉字）

一┃要怎么学好批处理？
二┃可潜水看帖，静静研究；
三┃可看教程做习题，然后解决实际的问题；
四┃也可二者并用取其优，当然还有其他方法。
五┃你是怎么做的呢？
复制代码

方法不限。答对加分鼓励，第一个最多。

上一题：[ 新手练习 5 ] 随机显示星期几
http://bbs.bathome.net/thread-2564-1-1.html
下一题：[ 新手练习 7 ] 把所有输出都写入一个文件
http://bbs.bathome.net/thread-2582-1-1.html

[ 本帖最后由 wxcute 于 2008-11-18 21:04 编辑 ]

772074834

@echo off
set arr=一二三四五
set /a index=0
setlocal enabledelayedexpansion
for /f %%i in (a.txt) do (
        call echo %%arr:~!index!,1%%┃%%i
        set /a index+= 1
)
pause

impk

@echo off
setlocal enabledelayedexpansion
set str=一二三四五
for /f %%i in ( a.txt ) do ( 
echo !str:~0,1!^|%%i
set str=!str:~1!
)
pause
复制代码

focusos

新手报到，请多多关照

懒虫阿布

贴个用数组的，可显示1～99行

@echo off
setlocal enabledelayedexpansion

set hanghao=一 二 三 四 五 六 七 八 九 十
echo %hanghao%
set index=1
for %%a in (%hanghao%) do (
	set indexarray[!index!]=%%a
	call echo %%indexarray[!index!]%%
	set /a index+=1	
)

set no=1
for /f "delims=" %%a in (a1.txt) do (
	if !no! leq 10 (
		call echo %%indexarray[!no!]%%｜%%a
	) else if !no! lss 100 (
		set /a shiw=!no!/10
		set /a gew=!no!%%10
		call echo %%indexarray[!shiw!]%%!indexarray[10]!%%indexarray[!gew!]%%｜%%a
	)
	set /a no+=1
)
复制代码

wutarnow

回复 1# wxcute

@echo off
setlocal enabledelayedexpansion
set line=0
set head=一二三四五
for /f %%I in (a.txt) do (
    echo !head:~,1!^|%%I
    set head=!head:~1!
)
复制代码

pcl_test

回复 49# 尘丶

@echo off&setlocal enabledelayedexpansion
(for %%a in (一 二 三 四 五) do set /p %%a=%%a^|&echo;!%%a!)<a.txt
pause
复制代码

尘丶

@echo off&setlocal enabledelayedexpansion
set n1=一
set n2=二
set n3=三
set n4=四
set n5=五
for /f "delims=" %%a in (1.txt) do (
    set /a t+=1
    call,set /p=%%n!t!%%<nul
echo;^|%%a
)
pause
复制代码

慕夜蓝化

每一题代码的写法都有所不同，建议往别的方向考虑一下。
我们仅仅针对这道题这说，排除变量名的不同，代码相似度，通过使用不同的命令组合，
解答这题的方案大概也有5到6种。

@echo off&setlocal enabledelayedexpansion
set "l=一二三四五"
for /f %%i in (a.txt) do ( 
   call set/p=%%l:~!n!,1%%<nul&echo,^|%%i
       set/a n+=1
)
pause>nul&exit
复制代码

这样。应该很不错。

ann

还好吧

@echo off
setlocal enabledelayedexpansion
set "aa=一|二|三|四|五|"
for /f "tokens=*" %%a in (F:\1.txt) do (set /a js+=1&set bb=%%a&call :loop)
pause>nul&exit
:loop
if %js%==1 echo !aa:~0,2!%bb%&goto :eof
if %js%==2 echo !aa:~2,2!%bb%&goto :eof
if %js%==3 echo !aa:~4,2!%bb%&goto :eof
if %js%==4 echo !aa:~6,2!%bb%&goto :eof
if %js%==5 echo !aa:~8,2!%bb%&goto :eof
复制代码

BHsolve

@echo off
setlocal enabledelayedexpansion
for /f "tokens=* delims=" %%i in (c:\Users\KINGBOOK\Desktop\a.txt) do (
set /a n+=1
if !n! equ 1 echo 一┃%%i
if !n! equ 2 echo 二┃%%i
if !n! equ 3 echo 三┃%%i
if !n! equ 4 echo 四┃%%i
if !n! equ 5 echo 五┃%%i
)
pause
复制代码

battab

@echo off&setlocal enabledelayedexpansion
echo 要怎么学好批处理？>a.txt	
echo 可潜水看帖，静静研究；>>a.txt
echo 可看教程做习题，然后解决实际的问题；>>a.txt
echo 也可二者并用取其优，当然还有其他方法。>>a.txt
echo 你是怎么做的呢？>>a.txt
set shu= 一二三四五
for /f "tokens=* delims=" %%i in (a.txt) do (
	set str=%%i
	set /a n+=1
	call echo %%shu:~!n!,1%%┃!str!
)
del a.txt
pause
复制代码

Enterpaise

@echo off & setlocal enabledelayedexpansion
set var=一二三四五
for /F %%i in (a.txt) do (
    echo !var:~0,1!^|%%i
     set var=!var:~1!
)
pause>nul
复制代码

无知小菜鸟

回复 41# PCL505512957
应该是那个^|%%i的原因，5楼貌似发现了这个问题

无知小菜鸟

看了这道题，和5楼的回答，我看了很久的set教程，终于明白了那句set的作用，是选取head中第%num%开始的2个字符串

@echo off&setlocal enabledelayedexpansion
set "head=一|二|三|四|五|"
set /a num=0
for /f  %%i in (a.txt) do ( 
   call set /p=%%head:~!num!,2%%<nul
   set /p=%%i<nul 
 echo.
   set /a num+=2
)
pause>nul
复制代码