[文本处理] 【已解决】求助批处理文件夹内所有文本合并后，提取重复数为N的字符

思想之翼

d:\data1\内有若干文本，欲将文件夹内所有文本合并后，提取重复数为7的字符，写入d:\data2\B.txt；若没有重复数为7的字符，则B.txt为空。
每个文本记录字符的格式如下：
00000 00001
00003
00004 00005 00006
...

77七

@echo off
cd /d "d:\data1\"
(type *.txt >>xxx.temp) 1>nul
for /f "delims=" %%a in (xxx.temp) do (
	for %%b in (%%a) do (
		set/a #%%b+=1
	)
)
cd.>d:\data2\B.txt
setlocal enabledelayedexpansion
(for /f "delims=" %%a in (xxx.temp) do (
	for %%b in (%%a) do (
		if !#%%b! equ 7 (
			echo %%b
			set /a #%%b+=1
		)
	)
))>d:\data2\B.txt
endlocal
del xxx.temp
pause
复制代码

不合并也可以，就是文本过多，可能会影响效率。昨天”优化“那个帖子代码，中间的延迟变量就是为了单独计数每个文本，去掉之后就是所有文本一起计数。
code  不合并

@echo off
cd /d "d:\data1\"
for /r %%i in (*.txt) do (
	for /f "delims=" %%a in ('type "%%i"') do (
		for %%b in (%%a) do (
			set/a #%%b+=1
		)
	)
)
cd.>d:\data2\B.txt
setlocal enabledelayedexpansion
(for /r %%i in (*.txt) do (
	for /f "delims=" %%a in ('type "%%i"') do (
		for %%b in (%%a) do (
			if !#%%b! equ 7 (
				echo %%b
				set /a #%%b+=1
			)
		)
	)
))>d:\data2\B.txt
endlocal
pause
复制代码

思想之翼

回复 2# 77七
感谢！合并文件夹内所有文本，是中间过程，觉得没必要输出，可以将所有文本数据读入内存，在内存中提取重复数为N的字符，然后输出。

77七

回复 3# 思想之翼


   直接 in ('type *.txt') ，好方法！学习了！

buyiyang

回复 2# 77七


    10行以后也可以这样

(for /f "tokens=1,2 delims=#=" %%a in ('set #') do (
if %%b equ 7 (echo,%%a)
))>d:\data2\B.txt
pause
复制代码

77七

回复 5# buyiyang


   学习了！很久以前见到过 set # 这种用法，一直不是很理解。在这个实例中，会不会 存在 计数为8的，也被统计出来呢
试了一下，好像不会

buyiyang

回复 6# 77七


    为什么说计数为8的可能会被统计出来呢？set #是列出所有#开头的变量及值，if %%b equ 7选择了值为7的变量

77七

回复 7# buyiyang

我太业余了。我以为的 set #的结果是这样的...

...
#00001=6
#00001=7
#00001=8
复制代码

77七

@echo off
cd /d "d:\data1\"
for /f "delims=" %%a in ('type *.txt') do (
        for %%b in (%%a) do (
                set/a #%%b+=1
        )
)
cd.>d:\data2\B.txt
(for /f "tokens=1,2 delims=#=" %%a in ('set #') do (
        if %%b equ 7 (
                echo %%a
        )
))>d:\data2\B.txt
pause
复制代码

综合3楼 5楼的方法，再贴一下代码，方便他人阅读。
代码精简、优化、改动好多，向两位老师学习！

思想之翼

回复 9# 77七

环境变量 # 没有定义

77七

回复 10# 思想之翼


   你是改动代码了吧？如果开延迟变量，就在代码结束再关

hfxiang

回复 1# 思想之翼

gawk "{for(i=1;i<=NF;i++)a[$i]++}END{for(i in a)if(a[i]==7)print i}" "d:\data1\*.txt">"d:\data2\B.txt"
复制代码

之前输出错写为"d:\data1\B.txt",现改正为"d:\data2\B.txt" ，因为输入输出为同1文件夹会有冲突

思想之翼

回复 12# hfxiang

gawk: fatal: cannot open file `d:\data1\*.txt' for reading (Invalid argument)
感谢帮助！经测试，路径改正前后，都出现上述提示。

buyiyang

回复 13# 思想之翼


    含通配符的路径去掉引号

d:\data1\*.txt
复制代码

思想之翼

回复 14# buyiyang

感谢！经测试，上述所有代码，对于小文本，结果正确。但是对于大文本（3行 60000列），输出文本为空。