[ 新手习题] 批处理去除字符串前所有的0

yslyxqysl

用户输入一串字符后，去除此字符串前所有的0。

例如：
014   ----->   14
040   ----->   40
002740   ----->   2740

最优方案：10分；
一般方案：5分；
判断是否为纯数字：3分。

参考：for语句从入门到精通

[ 本帖最后由 yslyxqysl 于 2009-1-15 20:39 编辑 ]

rat

@echo off
:accept
set /p n=Please input a number:
echo.%n%|findstr "^[0-9][0-9]*$">nul||goto accept
 
:loop
if "%n:~0,1%" neq "" if "%n:~0,1%"=="0" call set n=%%n:~1%%&goto loop
 
echo.%n%
set "n="
pauseCOPY

[ 本帖最后由 rat 于 2009-1-15 21:59 编辑 ]

rat

@echo off & setlocal enabledelayedexpansion
:accept
set /p n=Please input a number:
echo.%n%|findstr "^[0-9][0-9]*$">nul||goto accept
 
set i=0&set "s="&set "f="
 
:loop
if "!n:~%i%,1!" neq "" set "s=!s! !n:~%i%,1!"&set /a i=i+1&goto loop
 
for %%a in (%s%) do if not defined f (if %%a neq 0 set r=!r!%%a&set f=1) else set r=!r!%%a
echo.%r%
pauseCOPY

zqz0012005

利用tokens=*

@echo off
:accept
set /p n=Please input a number:
echo.%n%|findstr "^[0-9][0-9]*$">nul||goto accept
for /f "tokens=* delims=0" %%a in ("%n%") do echo %%a
echo.&pauseCOPY

zqz0012005

判断是否为纯数字还用一种好用的方法：
将待检测的字符串作为 set /a 运算的变量名，如果是纯数字会出现“运算符不存在”的错误。
set /a %n%=1 2>nul&&echo NaN

rat

@set @j=1/*&set "@j="&set /p n=Input a number:&call cscript -nologo -e:jscript "%~f0" %%n%%&set "n="&pause&goto:eof */
if(!isNaN(WSH.Arguments(0)))WSH.Echo(WSH.Arguments(0).replace(/^(0+)/, ""))COPY

tireless

@echo off
set /p str=请输入: 
for /f "tokens=* delims=0 " %%a in ("%str%") do echo %%a
for /f "tokens=* delims=0123456789 " %%a in ("%str%") do (
  if "%%a"=="" (echo 纯数字) else (echo 非纯数字)
)
pauseCOPY

rat

@set /p n=Plz input:&(call echo e0:200 '%%n%%$'&more /e +1 "%~f0")|debug|findstr /v "^[I\-0P]"&pause>nul&goto:eof
a100
mov ds,ax
cmp byte ptr [200+bx],30
je 113
lea dx,[200+bx]
mov ah,9
int 21
int 20
inc bx
jmp 102
 
g
qCOPY

rat

'&@cls&set /p n=Plz input:&call cscript -nologo -e:vbs "%~f0" %%n%%&pause&goto:eof
WSH.Echo Replace(LTrim(Replace(WSH.Arguments(0), "0", " ")), " ", "0")COPY

skuny

@echo off&setlocal enabledelayedexpansion
:111
set "a="
set /p a="请输入:"
echo %a%|findstr "^[0-9][0-9]*$">nul
if %errorlevel%==1 echo %a%不是纯数字&goto 111
:222
if "!a:~0,1!"=="0" set "a=!a:~1!"&goto 222
echo 除0纯数字%a%&goto 111COPY

[ 本帖最后由 skuny 于 2009-1-16 12:19 编辑 ]

rat

@echo off
:111
set "a="
set /p a="请输入:"
echo %a%|findstr "^[0-9][0-9]*$">nul
if %errorlevel%==1 echo %a%不是纯数字&goto 111
:222
if "%a:~0,1%"=="0" set "a=%a:~1%"&goto 222
echo 除0纯数字%a%&goto 111COPY

terse

新手习题 都给你们占了  ~5

@echo off
:lp
cls&set /p var=输入字符串:
echo %var%|findstr "^[0-9]*$">nul || goto lp 
:lp1
if %var:~,1% neq 0 (echo %var%&pause)else set var=%var:*0=%&goto lp1COPY

[ 本帖最后由 terse 于 2009-1-18 22:24 编辑 ]

Batcher

不是新手的，楼主通通给他们扣分，哈哈。

cjiabing

晕，找了半天不知道从哪里发帖？

vyuwwen1985

我也发一个！

@echo off
:kaishi
set /p n=请输入：
echo.%n%|findstr "^[0-9][0-9]*$">nul||goto kaishi
:panduan
if not "%n:~0,1%"=="0"  (echo %n%&pause&goto kaishi) else (goto begin)
:begin
set n=%n:~1%&goto panduan
 
 
 COPY