[挑战]批处理如何不换行输出以等号或引号开头的行？

zqz0012005

如何不换行输出以等号或引号开头的行？即行末没有回车。
文本中不是所有行都这样，还可能有其他特殊字符。

broly

路过

@echo off
set str==123123=34
if "%str:~,1%"=="=" set /p=%str%<nul
pause
复制代码

zqz0012005

这种方法直接忽略。把它输出到文本是不一样的。

wc726842270

总是感觉怪怪的。不知符不符合题意

@echo off
echo ^
= I am from bathome ^
"成功从这里开始"
pause
复制代码

powerbat

版主的意思应该是：
楼上的把你这个多行文本合并成一行试试？
你这个文本正好符合，既有等号开头也有引号开头，还要其他特殊字符。

hanyeguxing

1，处理后的结果是要显示的屏幕还是要输出到文本？
2，如果某行行首为=，那么是把这行与上一行合成一行，还是与下一行合成一行？

powerbat

猜测可能是我在5楼说的那个意思

523066680

我是来钻空子的
注意在ntfs磁盘下运行
echo =>a.txt
fsutil file setzerodata offset=1 length=2 a.txt
fsutil把换行替换成 值为0的符号   
=号开头，木有错，也木有换行符……

plp626

引号处理不难，set/p=^"""<nul或者set/p=""^"<nul

等号试了下，感觉像是在对=替换的那种转义，，纳闷中。。

plp626

对于等号，空格，间接方法给前面加个换行符set/p=!lf!=<nul 输出，
但这样不是本质方法，绕弯子。。。

CrLf

直接 findstr 可以吗？

@echo off
findstr ^^= %0
pause&exit
=
复制代码

当然，用 set /p 也口以的嘿，不过要先获取回车换行符：

@echo off
set hh=^


set /p=@!hh!=<nul>tmp
findstr /v "^$" tmp
复制代码

qzwqzw

感觉难度不是很大
一个空格加一个回退符号应该可以解决大多数问题

@echo off
for /f "tokens=*" %%l in ('more +4 %~sf0') do set /p t= %%l<nul
pause
goto :eof
test0:
=test1:
"test2:
"test3:"
^test4:
!test5!:
复制代码

CrLf

回复 12# qzwqzw


    先拜楼上三拜，前辈好久不见。不过话说输出到文本的时候怎么办呢？

qzwqzw

嘿嘿
输出到文本的方法有两种
一是用变量拼接起来再用echo输出
不过如何综合处理各种特殊字符挺考验人的

@echo off & setlocal EnableDelayedExpansion
set line=-
for /f "tokens=*" %%l in ('more +6 %~sf0') do set line=!line!%%l
>test1.txt echo %line:~1%
pause & goto :eof



test0:
=test1:
"test2:
"test3":
^test4:
!test5!:
%test6%:
test7
复制代码

二是直接使用ASCODE生成的特殊echo输出
但如果在意控制键盘代码和字符集切换就比较麻烦

@echo off & chcp 437>nul & graftabl 936>nul
ECHO ,HP_,6P-B~1En0eqZ[SCj@_YQ2M@-@BINNNNN~BO!A>ECHO-.COM
echo- ->nul
(for /f "tokens=*" %%l in ('more +6 %~sf0') do echo- %%l)>test2.txt
del echo-.com
goto :eof
test0:
=test1:
"test2:
"test3":
^test4:
!test5!:
%test6%:
test7
复制代码

CrLf

@echo off&setlocal enabledelayedexpansion
for /f %%a in ('copy /z %0 nul') do set crlf=%%a^


set<nul>tmp /p"=@!crlf!   123"
findstr /v $ tmp
echo 测试
pause
复制代码