[文本处理] 批处理如何在文本里的字母两边添加指定字符

502283644

怎么用代码把txt里的内容加料
把txt 文本内的a~z字母都加上{}
例如文本是batd变成  [b ][a][t][d]
要加上恢复的代码哦

CrLf

打乱了怎么可能恢复

502283644

有规律的打乱

DAIC

打乱

sed -i "s/[a-z]/[&]/g" a.txt
复制代码

DAIC

恢复

sed -i -r "s/\[([a-z])\]/\1/g" a.txt
复制代码

502283644

sed不是内部或外部命令

DAIC

sed.exe是需要单独下载的

502283644

有木有不用下载的代码

DAIC

有，但是，那些太难用了。

CrLf

变换.bat：

@echo off
set list=a b c d e f g h i j k l m n o p q r s t u v w x y z
(for /f "delims=" %%a in (原文件.txt) do (
	set "text=%%a"
	setlocal enabledelayedexpansion
	for %%b in (%list%) do set text=!text:%%b=[%%b]!
	echo !text!
	endlocal
))>变换.txt
pause
复制代码

还原.bat：

@echo off
set list=a b c d e f g h i j k l m n o p q r s t u v w x y z
(for /f "delims=" %%a in (变换.txt) do (
	set "text=%%a"
	setlocal enabledelayedexpansion
	for %%b in (%list%) do set text=!text:[%%b]=%%b!
	echo !text!
	endlocal
))>还原.txt
pause
复制代码

CrLf

bat+js 方案：

@set @n=0/*&echo off
cscript -nologo -e:jscript /encode %0 <原文件.txt >变换.txt
cscript -nologo -e:jscript %0 <变换.txt >还原.txt
pause&exit /b */

var text = WScript.StdIn.ReadAll()

	text = WScript.Arguments.Named.Exists('encode') ?
			text.replace(/[a-z]/ig,'[$&]'):
			text.replace(/\[([a-z])\]/ig,'$1')

WScript.Echo(text)
复制代码

502283644

回复 10# CrLf


    里面有数字或其他文字就自动退出了

CrLf

回复 12# 502283644


    本机测试无误，你是怎么测试的

502283644

原文件.txt:
sd4sd1sdasds4
输出:
空格

CrLf

回复 14# 502283644


    我这输出

[s][d]4[s][d]1[s][d][a][s][d][s]4
复制代码