[文本处理] 【已解决】批处理如何获取文本里特定行中的指定内容并按指定规则进行字符替换

pan528

[文本处理]批处理如何批量切分指定的字符串

一、材料，如：
老封推箱子box文件：


[Level 1]
MapWidth=8
MapHeight=8
MapData=0011111011122210124212111212232112222121112122210162211101111100
Title=Minicosmos 01
Author=Aymeric du Peloux

[Level 2]
MapWidth=8
MapHeight=9
MapData=000011111111122112224221122312211121121112222221126122211221111111110000
Title=Minicosmos 04
Author=Aymeric du Peloux

……

二、生成下列“YSokoban”xsb 格式：

  ##### 
###   # 
# $ # ##
# #  . #
#    # #
## #   #
 #@  ###
 #####  
; Level 1

    ####
#####  #
#   $  #
#  .#  #
## ## ##
#      #
# @#   #
#  #####
####    
; Level 2
复制代码

三、老封推箱数字与符号的关系

0        场外空白
1        #        墙壁
2        空隔        空地 / 过道
3        .        仓位
4        $        箱子
5        *         箱子 + 仓位
6        @         推箱人
7        +         推箱人 + 仓位

四、我的代码

@echo off
set a=
setlocal enabledelayedexpansion
for /f "delims=" %%a in (1.txt)do (
set new=%%a
:ne
set/a a+=1,w=%a%*8
echo,!new:~%w%,8!>>1.txt
if !a! lss 9 goto:ne
)

call:box2xsb 1.txt 1.xsb

pause
goto:eof

:box2xsb
for %%a in (%1)do (
	for /f "delims=" %%i in (%%a)do (
		set var=%%i
		set var=!var:0=^ !
		set var=!var:1=^#!
		set var=!var:2=^ !
		set var=!var:3=^.!
		set var=!var:4=^$!
		set var=!var:5=^*!
		set var=!var:6=^@!
		set var=!var:7=^+!
		echo !var!
		)>>%2
	)
goto:eof
复制代码

五、求助

批量处理将上述box材料转成xsb格式……

在我的上段代码中不能自动获取宽与高的数字，要手工写。更不能批量处理，写了一天都没有成功。底子太差，只好求助高手指点，谢谢了！

pan528

回复 9# happy886rr

测试了一下，只能显示最后一关。谢谢。

pan528

回复 9# happy886rr


    测试了一下，没有通过。谢谢回贴！

happy886rr

回复 1# pan528
加强版推箱子

@echo off
setlocal enabledelayedexpansion

set "ELEMENTS=□■□○□◆我★"
for /l %%N in (0,1,7) do (
	set P%%N=!ELEMENTS:~%%N,1!
)

for /f "delims=" %%A in ('more +30 "%~f0"') do (
	set "%%A" 2>NUL||echo -----------------%%A&&set L=0
	set/a L+=1
	if !L! gtr 5 (call :DISPLAY)
)
set/p=[1-开始]  [2-进度]  [3-说明]
exit /b

:DISPLAY
for /l %%i in (1,1,%MapHeight%) do (
	set "DISPLAY=!MapData:~0,%MapWidth%!"
	set "MapData=!MapData:~%MapWidth%!"
	for /l %%N in (0,1,7) do (
		for %%P in (!P%%N!) do (
			set "DISPLAY=!DISPLAY:%%N=%%P!"
		)
	)
	echo;!DISPLAY!
)
echo Width:!MapWidth!  Height:!MapHeight!
goto :EOF


[Level 1]
MapWidth=8
MapHeight=8
MapData=0011111011122210124212111212232112222121112122210162211101111100
Title=Minicosmos 01
Author=Aymeric du Peloux

[Level 2]
MapWidth=8
MapHeight=9
MapData=000011111111122112224221122312211121121112222221126122211221111111110000
Title=Minicosmos 04
Author=Aymeric du Peloux
复制代码

codegay

"""
老封推箱数据格式转YSokoban(xsb)
2016年9月3日 12:01:30 codegay
"""

import configparser
punctuation = " # .$*@+"

boxini = configparser.ConfigParser()

boxini.read("batbox.ini")

节点= boxini.sections()
print(节点)
#=>['Level 1', 'Level 2']

for r in 节点:
    width=int(boxini.get(r,"MapWidth"))
    height=int(boxini.get(r,"MapHeight"))
    data=boxini.get(r,"MapData")
    
    result=''.join([punctuation[int(d)] if (e%width!=0) else (punctuation[int(d)]+"\n") for e,d in enumerate(data,1)])
    with open("result.txt", "a+") as f:
        f.write(result+";"+"\n")
复制代码

pan528

回复 4# codegay

感谢回贴！但inifile.exe 命令的用法，不明白，因此没有测试。但还是要谢谢你的热心！

pan528

回复 3# pcl_test

非党感谢，一下子给了四个方案。这两个第三方软件，效力高多了，转换几乎是在瞬间完成！

再次感谢版主的指教！

pan528

回复 2# pcl_test
非常感谢！已全部通过测试。代码简洁，思路巧妙！我要慢慢消化。
先用你的原码做了一个直接转化命令：

@echo off

echo 1、按关卡切割文本，请稍候 ...
if exist ~n rd /q /s ~n
if not exist ~n md ~n
setlocal enabledelayedexpansion
for /f "delims=" %%i in (%~nx1)do (
set m=%%i
if "!m:~0,6!" == "[Level" set x=000!m:~7,-1!& echo %%i>~n\!x:~-4!.txt
        if not "!m:~0,6!" == "[Level" echo %%i>>~n\!x:~-4!.txt
)
if exist ~n\~-4.txt del ~n\~-4.txt

echo 2、将 box 格式转为 xsb 格式，请稍候 ...

for /f "delims=" %%i in ('dir /b /o ~n\*.txt')do (
set /a a+=1
call:box2xsb ~n\%%i
echo ; Level !a!
echo.
)>>%~n1.xsb
endlocal

pause
goto:eof

:box2xsb
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('findstr "^MapWidth= ^MapData=" "%1"') do set "%%a"
set MapData=%MapData:0= %
set MapData=%MapData:1=#%
set MapData=%MapData:2= %
set MapData=%MapData:3=.%
set MapData=%MapData:4=$%
set MapData=%MapData:5=*%
set MapData=%MapData:6=@%
set MapData=%MapData:7=+%
:loop
set str=!MapData:~%t%,%MapWidth%!
set /a t+=MapWidth
echo;%str%
if "%str%" neq "" goto loop
goto:eof
复制代码

codegay

这种格式就是INI 配置文件啦
inifile.exe 命令的用法：

C:\bcn>inifile batbox.ini [Level 1]
set MapWidth=8
set MapHeight=8
set MapData=0011111011122210124212111212232112222121112122210162211101111100
set Title=Minicosmos 01
set Author=Aymeric du Peloux
复制代码

C:\bcn>inifile batbox.ini [Level 1] mapheight
set mapheight=8
复制代码

C:\bcn>inifile batbox.ini [Level 2] mapheight
set mapheight=9
复制代码

pcl_test

第三方http://www.bathome.net/s/tool/index.html?key=gawk

#*&cls&gawk -f "%~f0" "box文件.txt">con&pause&exit
BEGIN{split(" ,#, ,.,$,*,@,+",reg,",")}
{
    gsub(/^[[:space:]]*|[[:space:]]*$/,"",$0);
    if($0~/^\[Level [0-9]+\]/)level=substr($0,2,length($0)-2);
    if($0~/^MapWidth=[1-9][0-9]*/)split($0,width,"=");
    if($0~/^MapData=[0-7]+/)split($0,data,"=");
    if(width[2]&&data[2]){
        n=1;
        while((str=substr(data[2],n,width[2]))!=""){
            s="";
            for(i=1;i<=length(str);i++){
                s=s""reg[substr(str,i,1)+1];
            }
            n+=width[2];
            print s,str;
        }
        print "; "level"\n"
        delete width;
        delete data;
    }
}
复制代码

#*&cls&gawk -f "%~f0" "box文件.txt">con&pause&exit
BEGIN{split(" ,#, ,.,$,*,@,+",reg,",")}
{
    gsub(/^[[:space:]]*|[[:space:]]*$/,"",$0);
    if($0~/^\[Level [0-9]+\]/)level=substr($0,2,length($0)-2);
    if($0~/^MapWidth=[1-9][0-9]*/)split($0,width,"=");
    if($0~/^MapData=[0-7]+/)split($0,data,"=");
    if(width[2]&&data[2]){
        for(i=0;i<=7;i++)gsub(i,reg[i+1],data[2]);
        n=1;
        while((str=substr(data[2],n,width[2]))!=""){
            n+=width[2];
            print str;
        }
        print "; "level"\n"
        delete width;
        delete data;
    }
}
复制代码

pcl_test

举个栗子

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in ('findstr "^MapWidth= ^MapData=" "%~f0"') do set "%%a"
set n=-1
for %%a in (" ",#," ",.,$,@,@,+) do set /a n+=1&set "#!n!=%%~a"
set #5=*
:loop
set str=!MapData:~%t%,%MapWidth%!
set /a t+=MapWidth
for /l %%a in (0,1,%MapWidth%) do (
    for /f %%b in ("!str:~%%a,1!") do set "s=!s!!#%%b!"
)
echo;%s% %str%
set s=
if "%str%" neq "" goto loop
pause&exit
[Level 1]
MapWidth=8
MapHeight=8
MapData=0011111011122210124212111212232112222121112122210162211101111100
Title=Minicosmos 01
Author=Aymeric du Peloux
复制代码

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in ('findstr "^MapWidth= ^MapData=" "%~f0"') do set "%%a"
set MapData=%MapData:0= %
set MapData=%MapData:1=#%
set MapData=%MapData:2= %
set MapData=%MapData:3=.%
set MapData=%MapData:4=$%
set MapData=%MapData:5=*%
set MapData=%MapData:6=@%
set MapData=%MapData:7=+%
:loop
set str=!MapData:~%t%,%MapWidth%!
set /a t+=MapWidth
echo;%str%
if "%str%" neq "" goto loop
pause&exit
[Level 2]
MapWidth=8
MapHeight=9
MapData=000011111111122112224221122312211121121112222221126122211221111111110000
Title=Minicosmos 04
Author=Aymeric du Peloux
复制代码