ads350668398

回复 13# ivor


    升级的bat 是的
但是这个好比别的语言 复杂难以理解 执行结果

C:\Users\Administrator\Desktop>owershell "& {[ScriptBlock]::Create("'#' + (gc '
C:\Users\Administrator\Desktop\1除以3的余数.bat' -raw)").Invoke()}"   & pause
& goto :eof
Get-Content : 找不到与参数名称“raw”匹配的参数。
所在位置 行:1 字符: 85
+ & {[ScriptBlock]::Create('#' + (gc 'C:\Users\Administrator\Desktop\1除以3的余
数.bat' -raw <<<< )).Invoke()}
    + CategoryInfo          : InvalidArgument: ( [Get-Content], ParameterBin
   dingException
    + FullyQualifiedErrorId : NamedParameterNotFound,Microsoft.PowerShell.Comm
   ands.GetContentCommand

请按任意键继续. . .

老刘1号

批处理的各种奇诡用法才是复杂难以理解的吧……

hongrk

回复 8# ads350668398

经测试可用。添加其他规则方法类似，如果很多的话可以再套一个for循环

@echo off

(for /f "tokens=*" %%a in (1.txt)do (
  set/a js=os=fs=0
  for %%i in (%%a)do (
     2>nul set/a1/(1%%i"&"1^)&&set/a js+=1||set/a os+=1
     rem 添1防当成八进制
     rem 数是奇数则js+1，偶数同理。最后js=0则说明全偶，os=0则说明全奇。
     2>nul set/a1/(3%%i%%3^)&&set/a fs+=1
     rem 最后fs[非三]=0则说明全是3的倍数。
     )
  2>nul set/a1/(js*os*fs^)&&echo %%a
     rem 只要有1个为0就不会回显
))>"2.txt"
复制代码

hongrk

回复 17# 老刘1号


    赞成，排BUG有时候最后排出来是真的气……自己感觉语法没问题，但就是会报错，还得把踩雷的写法记下来不能犯，非常憋屈。

Batcher

回复 18# hongrk


    你测试的我哪个代码？bat文件和txt文件打包压缩传上来我试试

hongrk

回复 20# Batcher


    我已经找到原因了。用的是您在4楼发的代码，执行失败原因是我把它拖进cmd执行，直接双击是可以正常使用的。
我自己的代码也已经找到问题所在（set/a中的括号没有转义、注释用了::而不是rem）并修复了，并在之前的位置重新编辑了一下。

amwfjhh

1.txt

01 02 03 04 05
01 02 03 04 06
01 02 03 04 07
01 02 03 04 08
01 02 03 04 09
01 02 03 04 10
01 02 03 04 11
复制代码

rule.txt

5 b=a+1 c=b+1 d=c+1 e=d+1
5 b=a+1 c=b+1 d=c+1 e=d+2
复制代码

test.bat

@if (0)==(0) echo off
setlocal enabledelayedexpansion
REM 读取文件内容
for /f "tokens=*" %%i in ('type 1.txt') do (
	set "strLine=%%i"
	echo,Line data : !strLine!
	echo,
	set "bFit=1"
	call :_analysis
	if "!bFit!" EQU "0" (
		echo,不符算式规则...
	) else (
		echo,符合算式规则...
	)
	pause
)

pause
exit /b


:_analysis
(
	for /f "tokens=*" %%i in ('type rule.txt') do (
		echo,Rule data : %%i
		cscript -nologo -e:jscript %~s0 CheckAlgorithm "!strLine!" "%%i"
		for /f "tokens=*" %%a in ('cscript -nologo -e:jscript %~s0 CheckAlgorithm "!strLine!" "%%i"') do (
			REM echo,---analysis : %%a
			set "bFit=%%a"
		)
		REM echo,Analysis result : !bFit!
		REM 符合规则
		if "!bFit!" EQU "1" goto :EOF
	)
	goto :EOF
)


@end 

var func = WScript.Arguments(0);

switch (func) {
	case "CheckAlgorithm":
		var strSrc = WScript.Arguments(1);
		var strAlg = WScript.Arguments(2);
		CheckAlgorithm(strSrc, strAlg);
		break;

	default:;
}

function GetColData(str, nCol) {
	//WScript.Echo("str is : " + str);
	//WScript.Echo("nCol : " + nCol);
	var nLen = str.split(" ").length;
	return nCol <= nLen ? 1 : 0;
}

function CheckAlgorithm(str1, str2) {
	/// 检测数据个数是否符合
	var strAlgs = str2.split(" ");
	WScript.Echo("strAlgs : " + strAlgs);
	var nCol = strAlgs[0];
	var nRet = GetColData(str1, nCol);
	if (!nRet) {
		WScript.Echo("0");
		return;
	}
	var nNums = str1.split(" ");
	WScript.Echo("nNums : " + nNums);
	/// 逐行对比算式是否符合
	for (var i=1; i<strAlgs.length; i++) {
		strAlgTmp = strAlgs[i];
		WScript.Echo("Check algorithm : " + strAlgTmp);
		var n1 = strAlgTmp.replace(/(\w)=.*/i, "$1");
		var n2 = strAlgTmp.replace(/.=(\w).*/i, "$1");
		var nP = strAlgTmp.replace(/.=.(.).*/i, "$1");
		var n3 = strAlgTmp.replace(/.=..(.*)/i, "$1");
		var strCodec = "";
		strCodec += parseInt(nNums[n1.toUpperCase().charCodeAt(0)-65]) + "==" + parseInt(nNums[n2.toUpperCase().charCodeAt(0)-65]) + nP + n3;
		WScript.Echo(strCodec);
		nRet = eval(strCodec);
		if (!nRet) {
			WScript.Echo("0");
			return;
		}
	}

	WScript.Echo(nRet ? 1 : 0);
}
复制代码

初步实现简单自定义计算式规则效果。
Rule.txt内数据格式：
第一个数为匹配数据的个数，用来进行初筛不符合数据量的行；
第二个数据起为具体需要实现的算式，变量以a字母开始，匹配被筛数据的第一个值，b为第二个值，以此类推；
可简单识别+-*算式，/式需要额外写取整操作，目前只处理了b=a[+-*]n的情况；
更复杂的算式，需要对算式拆分重组验证作更细分的处理。
未优化代码。抛砖引玉。

ads350668398

。。。。。。。。。。。。
。。。。。。。
感谢网友热心 我们很优秀

Taurus

回复  ads350668398

【排除12345】谢谢关注
01 02 03 04 06
01 02 03 04 07
01 02 03 04 08
01  ...
ads350668398 发表于 2019-5-4 23:24

我用A.B.C.D.E比喻五段數組
例如:
01 02 03 04 07
01=strA ,02=strB , 03=strC , 04=strD , 07=strE

如果數組排序的邏輯必然是 : E大於D , D大於C , C大於B , B大於A的話 (沒有[相同數目]、或者[負數]) , 那你 set /a nub=!E!-!D!-!C!-!B!-!A!   , 接著if "!nub!=4" echo yes , 如果是連續數目 , 減下去!nub!就必然是4了 , 否則!nub!就不是連續數目。

這樣沒了迴圈、效率就應較快了
=======================
偶数、 奇数
取str的最後一位數字、補上一個0、再除2 ; 答案最尾一位不是0就是奇数 , 否則是偶数

整除3也一樣 , 在str後補上一個0(原理是把他當成小數點後的位)、再除3 , 答案最尾一位不是0就不能整除 , 否則是能整除(原理是 , 不能整除才會出現小數點)
整除5 , 同上

!str:~-1,1!     顯示最後一個字的寫法
!str:~0,-1!    去掉最後一個字的寫法


路過 , 邊看邊答 , 就不寫代碼了 , 只幫忙想想思路上迴圈最少的方法

Taurus

易讀版:

@echo off&setlocal enabledelayedexpansion
del testinbathome.txt 2>nul>nul
for /f "tokens=1,2,3,4,5 delims= " %%a in (1.txt) do (
     set ORG=%%a %%b %%c %%d %%e
     for  %%f in (!ORG!) do (
          set /a looptime+=1
::去除字串左前的所有0
          set /a var!looptime!=-11%%f+10%%f+1%%f
     )
     call :step !var1! !var2! !var3! !var4! !var5!
     set looptime=
)>>testinbathome.txt
start testinbathome.txt
<
:step
::判斷是否順數 , 非順數才繼續嘗試整除
set str=set/a nub=%5-%4+%4-%3+%3-%2+%2-%1
for /f  %%i in ('!str!') do (
     set /p=!ORG!  <nul
     if "%%i" EQU "4" (
          echo 連續的字串
     ) else (
          ::非連續的字串
          call :step2 !var1! !var2! !var3! !var4! !var5!
     )
     goto :eof
)
:step2
::判斷數字能否全為2-9之倍數 , 和判斷奇偶數
set str=%10 %20 %30 %40 %50
::for語句[2,3,5,9] 可切換成 [2,3,4,5,6,7,8,9] , 則變成判繼2至9的所有倍數
     for %%Z in (2,3,5,9) do (
     call :step3 %%Z
     if "!about%%Z!" EQU "00000" (
          set /p=整除於[%%Z]<nul
          if "%%Z"=="2" (set /p=, 偶數字串 , <nul) 
          )else if "!about%%Z!%%Z" == "555552"  (set /p=奇數字串<nul))
     )
echo.
goto :eof
)
:step3
::數字2-9通用的整除計算語句
     for /f "tokens=1,2,3,4,5 delims= " %%i in ('echo !str!') do set/a A=%%i/%1 ,B=%%j/%1,C=%%k/%1,D=%%m/%1,E=%%l/%1&&set about%1=!A:~-1,1!!B:~-1,1!!C:~-1,1!!D:~-1,1!!E:~-1,1!
复制代码

精簡版:

@echo off&setlocal enabledelayedexpansion
del testinbathome.txt 2>nul>nul
for /f "tokens=1,2,3,4,5 delims= " %%a in (1.txt) do (
     set ORG=%%a %%b %%c %%d %%e
     for  %%f in (!ORG!) do set /a looptime+=1&&set /a var!looptime!=-11%%f+10%%f+1%%f
     set/a str=!var5!-!var4!+!var4!-!var3!+!var3!-!var2!+!var2!-!var1!
     set /p=!ORG!  <nul
     if "!str!" EQU "4" set /p=連續的字串<nul
     for %%Z in [color=Red](2,3,4,5,6,7,8,9)[/color] do (
          set/a A=!var1!0/%%Z ,B=!var2!0/%%Z,C=!var3!0/%%Z,D=!var5!0/%%Z,E=!var5!0/%%Z
          set about%%Z=!A:~-1,1!!B:~-1,1!!C:~-1,1!!D:~-1,1!!E:~-1,1!
          if "!about%%Z!%%Z" == "555552" set mark=1&&set /p=奇數字串<nul
          if "!about%%Z!" EQU "00000" (
               if "%%Z"=="2" (
                    set mark=2&set /p=偶數字串 , [%%Z]<nul
               ) else (
                    if !mark!==1 set /p=, <nul
                    set mark=2&set /p=[%%Z]<nul
               )
          )
          if !mark!9==2%%Z set /p=之倍數<nul
     )
echo.
set looptime=&set mark=0
)>>testinbathome.txt
start testinbathome.txt
复制代码

測試文件[1.txt]

01 02 03 04 05
01 02 03 04 06
01 02 03 04 07
01 02 03 04 08
01 02 03 04 09
01 02 03 04 10
01 02 03 04 11
02 03 04 05 06
02 04 06 08 10
03 06 09 12 15
01 03 05 07 09
05 10 15 20 25
06 09 15 27 33
01 04 07 10 13 
01 05 09 13 17
01 06 11 16 21
01 07 13 19 25
01 08 15 22 29
01 09 18 26 34
03 11 15 21 23
06 10 18 22 28
04 06 08 10 12
06 07 08 09 10
23 24 25 26 27
06 10 20 22 28
28 29 30 31 32
09 18 27 36 99
099 0117 0234 0594 07992
0090 0099 0909 0594 07992
02889 2898 02997 03789 04293
0029 030 00031 32 033
29 00030 031 00000032 0033
2 0000004 006 00008 10
550 00660 000770 880 0990
33 39 63 69 99
44 88 124 164 204
40 80 120 160 200
06 12 18 24 30
07 14 21 28 35
08 16 24 32 40
01 03 06 07 09
09 18 27 36 99
复制代码

我把他直接寫成可分類 : 奇數、偶數、順序字串、和分辨[1-9]的倍數
另外因不肯定你只是用來處理2位數組 , 也不肯定數目前必然只有1個零 , 所以也把它寫成可以通用處理[測試文件]那些古怪格式了
另外也因不肯定你只是用來處理[3]和[5]的倍數 , 所以也把它寫成可以通用分辨[1-9]的倍數。如果需要改回只處理3和5的倍數 , 你可把[精簡版:](2,3,4,5,6,7,8,9) 一句改成(2,3,5)就可以了

第一個[易讀版:]的代碼是方便你讀和修改的 , 所以盡量把運作分類和每部份寫註解了。如果你想增加判斷字串方法 , 應該你再增加 標籤/算式 , 再call這標籤就成了

hongrk

做了一个通用的版本。
规则：
1.用S2表示本行第2个数，其他同理。
2.本行数的总数用n表示。
3.同一行的小节规则用""包起来，同一大节的规则之间空格隔开。
4.同一规则重复检测格式："起始位置 间隔 中止位置(直到最后则写n)""其他规则1""其他规则2"
在此格式中，用%%i表示不确定的位置。还可以实现对%%i进行各种运算，用[]包起来即可。
5.可以自创变量进行赋值(不与已用变量冲突即可，如可使用A1、A2、B1等等)。格式相当于省去了set/a的set/a
6.检验部分相当于省去了if的if
举个例子：
"n GTR 3" "3 1 n""S%%i==S[%%i-1]+S[%%i-2]" "S2==50" "1 1 n""B1+=S%%i" "B1 GTR 100"
这是斐波那契数列的规则，且要求第2个数是50，全部数加起来超过100.
这个分析器可以实现之前代码的所有功能，并且要强大出许多。
【BUG这下应该算是彻底修好了!】

代码如下。

@echo off&setlocal enabledelayedexpansion

echo 默认目标文档为“分析器”目录下的2.txt
set/p rule=请拖入规则文档：
rem 先读取规则，分行读取，G系列存规则，变量Gn用于标记这是第几行规则(在下一部分即总共有几行规则)。（G：Gui则）（n：number）
for /f "tokens=*" %%a in (%rule%)do (
  set/a Gn+=1
  for /f "tokens=1*" %%b in ("!Gn! %%a")do set G%%b=%%c
)

set/p shu=请拖入待处理文档：
cls
rem n系列：存每一行的数总数。 S系列(Shu)：存每一行的每一个数。 F系列：存是否符合对应规则行，符合为1否则为0.  
rem 按行读取待检测的数，先赋好一行，然后再执行规则，最后判断执行结果。完成后读取下一行数。
(for /f "tokens=*" %%a in (%shu%)do (
  setlocal
  for %%b in (%%a)do set/a n+=1&set S!n!=%%b
  for /l %%b in (1 1 %Gn%)do (
    for %%c in (!G%%b!)do (
rem 把一行规则分解为几节逐一分析检验
      for /f tokens^=1*^ delims^=^" %%d in ("%%~c")do (
        if "%%e"=="" (set forl=&set t=%%d
        )else set t=%%e&for /f "tokens=1-3 delims=,; " %%f in ("%%d")do (
                set/a Z1=%%f,Z2=%%g,Z3=%%h
                set "forl=for /l %%i in (!Z1! !Z2! !Z3!^)do"
              )
rem 若此节规则的中间没有引号，说明没有类似"1 1 n"的结构；否则要准备开for /l了。将去除"for /l"结构后的“整节规则”赋给t。
        set "t=!t:""=" "!"
rem 准备开始分割小节规则。
        call :forl %%b
      )
rem 此节规则结束。
    )
rem 此行规则结束。
    set/a f+=f%%b
  )
rem 对此行数，所有规则结束。
  if !f!==0 echo %%a
rem 只要有一行规则完全符合，就不输出
  endlocal
))>2.txt
exit

rem %t%存整节规则，!t!存小节规则。
:forl
(%forl% (
  for %%j in ("%t%")do (
    set Le=&set Ri=
    set t=%%~j&set t=!t:%%%%i=%%i!
rem 因为前面在整节规则中造出了空格，因此可用for截取小节规则。
    for %%k in ("!t!")do (
      set u=!t:%%~k!
      set center==
      if "!u:~,1!"=="=" set center===
      if "!u:~,1!"=="t" set center=
    )
rem 以上利用字符串替换对"="的检测规律，来分析t，也就是小节规则，是0个/1个/2个等于号中的哪一种。
    for /f "tokens=1-3 delims== " %%k in ("!t!")do (
      set Le.ft=%%k
      if "!center!"=="" (set center=%%l&set Ri.ght=%%m)else set Ri.ght=%%l
    )
rem 分割小节规则
    for %%k in (Le.ft Ri.ght)do (
      set %%k=!%%k:[= !&set %%k=!%%k:]= !
      set QAQ=0
      for %%l in (!%%k!)do (
        2>nul set/a AQA=%%l
        2>nul set/a QAQ+=1,1/(QAQ"&"1^)&&set %%~nk=!%%~nk!%%l||set %%~nk=!%%~nk!!AQA!
      )
    )
rem 处理[]
    if "!center!"=="=" (set/a !Le!=!Ri!)else set/a Le=!Le!,Ri=!Ri!&call :zl %1
rem 若是赋值规则就直接打包set/a；若是比较规则，左右计算后进行比较。
  )
)
)&exit/b

:zl
rem if语句做不到耐心地把感叹号扩充开再判断语句是否合理，所以——
if %Le% %center% %Ri% (if not defined F%1 set F%1=1)else set F%1=0
rem F%1是用来存这行数对应这行规则的判定结果。有一节规则不满足就不算满足此行规则。符合为1，不符合为0.
exit/b
复制代码

Taurus

精簡化#24樓代碼 , 以及按8樓要求改為過濾[1~9]、奇偶數、順序數
優化不必要的迴圈至最少
同樣 , 只要把[for %%Z in (2,3,4,5,6,7,8,9) do (] 改為[for %%Z in (2,3,5) do (] 則只過濾2、3、5倍數 , 現在是判斷過濾1-9的

@echo off&setlocal enabledelayedexpansion
del test.txt>nul 2>nul
for /f "tokens=1-5 delims= " %%a in (1.txt) do (
    for  %%f in (%%a %%b %%c %%d %%e) do set/a loop+=1&&set/a var!loop!=-11%%f+10%%f+1%%f
    set/a str=!var5!-!var4!+!var4!-!var3!+!var3!-!var2!+!var2!-!var1!,loop=0
    if "!str!" NEQ "4" call :a %%a %%b %%c %%d %%e
)
test.txt
:a
for %%Z in (2,3,4,5,6,7,8,9) do (
    set/a A=!var1!0/%%Z,B=!var2!0/%%Z,C=!var3!0/%%Z,D=!var4!0/%%Z,E=!var5!0/%%Z
    if "!A:~-1,1!!B:~-1,1!!C:~-1,1!!D:~-1,1!!E:~-1,1!" == "00000" goto :eof
    if "!A:~-1,1!!B:~-1,1!!C:~-1,1!!D:~-1,1!!E:~-1,1!%%Z" == "555552" goto :eof
)
echo %*>>test.txt

註解:
第四行 : 去字串前的[0]的算式 , 原理為 , 把[009090]加上兩個位 ,  -11009090+10009090+1009090=[9090]
算式為-11[string]+-10[string]-1[string]=[Result]

第五行 : 去除[連續數]的算式 , 原理為 , 例如連續數[5,6,7,8,9] , 把9-8+8-7+7-6+6-5=[4] ; 只要是[連續數] , 餘值必然是[4]
算式為E-D+D-C+C-B+B-A=4

第十一行 : 把5組數在結尾補上一個0位 , 再分別除以[1-9] ; 例如[903 , 906 , 909 , 912 , 915] , 除[2]等於[451.5/953.0/454.5/456.0/457.5 ] , 截取小數點後一個位等於[50505] , 小數點後出現餘值等於不能整除 ; 反之 , [903 , 906 , 909 , 912 , 915]除[3] = [301.0/302.0/303.0/304.0/305.0] , 截取小數點後一個位等於[00000] , 小數點後不出現餘值等於能被整除
第十一行通用判斷奇數(被2整除出現00000)、偶數(被2除後出現55555)、1-9倍數(被1-9整除出現00000) , 所以非[00000]也非[55555]之數正是樓主所需篩選出來的值
算式為[A string]/2 , [B string]/2  , [C string]/2 , [D string]/2 , [E string]/2  =   [00000] or [55555] or [0和5的混合字串]

==================================
所以 , 綜合判斷條件其實只是需要[去零]、[去連續數]、[分辨整除數]三條算式