[原创] 【征集】批处理库函数征集

defanive

征集批处理函数专用贴。。。

此贴用来征集批处理函数的。。。

所谓的函数呢，就是一个标签，里面有编写好的功能，通过call和参数来执行。。。

使用批处理函数可以减少重复的代码，让批处理更简洁。。。

下面给一些库函数做参考，格式可以不按照下面的。。。

这个是计算两点时间差，call :TimePoint Time1 Time2 Var
Var变量里就保存了Time1到Time2的时间差

1.0
CN-DOS Jvive
不需要其他库的支持
TimePoint、TimePoint_1标签
定义了TimePoint标签，用于计算两点时间差
用法 call :TimePoint Point1 Point2 Variable
Point1和Point2是标准时间格式（例如time变量），Point2需大于Point1。两点时间差将保存在Variable变量里。
使用本库的时候可以给参数外加上双引号（如"%time%"），本库会自动处理
使用本库需要保留TimePoint、TimePoint_1标签
使用本库需要开启变量延迟
//**//
:TimePoint
setlocal enableextensions
:TimePoint_1
set "P2=%~1"
set "P2=!P2::=!"
set /a "P2=%P2:.=%-4000*(%P2:~,4%+60*%P2:~,2%)"
if not "%~3"=="" (
        set "P1=!P2!"
        shift
        goto :TimePoint_1
)
if !P2! geq !P1! (
        set /a "df=!P2!-!P1!"
) else (
        set /a "df=!P2!-!P1!+8640000"
)
set /a "h=df/360000,m=df%%360000/6000,s=df%%6000/100,pt=df%%100"
if %pt% leq 9 set "pt=0%pt%"
endlocal&set "%~2=%h%:%m%:%s%.%pt%"
goto:eof
复制代码

下面这个是Ritchie Lawrence写的，也是他最先提出批处理函数这个概念的
这个函数可以将日期转化为星期

1.1
Ritchie Lawrence
不需要其他库的支持
DateToDOW标签
定义了DateToDOW标签，用于将日期转化为星期（1-7）
用法 call :DateToDOW "Year" "Month" "Date" "Variable"
Year为年，Month为月，Date为日。星期（1-7）将保存在Variable变量里。
使用本库的时候可以给参数外加上双引号（如"2009"），本库会自动处理
使用本库需要保留DateToDOW标签
//**//
:DateToDOW
setlocal ENABLEEXTENSIONS
set "yy=%~1"
set "mm=%~2"
set "dd=%~3"
if 1%yy% LSS 200 if 1%yy% LSS 170 (set "yy=20%yy%") else (set "yy=19%yy%")
set /a "dd=100%dd%%%100,mm=100%mm%%%100"
set /a "z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,dow=153*m+2"
set /a "dow=dow/5+dd+y*365+y/4-y/100+y/400-2472630,dow%%=7,dow+=1"
endlocal&set "%~4=%dow%"
goto :EOF
复制代码

大家多写点批处理函数发上来，谢谢了。。。。

Batcher

Ritchie Lawrence 批处理函数库中英文版
http://bbs.bathome.net/thread-3056-1-2.html

defanive

他的函数库看过了，很好很强大，不过基本都是日期类的，有很多函数不适合移植到中文系统。。。

defanive

再附上几个函数库做参考：

判断文件夹是否为空的函数：

 1.0
Ritchie Lawrence
不需要其他库的支持
isDirEmpty标签
定义了isDirEmpty标签，用于判断文件夹是否为空
用法 call :isDirEmpty "Directory"&& Command1 || Command2
Directory是文件夹路径，可用短名。为空时，会执行Command1，否则执行Command2
使用本库的时候可以给参数外加上双引号（如"C:\Windows"），本库会自动处理
使用本库需要保留isDirEmpty标签，i变量
//**//
:isDirEmpty
setlocal enableextensions
dir/ad "%~1" >nul 2>nul||(goto :EOF)
set i=0
for /f %%a in ('dir /a/b "%~1" 2^>nul') do set /a "i+=1"
if %i%==0 (ver>nul) else (md;2>nul)
endlocal
goto :EOF
复制代码

声明一个数组：

 1.0
BatCodeer
不需要其他库的支持
NewArray标签，arrays贮存变量
定义了NewArray标签，用于定义新的数组，支持1-3维度。
用法：call :NewArray "Array" "Var"
Array是形如array_2的字串符，其中array是数组名，2是一维长度。Var是数组的缺省值。定义二维数组则是形如array_2_2，三维则是array_2_2_2。
例如call :NewArray "array_2_2" "0"，执行后变量array_1_1、array_1_2、array_2_1、array_2_2的值均为0
使用本库的时候可以给参数外加上双引号（如"array_2_2"），本库会自动处理
使用本库需要保留NewArray标签，arrays变量
//**//
:NewArray
if "%~1"=="" goto :EOF
for /f "eol= tokens=1-4 delims=_" %%1 in ("%~1") do (
 if "%%~2"=="" goto :EOF
 set arrays=%arrays%%%1;
 if "%%~3"=="" (
  for /l %%a in (1,1,%%2) do (
   set "%%1_%%a=%~2"
  )
  goto :EOF
 ) else (
  if "%%~4"=="" (
   for /l %%a in (1,1,%%2) do (
    for /l %%b in (1,1,%%3) do (
     set "%%1_%%a_%%b=%~2"
    )
   )
  ) else (
   for /l %%a in (1,1,%%2) do (
    for /l %%b in (1,1,%%3) do (
     for /l %%c in (1,1,%%4) do (
      set "%%1_%%a_%%b_%%c=%~2"
     )
    )
   )
  )
 )
)
goto :EOF
复制代码

获得数组的维数：

1.0
BatCodeer
不需要其他库的支持
GetArrayWides标签
定义了GetArrayWides标签，用于获得数组的维度
用法 call :GetArrayWides ArrayName Variable
ArrayName是数组的名称（例如数组array_10_10，名称为array），数组可以是隐式或显式定义。数组的维度将保存在Variable变量里
使用本库的时候可以给参数外加上双引号（如"array"），本库会自动处理
使用本库需要保留GetArrayWides标签
使用本库需要开启变量延迟
//**//
:GetArrayWides
setlocal enableextensions
set "ArrayWides=%~1"
set "AWs=0"
for /l %%a in (1,1,3) do (
set "ArrayWides=!ArrayWides!_1"
if defined !ArrayWides! set "AWs=%%a"
)
endlocal&set "%~2=%AWs%"
goto :EOF
复制代码

获得数组某一维上有多少个数据：

 1.0
BatCodeer
需要GetArrayWides库
GetArrayWideNum、GetArrayWideNum_1标签
定义了GetArrayWideNum标签，用于获得数组维度中的数据个数
用法 call :GetArrayWideNum ArrayName ArrayWide Variable
ArrayName是数组的名称（例如数组array_10_10，名称为array），数组可以是隐式或显式定义
ArrayWide是需返回数据个数的数组维度。数组的维度将保存在Variable变量里
使用本库的时候可以给参数外加上双引号（如"array"），本库会自动处理
使用本库需要保留GetArrayWideNum、GetArrayWideNum_1标签
使用本库需要开启变量延迟以及GetArrayWides库
//**//
:GetArrayWideNum
setlocal enableextensions
call :GetArrayWides "%~1" "AWs"
if %AWs%==0 (
 endlocal
 set "%~3=0"
 goto :EOF
)
if %AWs% lss %~2 (
 endlocal
 set "%~3=0"
 goto :EOF
)
set /a "leftn=%~2-1"
set /a "rightn=%AWs%-%~2"
for /l %%a in (1,1,%leftn%) do set "left=!left!_1"
for /l %%a in (1,1,%rightn%) do set "right=!right!_1"
set /a AWNs=0
:GetArrayWideNum_1
set /a AWNs+=1
if defined %~1%left%_%AWNs%%right% goto GetArrayWideNum_1
endlocal&set /a "%~3=%AWNs%-1"
goto :EOF
复制代码

defanive

大家帮忙多写一点啊，软件是写好了，但是库函数少得不能见人。。。

Batcher

翻译的中文版里面哪个函数在中文系统中会出错？

defanive

有些不适用，而且很多用处也不大。。。。

Batcher

能否举例说明一下哪个不适用？也好让 HAT 去修改一下^_^

defanive

GetOS有问题，网络类的函数没测试，不过估计都是有问题的了。。。

findstr查找的单词是英文的，在中文系统上都换成中文了。。。

Batcher

经测试，GetOS在中文版系统上确实有问题。
HAT已经更新了电子书。
我也重新上传了附件。
感谢分享。

另，网络类的函数没有问题。

defanive

不过网络类的实用价值不大。。。

BBCC

batcher要做双面人啊,囧.

Batcher

对于网管来说，还是有点用的：）

xouou_53320

感谢楼主分享 顶上去

freeback

希望在以后能多增加一些库函数