【练习-039】批处理输出设定范围内的字母

batman

出题目的：
　　掌握将常量字符转划成数字变量的方法
　　掌握随机取值的方法
加分规则：
　　满分10分，视情形加分（以思路为重）
解题限制：
　　此题仅限普通会员作答，技术组和管理层可做解题指导，如贴出代码，则法不容情
题目如下：
　　编写批处理代码，当使用者输入1－26（因为字母有26个）间的任意一个数后，程序在
26个字母中再随机生成一个不等于输入位序上字母的字母（a-z的位序为1－26），最后程序
将这两个字母中的所有字母在一行内列出，示例如下：

请输入1-26中的任意一个数值：18
g和r之间的字母是：hijklmnopq
复制代码

给出参考答案如下：

@echo off
set "code=abcdefghijklmnopqrstuvwxyz"
set /p input=请输入1-26内的任意数值：
:lp
set /a _random=%random%%%26+1,a=_random-input
if "%a:-=%" lss "2" goto lp
if %_random% gtr %input% (
   set /a a=input,b=27-_random,c=a-1,d=_random-1
   ) else (
   set /a a=_random,b=27-input,c=a-1,d=input-1
)
call,set /p=%%code:~%c%,1%%和%%code:~%d%,1%%间的字母是：%%code:~%a%,-%b%%%<nul
pause>nul
复制代码

[ 本帖最后由 batman 于 2009-4-9 00:15 编辑 ]

irresolute

@echo off
setlocal enabledelayedexpansion
set "line=a b c d e f g h i j k l m n o p q r s t u v w x y z"
for %%i in (!line!) do (set /a n+=1 & set _!n!=%%i)
set /a aa=%random%%%26+1
set /p bb=请输入一个0－－26之间的随机数
if !aa! leq !bb! (
for /l %%i in (!aa!,1,!bb!) do set /p =!_%%i! <nul
) else (
for /l %%i in (!bb!,1,!aa!) do set /p =!_%%i! <nul
)
pause>nul
复制代码

batman

楼上的代码还有两个问题：
　　一、会出现aa等于bb的情况，这样没有中间的字母可列。
　　二、没有显示出由输入数确定的字母以及系统随机选择的字母。
程序运行的结果应该如下：

请输入1-26中的任意一个数值：3
c和w之间的字母是：defghijklmnopqrstuv
复制代码

523066680

你再也没给我加过分~     俺做题来了

@echo off
set a=abcdefghijklmnopqrstuvwxyz
set /p inp="输入一个1~26内的数字: "
if %inp% gtr 13 (set /a inp=26-inp-1)
set /a left=inp-1
call,echo,%%a:~%left%,1%% 和 %%a:~-%inp%,1%% 之间的字符是: %%a:~%inp%,-%inp%%%
pause


啊 好象不对  上网时间到了~ 闪

我自己算了算   1楼的 输入 18  应该是 g和t 对应~


哈哈  原来是我没看清题意,  当是个错误示范   扣个分吧~

[ 本帖最后由 523066680 于 2009-2-28 17:14 编辑 ]

irresolute

@echo off
setlocal enabledelayedexpansion
set "line=a b c d e f g h i j k l m n o p q r s t u v w x y z"
for %%i in (!line!) do (set /a n+=1 & set _!n!=%%i)
set /a aa=%random%%%26+1
set /p bb=请输入一个1－26之间的随机数:
if !aa! lss !bb! (set cc=!aa!&set aa=!bb!&set bb=!cc!)
set /a cc=%aa%-%bb%
call set /p=%%_%bb%%%和<nul & call set /p=%%_%aa%%%之间的字母是：<nul
if %cc%==0  (set /p=空<nul) else (
 if %cc%==1 (set /p=空<nul) else (
  set /a a2=!aa!-1
  set /a b2=!bb!+1
  for /l %%i in (!b2!,1,!a2!) do set /p =!_%%i! <nul
)
)
echo.
pause>nul
复制代码

BBCC

@echo off
SetLocal EnableDelayedExpansion
set "var= abcdefghijklmnopqrstuvwxyz"
set /p Get_var=
set bc=%random%%random%%random%
set count=1
:Count
    if %count% lss 27 (
        if "!var:~%count%,1!" equ "!Get_var!" set /a Num1=count
        set /a count+=1
        goto :Count
        )
    set/p,=!Num1! <nul
:GetRan
    set /a Ran=%random%%%26+1
    set/p,=!Ran!<nul
    set /a Tem=Ran-Num1
    if %Tem% lss 0 (set /a n1=Ran+1,n2=Num1-Ran-1) else (if %Tem% gtr 0 (set /a n1=Num1+1,n2=Tem-1) else (goto :GetRan))

:Print
    echo. !var:~%n1%,%n2%!
复制代码

看似简单,其实有点难度...
在获取输入字母的编号时是不是还有什么好方法呢?
嗯...搞了那么久原来搞复杂了...囧.

[ 本帖最后由 BBCC 于 2009-2-28 22:26 编辑 ]

batman

楼上的代码有问题：
    一、没有按要求列出根据输入值得出的字母及程序随机选择的字母
    二、程序运行的结果是!var:~,%n%!（n为程序随机取得的数值）
    三、最后少了pause导致双击就会一闪而过
    四、代码书写不规范，嵌套时应进行代码缩进
    五、代码复杂了

BBCC

re 7
一: 的确是我理解错了题意(我是键入字母)
二:因为理解错的原因所以会有这种结果
三:我是一个cli,一般都是直接在cmd里调用的...所以不加pause
四:是的,那里没怎么改好
五:还是因为一的原因...

terse

for /l 好用不呢
还是直接截位吧

[ 本帖最后由 terse 于 2009-2-28 22:57 编辑 ]

523066680

楼主的代码输入18的时候……

请输入1-26内的任意数值：18
j和z间的字母是：klmnopq

1   该是xx与r之间的
2   即使是z  之间的 rstuvw哪去了？  

谁叫你没鸟我？我就来找漏洞~

[ 本帖最后由 523066680 于 2009-3-1 09:42 编辑 ]

batman

原帖由 523066680 于 2009-3-1 09:33 发表
楼主的代码输入18的时候……



1   该是xx与r之间的
2   即使是z  之间的 rstuvw哪去了？  

谁叫你没鸟我？我就来找漏洞~

呵呵，是改代码时写错一个字符，有一个input写成了_input，感谢兄弟指出，已改正。

BBCC

再来一个

@echo off
SetLocal EnableDelayedExpansion
set "var=abcdefghijklmnopqrstuvwxyz"
set /p Input=Enter a number 

:Get_Ran
    set /a Ran=%random%%%26+1
    set/p,=%Input% %Ran%<nul
    if %Ran% equ %Input% goto :Get_Ran
    if %Ran% lss %Input% (
        set /a N1=%Ran%,N2=%Input%-%Ran%-1
        ) else (
        set /a N1=%Input%,N2=%Ran%-%Input%-1
        )
:Print 
    echo. !var:~%N1%,%N2%!
    pause>nul
复制代码

batman

一、楼上的没有将输入的数值转化为字母并和程序随机选择的字母一起输出
二、同时没有考虑对当两个字母为c d中间无字母的情况的判断和筛选

[ 本帖最后由 batman 于 2009-3-1 23:43 编辑 ]

shqf

楼主，你的代码中for 一句好象多余了呀，去掉，直接set "code=abcdefghijklmnopqrstuvwxyz"就可行了吧。

batman

最近老是搞错，可能真的是老糊涂了。。。

[ 本帖最后由 batman 于 2009-3-1 23:44 编辑 ]