【练习-022】批处理对特殊字符的输出挑战

batman

出题目的：
       1 解决新手们对特殊字符的恐慌问题，增强大家信心
       2 掌握开启变量延迟的时机（技巧）
       3 重温随机取值
加分原则：
       1 思路新颖基分5分
       2 代码高效基分4分
       3 代码简洁基分3分
       4 代码通用基分2分
       5 无临时文件基分1分
       6 完美代码加15分
题目如下：
       要求通过批处理输出10行每行30个由特殊字符随机组成的字符串（见举例）

\<^=|>*)(~$=!$==###"^!!&#*^~')
"^:*\*)>^&:@<%:"^>^'|(^~!)&&|&
%)'(^)$!|~'!%||##(%*):$(!>)%:&
^!"'@\\~$>$*@~:'=='(=)|(^=|&%|
%)'&*'&&&>@^~"*^*||>$~|<!'<%=&
(|"\~**'^@^|))#@%$|^%)|#&**%<"
~)|\!(%:\#%>>#$&<&~!)@~~~=>!'*
|*'&<<$$!\%**:$*'=\"!$&|)#(*|~
#=\@@)<\=!%'(~\)":#<&%"'*!^>&~
:^@^^*>!\~%$%$=\=$>|%$~@"\~&#*
复制代码

[ 本帖最后由 batman 于 2008-9-7 09:49 编辑 ]

vsbat

[code][code][code][code][script]alert('Good!')[/script]
复制代码

[/code][/code][/code][/code]

Taurus

呀 ..... 樓主沒寫要求....

@echo off&more +3 %0
set/p=
<
\<^=|>*)(~$=!$==###"^!!&#*^~')
"^:*\*)>^&<%:"^>^'|(^~!)&&|&
%)'(^)$!|~'!%||##(%*)(!>)%:&
^!"'@\\~$>$*@~:'=='(=)|(^=|&%|
%)'&*'&&&>@^~"*^*||>$~|<!'<%=&
(|"\~**'^@^|))#@%$|^%)|#&**%<"
~)|\!(%:\#%>>#$&<&~!)@~~~=>!'*
|*'&<<$$!\%**:$*'=\"!$&|)#(*|~
#=\@@)<\=!%'(~\)":#<&%"'*!^>&~
:^@^^*>!\~%$%$=\=$>|%$~@"\~&#*

batman

原来我当时没有贴出自己的代码，现在补写一个：

@echo off
set "str=:~!@#$%%&*()_-+={[]}|\:;'<,.>?/^^""
setlocal enabledelayedexpansion
for /l %%a in (1,1,10) do (
  for /l %%b in (1,1,30) do (
    set /a a=!random!%%33
    for %%c in (!a!) do set "var=!var!!str:~%%c,1!"
  )
  echo !var!&set "var="
)  
pause>nul
复制代码

路过

set "dm=:?^~!#$%^&*()='"><|/@\"
@echo off
setlocal enabledelayedexpansion
for /l %%a in (0 1 9) do (
     set text=<nul
     for /l %%i in (1 1 30) do (
          set/a zifu=!random!%%22
          call set zifu=^%%dm:~!zifu!,1%%
          set text=!text!!zifu!
     )
     echo;!text!
)

Demon

@echo off
set "$=!#$%%&'()*+,-./:;<=>?@[\]^_`{|}~""
setlocal enabledelayedexpansion
(for /l %%i in (1, 1, 10) do (
    set "_="
    for /l %%j in (1, 1, 30) do (
        set /a n = !random! %% 32
        for /l %%k in (!n!, 1, !n!) do (
            set "_=!_!!$:~%%k,1!"
        )
        
    )
    echo !_!
)) > 1.txt
pause
复制代码

Seder

命令提示符下运行：

gawk "BEGIN{srand();for(i=0;i<10;i++){for(j=0;j<30;j++){aryRand[0]=int(15*rand()+33);aryRand[1]=int(5*rand()+58);aryRand[2]=int(4*rand()+91);aryRand[3]=int(4*rand()+123);printf(\"%c\",aryRand[int(4*rand())]);}print \"\";}}"
复制代码

若保存为bat,则保存这个：

gawk "BEGIN{srand();for(i=0;i<10;i++){for(j=0;j<30;j++){aryRand[0]=int(15*rand()+33);aryRand[1]=int(5*rand()+58);aryRand[2]=int(4*rand()+91);aryRand[3]=int(4*rand()+123);printf(\"%%c\",aryRand[int(4*rand())]);}print \"\";}}"
复制代码

Seder

回复 10# Batcher


    看错题了

Batcher

回复 9# Seder


test.txt是不存在的

Seder

sed -n p test.txt
复制代码

Hello123World

感觉batman出的题目都太难了，用作挑战题才恰当。

liusen

不错

terse

5# superbat
你这样就试

:~!@#$%^&*()<>"/\|'=;
@echo off
set/p str=<%~fs0 >nul
setlocal enabledelayedexpansion
for /l %%a in (1 1 10) do (
     set "var="
     for /l %%b in (1 1 30) do (
        set/an=!random!%%21
        for %%c in (!n!) do set "var=!var!!str:~%%c,1!"
     )
     echo !var!
)
pause
复制代码

superbat

有个小问题，不用call直接把
set "var=!var!!str:~%n%,1!"
这一句加在随机数的后面怎么不行？把%n%也替换成了！n！，但是出来的是一片片特殊字符，根本没按代码写的按三十个输出。

qq641255849

越搞越糊涂了....

还是回去想想，占个位子...