[文件操作] 检测U盘盘符的批处理可以在XP执行，WIN7不行，什么原因？

xzalabc

插入U盘，winxp系统可以检测到盘符是H盘，WIN7提示“检测完毕！没有检测到U盘存在！请手工输入U盘盘符”

echo 正在检测您系统中的可移动设备
setlocal enabledelayedexpansion
for /f "skip=1 tokens=1,2 delims=\" %%i in ('fsutil fsinfo drives^|find /v ""') do (
    set genre=%%i
    set genre=!genre:~-2!
    for %%a in (!genre!) do (
        fsutil fsinfo drivetype %%a | findstr "移动" >nul 2>nul && if /i not "%%a"=="A:" (
            set drive=%%a
            echo.
            echo 找到可移动存储设备, 盘符为%%a 。
         echo.
            echo 正在处理U盘隐藏文件,该过程时间会持续几秒，视您U盘速度以及隐藏文件个数决定...
            echo.
            !drive!
            cd\
            attrib /s/d -r -h -s -a *.* >nul 2>nul
            call :go
        )
    )
)
cls
echo 检测完毕！没有检测到U盘存在！请手工输入U盘盘符
echo.
pause
复制代码

flyinnet9

wmic LOGICALDISK get Description,DeviceID|find "移动"

xzalabc

回复 2# flyinnet9


    怎么检测到是系统盘呢

xzalabc

WIN7还是提示“检测完毕！没有检测到U盘存在！请手工输入U盘盘符”

flyinnet9

@echo off
for /f "tokens=2 delims= " %%a in ('wmic LOGICALDISK get Description^,DeviceID^|find "移动"') do echo.移动设备的盘符是：%%a
pause
复制代码

aa77dd@163.com

wmic LOGICALDISK WHERE DriveType=2 get DeviceID
复制代码

terse

@echo off
for /f %%i in ('wmic LOGICALDISK WHERE "DriveType=2" get DeviceID^|find ":"') do set u=%%i
echo;%u%
echo 系统盘 %windir:~,3%
pause
复制代码

pcl_test

@echo off
for %%a in (A B C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if exist %%a:\ (
        fsutil fsinfo drivetype %%a:|findstr /i "移动 Removable" >nul&&(
            echo;找到可移动存储设备, 盘符为%%a 。
        )
    )
)
pause
复制代码