[文本处理] [已解决]批处理set替换字符时如果str2是变量那该怎么办？

lj84831253

set %PATH:str1=str2%
如果上面的str2是变量那该怎么办呢？唉自己搞了好久。所以只好来求大家了~
已经解决了，谢谢好心人！！

[ 本帖最后由 lj84831253 于 2010-4-17 22:16 编辑 ]

GNU

call set str=%%str:%str1%=%str2%%%
复制代码

hanyeguxing

给你写个示例：

@echo off&setlocal enabledelayedexpansion
set a=!windir:%systemdrive%=%username%!
echo.%a%
pause
复制代码

lj84831253

@echo off
setlocal enabledelayedexpansion
for /f %%c in (1.txt) do (
set /a N+=1
set /a M=!N!+1
for /f "delims=" %%d in (html.html) do (
set d=%%d
set -i d=!d:WML=!N!!
set -i d=!d:HTML=!M!!
echo !d! >> !N!.html
)
)
pause
复制代码

能帮我看下我这个错在哪里吗？

hanyeguxing

set -i d=!d:WML=!N!!
set -i d=!d:HTML=!M!!

应该写成

call set d=%%d:WML=!N!%%
call set d=%%d:HTML=!M!%%
复制代码

set中没有-i这个参数

lj84831253

还是不行，，我还是把我做的发上来给大侠们看看吧！~后缀是rar的。请你看一下。

hanyeguxing

从语法上讲，该这样写：

@echo off
for /f %%a in (1.txt) do (
set /a N+=1,M=N+1
for /f "delims=" %%b in (html.html) do (
set "d=%%b"
setlocal enabledelayedexpansion
call set "d=%%d:WML=!N!%%"
call set "d=%%d:HTML=!M!%%"
>>!N!.html echo.!d!
Endlocal))
pause
复制代码

但这样会把“url=HTML.html">” 中后面的html也替换，也把如“</html>”这些也替换了，所以，如果你只想替换HTML.html中前面的HTML的话：

@echo off
for /f %%a in (1.txt) do (
set /a N+=1,M=N+1
for /f "delims=" %%b in (html.html) do (set "d=%%b"
setlocal enabledelayedexpansion
call set "d=%%d:WML.wml=!N!.wml%%"
call set "d=%%d:HTML.html=!M!.html%%"
>>!N!.html echo.!d!
Endlocal))
pause
复制代码

如果想用call来扩展变量，那么call 的变量名不能与for扩展的变量名有重叠！

[ 本帖最后由 hanyeguxing 于 2010-4-17 21:01 编辑 ]

lj84831253

学过Linux，我知道sed可以呵呵，但我就是不明白为什么我那样不行呵呵，而且现在学批处理，就想把所有不懂的都了解一下，我这人比较钻牛角尖，呵呵。那看来只能sed了，，，

hanyeguxing

重新看我给你改过的，明白了没？

lj84831253

原帖由 hanyeguxing 于 2010-4-17 20:39 发表
从语法上讲，该这样写：@echo off
for /f %%a in (1.txt) do (
set /a N+=1,M=N+1
for /f "delims=" %%b in (html.html) do (
set "d=%%b"
setlocal enabledelayedexpansion
call set "d=%%d:WML=!N!%%"
call ...

set加个 -i  参数就可以指定大小写替换字符串了。先谢谢你，代码我研究下。比较笨呵呵。

hanyeguxing

原帖由 lj84831253 于 2010-4-17 21:03 发表
set加个 -i  参数就可以指定大小写替换字符串了。先谢谢你，代码我研究下。比较笨呵呵。

你的是什么操作系统？应该不是xp的吧。。。

lj84831253

原帖由 hanyeguxing 于 2010-4-17 21:05 发表

你的是什么操作系统？应该不是xp的吧。。。

是XP SP2深度简化版

lj84831253

我测试成功了。再问个问题，>>!N!.html echo.!d!   这样也行呀？第一次看到。。见识了呵呵！~还有啊，set前面加个call是什么意思呢？我刚学批处一个礼拜呵呵，关于call的我还没去看。

lj84831253

你是SP3的，可能区别在这吧。

hanyeguxing

这里是用call再扩展。。。。

奇怪，我的系统set怎么没这个增强呢？

呼叫：有没有其他人的系统里set支持-i这个参数的？

解决完问题，请把标题前修改加上[已解决]

[ 本帖最后由 hanyeguxing 于 2010-4-17 21:28 编辑 ]