[问题求助] [已解决]VBS脚本怎样把Excel中的多个sheet转换成一个txt？

gawk

我找到一个把每个sheet单独转换成一个txt的，但是我想把一个Excel文件里面的所有sheet全部转换到一个txt，怎么办？
http://www.bathome.net/thread-10806-1-1.html

gawk

回复 6# cutebe


    测试成功，多谢。

cutebe

'将 XLS 文件拖到此 VBS 中，将生成同名 TXT 文本文件。
Filename = WScript.Arguments(0)
Set ExcelApp = CreateObject("Excel.Application")
Set ExcelOut = ExcelApp.Workbooks.Open(Filename)
If LCase(Right(Filename,4))=".xls" Then
    RowC = ExcelOut.WorkSheets(1).UsedRange.Rows.Count
    For i = 2 to ExcelOut.WorkSheets.Count
        ExcelOut.WorkSheets(i).UsedRange.Copy
        ExcelOut.WorkSheets(1).Range("A" & RowC + 1).PasteSpecial
        RowC = RowC + ExcelOut.WorkSheets(i).UsedRange.Rows.Count
    Next
    ExcelOut.WorkSheets(1).SaveAs Left(Filename,instrrev(Filename,".")) & "TXT",3
End If
ExcelOut.Saved = True
ExcelOut.Close
Wscript.Quit
复制代码

gawk

回复 3# Demon


不想生成几十个临时文件，觉得不够优雅。

gawk

回复 2# powerbat


报错信息如下：
c:\Test>cscript //nologo test.vbs >a.txt
c:\Test\test.vbs(12, 5) Microsoft JET Database Engine: Too many fields defined.

我的xls文件里面有几十个sheet，是不是因为东西太多了？

Demon

单独转后合并不就行了

powerbat

xls = "C:\Users\root\Desktop\1.02战法数据表.xls"

strConnect = "Provider=Microsoft.Jet.OLEDB.4.0;" & _
    "Data Source=" & xls & ";Extended Properties=""Excel 8.0;HDR=no;IMEX=1;"";"

Set AdoCnn = CreateObject("ADODB.Connection")
AdoCnn.Open strConnect
Set rs = AdoCnn.OpenSchema(20)
Do Until rs.EOF
    tbl = rs.Fields("table_name")
    s = s & tbl & vbCrLf & String(40,"-") & vbCrLf
    s = s & AdoCnn.Execute("select * from [" & tbl & "]").GetString(2)
    s = s & String(80,"=") & vbCrLf & vbCrLf
    rs.MoveNext
Loop
AdoCnn.Close
WScript.Echo s
复制代码