[原创] 批处理for命令/f参数通俗讲解

随风

for /f  参数详解
:: by 随风  @bbs.bathome.net  2007-11-15
for命令 在dos命令中,不算最复杂的也应该算是相当复杂的了,
而for的参数中又以 /f 参数最为复杂,难懂和常用.
在刚学时确实费了我不少脑筋,下面就我个人的理解,给新手们通俗的讲讲,也好让新手少走些弯路.
格式:
::例一:

for /f "skip=1 tokens=1,2* delims= " %%a in (a.txt) do echo %%a %%b %%c
pause
复制代码

先从引号内的东西讲起,很多新手对这些难以理解,因为 for /? 翻译的简直是一塌糊涂.
skip=
tokens=
delims=
这三项是用的最多的,根据需要.可以不用,可以一起使用,也可以只使用一个或两个.
但是不管使用几个都要用引号将它们扩起来.当然不使用时,自然就不需要引号了.
skip=
for循环文本内容是以行为单位,从上至下进行的,skip=1意识就是跳过文本的第一行,即不循环第一行
那么skip=2 自然就是跳过前两行了,依次类推.........
delims=
先讲这句
delims=后面的字符的意识是,将文本每一行的内容以delims=后面的字符分割成若干列.
假设a.txt某一行的内容是 111,222.333 444/555
我们用下面的语句
::例二:

for /f "tokens=1-5 delims=,./ " %%a in (a.txt) do echo %%a %%b %%c %%d %%e
pause
复制代码

显示结果是 111 222 333 444 555
解释:
  意识就是把111,222.333 444/555以,./和空格(不分先后)分成了5列.注意代码中/和"后面有个空格,
  使用中要注意空格要放到最后,如"delims=,. /" 这样就不行了.
那如果我们不使用逗号来分割会如何呢?如: "delims=./ "那么就会分割成111,222 333 444 555
看出区别了吗?delims=后面可以是多个字符,可以是空格,也可以什么都没有.
什么都没有代表什么呢?就是不以任何东西为分割符,也是整行的内容了.
因为for默认是以,;和空格作分割符的,
所以一般要取得整行内容通常会用"delims="这样的形式来取消for的默认分割符.
tokens=
tokens=1-5
1-5很好理解就1至5,前面我们用delims=后面的字符为分割符,将文本内容分成了多列,那么你需要的是哪些列呢?
用tokens=可以很好帮你提取到.
还是以例二为例:
通过dilims=,./  将文本分成了111 222 333 444 555 五列.
注意代码中前面有个%%a 这里的%%a就是代表第一列,第二列就是%%b,第三列就是%%c 依此类推.....
那么我们如果把echo %%a %%b %%c %%d %%e 改为 echo %%e %%d %%c %%b %%a 会如何呢?
当然.会显示 555 444 333 222 111
如果是:echo %%b %%d 又会显示什么呢?  不用我说了吧!
若是第一个%%a把它改为%%i也是一样,那么第二列就是%%j...%%k...依此类推....
明白了?就是按英文字母的顺序依此类推的.
这里我们用的是tokens=1-5但是在例一中,我们用的是tokens=1,2* 有什么区别呢?
其实差不多-号代表从几至几而逗号代表单一的,如 tokens=1,5就是代表第一列和第五列,而不是1至5列.
*号代表剩下的所有的列.如:tokens=1,2*代表%%a为第一列,%%b为第二列,%%c代表后面所有的列.
for /f 不但可以循环文本内容还可以循环字符窜,如:
::例三:

for /f "tokens=1-3 delims=,./ " %%a in ("111,222.333 444/555") do echo %%a %%b %%c
pause
复制代码

只要将()里的字符串用引号扩起来,for就会把它当字符串来循环,而不是文本.

秀才

这个教程确实相当的清晰明了
本以为会很麻烦的，楼主讲的很好

littlebird

简单明了，很好的

wdh123

回复 1# 随风


    详细，这课上的好。吸收了

Bat_s

如果分割符不是字符，而是字符串，该怎么写delims呢？
比如 aaabbcccbbdddbbeee
要分割为:
aaa
ccc
dd ...
xiaoxx 发表于 2008-4-25 16:07

==================
@echo Off
rem 将文本中的字符“aaabbcccbbdddbbeee”提出为aaa  ccc ddd eee
echo aaabbcccbbdddbbeee>a.txt
setlocal enabledelayedexpansion
for %%i in (a.txt) do (
        set /p str=<%%i
        set str=!str:bb=:!
        for /f "delims=: tokens=1-4"  %%a in ('echo !str!') do echo %%a %%b %%c %%d  
)
if exist a.txt del a.txt
pause

Colin3

浅显易懂，非常好的教程帖子，感谢楼主

sanboo2007

感谢分享....

cjiabing

如果分割符不是字符，而是字符串，该怎么写delims呢？
比如 aaabbcccbbdddbbeee
要分割为:
aaa
ccc
dd ...
xiaoxx 发表于 2008-4-25 16:07

    delims用作分隔符的似乎只有字符本身，而非具有特定特征的字符串，设置"delims=a"和设置“delims=aaa”的结果应该是一致的。
如果确实要将以上字符串分割，如果比较有规律的话可以使用set的截取功能。如果比较随机，也可以使用set的替换功能。

bclcc

自己的学习整理，不知道怎么样~

xuhuoren

回复 37# WUYAN520


    对于这种很长但是很有规律的字符串，总不能每次数一下位置再用set分割吧

xuhuoren

15楼没有人回答么？

feelinglove

我想我是看懂了，深入一点又很迷茫，是DOS不熟练呢，还是……

yefeng007520

学习，回复支持，感谢楼主分享。。。。

jackmux

基本每天都来看一下 学习一下

lxwlt

::例三:
for /f "tokens=1-3 delims=,./ " %%a in ("111,222.333 444/555") do echo %%a %%b %%c
pause
显示结果为：
111 222 333
wangmz5908 发表于 2008-12-4 08:45

tokens=1-5 后面少了几个显示参数，在加个%%d %%e就显示完了