[文件操作] [已解决]批处理按照顺序合并PDF 文件

feiyan

1.在当前目录有多个文件夹，每个文件夹内有多个PDF 文件。
2.想把每个文件内的多个pdf 文件合并成一个pdf,存在在这个文件夹内，用这个文件夹名来命名这个合并PDF 文件。

举例，文件夹名称：S123     包含（1.pdf, 2.pdf, 3.pdf, 4.pdf,5.pdf)等多个pdf 文件，要求合并后文件名称是S123,
在当前目录下，这样类似的文件夹有多个。

ailier532

回复 58# 77七


    通过改环境变量搞定，测试成功！膜拜大佬！非常感谢！！！

77七

回复 57# ailier532




参考 https://jingyan.baidu.com/article/b907e627b5b4b707e7891cc1.html 添加到环境变量

或者写明 pdftk.exe 的路径，多处pdftk都要修改，
如

"d:\pdftk\pdftk.exe" *.pdf cat output "%~dp0%%~nxd.pdf"
复制代码

ailier532

回复 56# 77七


    pdftk'is not recognized as an
internal or external command,
operable program or batch file.
我把PDFTK放在BAT一个目录下的啊

77七

回复 55# ailier532

遍历批处理文件所在目录下所有文件夹，添加书签后合并，删除源文件、及添加书签后的文件、空文件夹。使用前先备份。

@echo off
chcp 65001 >nul
rem 批处理保存为utf-8编码格式
cd /d "%~dp0"
rem 仅给无书签的pdf文件添加文件名作为书签(part) ，所有文件添加（all）
set "c=all"

for /d %%d in (*) do (
	if exist "%%d\*.pdf" (
		pushd "%%d"
		for /f "delims=" %%i in ('dir /b /a-d *.pdf') do (
			pdftk "%%i" dump_data_utf8 output >$
			setlocal
			if /i "%c%" equ "all" (
				call :1 "%%i"
			) else if /i "%c%" equ "part" (
				find "BookmarkTitle:" <$ 1>nul || call :1 "%%i"
			)
			endlocal
		)
		pdftk *.pdf cat output "%~dp0%%~nxd.pdf"
		rem 删除pdf
		del *.pdf 2>nul
		del $;report.txt 2>nul
		popd
		rd "%%d" 2>nul
	)
)
pause & exit

	:1
	for /f "tokens=1* delims=[]" %%a in ('find /n "NumberOfPages: " ^<$') do (
		set #%%a=1
	)
	(for /f "tokens=1* delims=[]" %%a in ('find /n /v "" ^<$') do (
		echo=%%b
		if defined #%%a (
			echo BookmarkBegin
			echo BookmarkTitle: %~n1
			echo BookmarkLevel: 1
			echo BookmarkPageNumber: 1
		)
	))>report.txt
	pdftk "%~1" update_info_utf8 report.txt output $.pdf
	move $.pdf "%~1"
	exit /b
复制代码

ailier532

回复 45# 77七


    第二段代码是给PDF文件以文件名添加书签用的，但是还是要每一个文件夹去复制粘贴并运行一次，能不能将两段代码合并成一个，实现自动添加标签自动合并？
请大佬帮帮我，万分感谢！！

佛笑崖

回复 53# 77七


    大佬实在太牛了，解决了痛点

77七

回复 52# yilianqiumeng


  

@echo off
rem 批处理保存为ansi编码格式
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /b /ad') do (
    pushd "%%i"
    echo 正在处理文件夹：%%i
    "d:\新建文件夹\pdftk.exe" *.pdf cat output "%%~nxi.pdf"
    popd
)
pause
复制代码

可能你的path的路径没设置对吧，修改了下5楼代码，在代码中直接写pdftk路径，自行修改为实际路径，批处理文件放在 “当前目录”下

yilianqiumeng

回复 51# 77七


   我的问题和他的一样的：就是一键把每个文件夹内的pdf文件合并起来，手动合并太慢了！请大神指教！谢谢

1.在当前目录有多个文件夹，每个文件夹内有多个PDF 文件。
2.想把每个文件内的多个pdf 文件合并成一个pdf,存在在这个文件夹内，用这个文件夹名来命名这个合并PDF 文件。
举例，文件夹名称：S123     包含（1.pdf, 2.pdf, 3.pdf, 4.pdf,5.pdf)等多个pdf 文件，要求合并后文件名称是S123,
在当前目录下，这样类似的文件夹有多个。

77七

回复 50# yilianqiumeng


   请完整描述一下需求吧，不知道你具体需要怎么合并

yilianqiumeng

回复 49# 77七


    不行，我用了5楼的代码也只是运行pdftk软件，不会自动合并的。请大神看看有没有别的方法吧？给指导一下！谢谢

77七

回复 48# yilianqiumeng


   你用的哪一楼的代码？我写的只是满足了楼主的按顺序要求，你试一下4、5楼站长的代码

yilianqiumeng

回复 21# 77七


    大神，我用批处理合并pdf文件，合并不了啊，只是运行了pdftk软件，不能自动合并啊？

yilianqiumeng

我试了一下，不行啊?只是把pdftk软件运行打开了，它不会自动合并pdf文件呀？请大神看看是什么原因？

feiyan

回复 45# 77七 感谢，程序测试OK