[文本处理] 【已解决】批处理如何把文本结果竖排变横排？

freesoft00

mountvol|find ":\"
执行的结果是

C:\
D:\
E:\
F:\
K:\
复制代码

如何让这些结果文本横排显示，在一行显示，再者，如何去除后面的:\只显示盘符

如何把结果作为下一步执行的变量，类似下面（下面的批处理不正确，我只是表达意思）
for %%a in （mountvol|find ":\"） do （
echo %%a
）

bailong360

@Echo Off
For /F "Delims=: " %%i in ('mountvol^|find ":\"') Do If Not "%%i:"=="%~d0" Set /P =%%i <nul
Echo;
For /F "Delims=: "  %%i in ('mountvol^|find ":\"') Do If Not "%%i:"=="%~d0" Echo %%i
复制代码

已修改

freesoft00

另外一个要求是，列出来当前的盘符后，如何用命令过滤掉当前的盘符，盘符是从a到z的吧，过滤掉当前有的，然后取第一个当前系统中没有的盘符作为变量显示出来。

freesoft00

回复 2# bailong360


     第一个是横排显示的，是否可以去掉:\

pcl_test

回复 3# freesoft00

@echo off
setlocal enabledelayedexpansion
set "str=CDEFGHIJKLMNOPQRSTUVWXYZ"
for /f "tokens=1* delims=: " %%a in ('mountvol^|find ":\"') do set "s=!s!%%a "
echo,!s!
for %%i in (!s!) do set "str=!str:%%i=!"
echo !str:~,1!
pause
复制代码

freesoft00

ok了，谢谢各位的热心！

freesoft00

另外一个命令

fsutil fsinfo drives执行的解决是横排，

驱动器: C:\: D:\  E:\  F:\
复制代码

同样也是，把上面的结果作为变量参数传递到下面的命令执行，下面的命令比如是echo吧，上面的运行结果中有一个驱动器:是需要去掉的。

freesoft00

比如我要执行fsutil fsinfo drives列出来本地硬盘，然后把执行后的结果作为盘符变量
执行后面的格式化命令
format %str%

pcl_test

回复 9# freesoft00

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1*" %%a in ('fsutil fsinfo drives ^|find ":\"') do (
for %%i in (%%b) do set a=%%i & echo format !a:~,2!
)
pause
复制代码

freesoft00

回复 10# pcl_test


    thank you！

freesoft00

回复 10# pcl_test


    再请教：

@echo off
setlocal enabledelayedexpansion
for /f "delims=\" %%i in ('fsutil fsinfo drives^|find /v ""') do (
set var=%%i
set drive=!var:~-2!
fsutil fsinfo drivetype !drive!|find "驱动器">nul&& echo !drive!

)
pause
复制代码

这段在xp下面没有问题，而在win7下面只有一个盘符A（我的系统中有A盘）

bailong360

@Echo Off
For /F "Skip=1" %%i In ('Wmic LogicalDisk Where DriveType^="3" Get Caption') Do Echo Format %%i
复制代码

感觉Wmic在这个时候要好用一点

freesoft00

回复 13# bailong360
Format C:
Format D:
Format E:
Format


   
结果中多了一行后面没有盘符的format
另外，wmi在pe中有很多不支持，而其它的方法只要pe中有文件比较好实现

bailong360

回复 14# freesoft00


    第一个问题只要加上2>nul就行了

不支持wmi这倒是没想到...

pcl_test

回复 12# freesoft00
你这个代码本身就只是列出一个盘符，有什么问题？