【练习-002】批处理查找字符数最多的文本行

batman

有文本a.txt如下：

aaaaaaa                                 aaaa bbbbbb ccccccccccc dddd
aa  aaaaaaa bbbbbbbb cccccccccc ddddddddddddd eeeeeee
     aaaaaaaaaaaa bbbbbbbbbbb cccccccccccccccccccc
                aaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaaa aa
                    aaaaaaaaaaaaaaaaaaaaaaaaaaaa bbbbbbbbbb
aaaaaaaaa        ccccccccc bbbbbbbbbbbbb               ddddddddddddddddd
复制代码

通过批处理查找出文本中字符数(不含空格)最多的行并输出，很明显就是

aaaaaaaaa        ccccccccc bbbbbbbbbbbbb               ddddddddddddddddd
复制代码

要求：
1 不生成临时文件
2 代码简洁，高效，通用性好
3 加分仍以思路为重

----------------------------------------------------------------------------------------------------------------------------------------------------
至目前已有解决方案：见3楼浅默和4楼本人的方案，期待更多方案的出现。







[ 本帖最后由 batman 于 2008-7-27 23:58 编辑 ]

pusofalse

这题还要输出最多的字符在第几行吗？
如果是，包含空行吗？

浅默

@echo off
Setlocal Enabledelayedexpansion
set n=0
for /f "delims=" %%i in (a.txt) do (
      set "ke=%%i"
      set ke1=!ke: =!
      set m=0
      call :1                  
)
echo %wang%
pause
goto :eof
:1
  if not "!ke1:~%m%,1!"=="" set /a m+=1&goto 1
  if %m% gtr %n% set n=%m%&set wang=%ke%
  goto :eof

batman

下面给出本人的方案一：

@echo off
set num=0
for /f "delims=" %%i in (a.txt) do  set "str=%%i"&call,set "str=%%str: =%%"&call :lp "%%i"
call,echo %%_%num%%% %num%个字符
pause>nul&goto :eof
:lp
set "str=%str:~1%"&set /a n+=1
if defined str goto lp
if %n% geq %num% set "num=%n%"&set "_%num%=%~1"
set "n=0"
复制代码

[ 本帖最后由 batman 于 2008-7-26 18:25 编辑 ]

pusofalse

原帖由 batman 于 2008-7-26 08:19 发表
下面给出本人的方案一：@echo off
set num=0
for /f "delims=" %%i in (a.txt) do  set "str=%%i"&call,set "str=%%str: =%%"&call :lp "%%i"
call,echo %%_%num%%% %num%个字符
pause>nul&goto :eof
:lp
set  ...

有一点小错误，加完分才看出来。变量%%_%num%%是字符数最多的行，没有进行条件约束而每次都赋值给它，导致输出的字符数正确，行的内容却每次都是最后的那一行。

batman

确实如此，粗心了，谢谢兄弟指出。

namejm

　　可以考虑 findstr /o 方案。

/O        在每个匹配行前打印字符偏移量。

batman

原帖由 namejm 于 2008-7-30 10:59 发表
　　可以考虑 findstr /o 方案。

思路是对的，但实施起来还真的有点麻烦：

@echo off&setlocal enabledelayedexpansion
set "max=0"
for /f "delims=" %%i in (1.txt) do set "str=%%i"&echo !str: =!>>2.txt
echo end>>2.txt
for /f "tokens=1* delims=: " %%i in ('findstr /o .* 2.txt') do (
    set /a n+=1&set "_!n!=%%i"&set ".!n!=%%j"
    set /a m=n-1
　　if !m! geq 1 call :lp
)
echo.&echo 字符数最多的行为：!a%max%!
echo.&echo 　　　　字符数为：%max%个   
del /q 2.txt&pause>nul&goto :eof
:lp
set /a num=_%n%-_%m%-2
if %num% gtr %max% set "max=%num%"&set "a!max!=!.%m%!"
复制代码

keen

太复杂了，想办法优化：

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in (a.txt) do (
    set v=%%i
    set n=0
    set /a m+=1
    call :lp
    set _!m!=!n!#%%i
)
set max=0
call :next
for /f "tokens=1 delims=#" %%a in ("!var!") do (
        set s=%%a
        if !s! gtr %max% set max=!s!
)
call :next
for /f "tokens=1,2 delims=#" %%a in ("!var!") do (
        if %%a==%max% echo %%b
)
pause&exit/b

:next
for /l %%i in (1 1 %m%) do (
    set c=%%i
    call,set var=%%_!c!%%
)
goto :eof

:lp
    if "!v:~0,1!" neq " " set /a n+=1
    set v=!v:~1!
    if "!v!" neq "" goto lp
goto :eof
复制代码

batman

回复楼上：
兄弟看来是特有求知欲和动手欲的，这么老的练习贴子也让你翻到了，还做了解答，呵呵，加油。。。

keen

只能优化成3楼的了：

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in (a.txt) do (
    set v=%%i
    set /a max=0,n=0,m+=1
    call :lp
    if !n! gtr !max! set max=!n!&set xx=%%i
)
echo %xx%&pause&exit/b

:lp
    if "!v:~0,1!" neq " " set /a n+=1
    set v=!v:~1!
    if "!v!" neq "" goto lp
goto :eof
复制代码

keen

我是新手，刚从新手训练营出来。
我从新手训练营出来后，就迷失方向了，不知道怎么继续学批处理了，我把论坛挨个翻了一遍，又发现在这一块，有好多题。
我就继续练下去。
请batman多多指教！

batman

呵呵，这块确实是很多人没有注意到的，如果说学批处理有速成班的话，这块就算是的吧。。。
祝兄弟学得开心并学有所成，本人将尽一切能力帮助学习批处理的新人们。

everest79

@echo off
for /f "delims=" %%a in (1.txt) do (
for %%b in (%%a) do call :xxx "%%b"
call :yyy
)
for /f "tokens=2,3 delims=_=" %%i in ('set l_^|sort /+4') do set msg=最长的行为:%%i  长度为:%%j
echo %msg%
pause
goto :eof


:xxx
set "lines=%lines%%~1"
goto :eof

:yyy
set /a x+=1
for /f "skip=1 delims=:" %%i in ('^(echo "%lines%"^&echo.^)^|findstr /o ".*"') do set/a l_%x%=%%i-5
set lines=
goto :eof
复制代码

只处理这个文本

tireless

@echo off
set max=0
for /f "tokens=*" %%a in (a.txt) do (
  if "%%a" neq "" call :ready "%%a"
)
echo 第 %strline% 行字数最多，共 %max% 个字符:&echo.&echo %str%&echo.
pause & exit /b

:ready
set var=%~1
set var=%var: =%
set /a n=0,line+=1

:lp
set fifteen=%var:~,15%fedcba987654321
set /a n+=0x%fifteen:~15,1%
if "%var:~15%" neq "" set "var=%var:~15%" & goto lp
if %n% gtr %max% set /a "max=n,strline=line" & set str=%~1
复制代码