[文件操作] [分享]批处理按照年和月把图片分类移动到子文件夹

Batcher

【问题描述】

寻找2021年1月的截图放到 时间轴\2021年\2021年01月\N截图202101
截图关键字screenshot
时间范围201501-202301
说白了我就说想吧每个月（2015年-2023年）的截图找出来放到每个文（2015年-2023年）件夹里

qixiaobin0715

@echo off
for /f "delims=" %%a in ('dir /b /s /a-d *.jpg *.png') do (
    for /f "tokens=1,2 delims=/" %%i in ("%%~ta") do (
        if not exist "..\时间轴\%%i年\%%i年%%j月\N截图%%i%%j" (
            md "..\时间轴\%%i年\%%i年%%j月\N截图%%i%%j"
        )
    )
    move "%%a" "..\时间轴\%%i年\%%i年%%j月\N截图%%i%%j\"
)
pause
复制代码

Batcher

【解决方案】

请参考Q-04把bat文件保存为ANSI编码：
https://mp.weixin.qq.com/s/Koje4FufWxWBs7ioDy_LJA

test-1.bat

@echo off
set "StartYear=2015"
set "EndYear=2023"
setlocal enabledelayedexpansion
for /l %%y in (%StartYear%,1,%EndYear%) do (
    for /l %%m in (1,1,12) do (
        set "ThisMonth=%%m"
        if %%m lss 10 (
            set "ThisMonth=0%%m"
        )
        echo 正在处理：%%y年!ThisMonth!月
        set "NewFolder=..\时间轴\%%y年\%%y年!ThisMonth!月\N截图%%y!ThisMonth!"
        if not exist "!NewFolder!" (
            md "!NewFolder!"
        )        
        for /f "delims=" %%i in ('dir /b /s /a-d *.jpg *.png 2^>nul ^| findstr /c:"%%y!ThisMonth!" /c:"%%y-!ThisMonth!"') do (
            move "%%i" "!NewFolder!"
        )
    )
)
pause
复制代码