[文本处理] 【已解决】请教批处理备份压缩上个月的文件及延时的方法

ztxby

你好,服务器上有这样的目录比较复杂,我通过搜索和查看帮助文档还是不能解决,于是请教各位的帮助


如果有以下目录,假如我想备份F:/AAA1/2009/03 目录下03的文件夹打包压缩至F:/bak 目录下并改名为AAA1[03].rar(其中AAA1是自动调用F:/AAA1这个目录)  一个比较复杂的问题,就是目录下面的F:/AAA1/2009/03   的"03"文件夹是一个月份文件,假如这个月是4月,就会让批处理自动压缩上个月以03文件夹的压缩处理
因为文件比较大压缩起来会要一些时间,所以我要它等待30分钟后,又备份另外一个目录即F:/AAA2/2009/03 目录下的03文件夹打包压缩至F:/bak 目录下并改名为AAA2[03].rar
然后以此类推备份:
F:/AAA3/2009/03 => F:/bak/AAA3[03].rar
30分钟后备份
F:/AAA4/2009/03 => F:/bak/AAA4[03].rar
30分钟后备份
F:/AAA5/2009/03 => F:/bak/AAA5[03].rar
30分钟后备份

由于对变量及调用目录的不了解,所以促使我无法下手,请大家帮忙指明一下思路,谢谢!

[ 本帖最后由 ztxby 于 2009-4-13 09:23 编辑 ]

ztxby

自己顶一下,谢谢!!!

Batcher

@echo off
rem 请根据自己的实际情况修改WinRAR的路径
set rarPath=C:\Program Files\WinRAR
rem 假设系统日期格式是yyyy-mm-dd
set ThisYear=%date:~0,4%
set ThisMonth=%date:~5,2%
set ThisDay=%date:~8,2%

call :DateToDays %ThisYear% %ThisMonth% %ThisDay% ThisDays
set /a DstDays=%ThisDays%-1%ThisDay%+100
call :DaysToDate %DstDays% DstYear DstMonth DstDay

for /l %%a in (1,1,5) do (
  "%rarPath%\rar.exe" a "D:\bak\AAA%%a[%DstMonth%].rar" "D:\AAA%%a\%DstYear%\%DstMonth%"
  ping -n 1800 127.1 >nul
)
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF
复制代码

ztxby

谢谢 Batcher的鼎力帮助,我先细细研究这段代码!

ztxby

还有几个问题想请教下,就是压缩AAA5之后的目录,它还会不会继续压缩AAA6的文件夹呢?

这段代码如果Batcher兄能加上稍许的注释就太好不过了,谢谢!

Batcher

不会。如果想让它继续，就自己修改一下那个for循环。

哪句不懂，就问哪句，有很多热心人会告诉你答案；如果全部不懂，建议先去教学区学习基础教程，这样才能更快的掌握批处理。

ztxby

恩 谢谢! 我会研究不懂的代码