[网络连接] 批处理能写添加IE代理的代码吗？

sexfio

就是ie浏览器,自动加个代理比如66.66.66.66 断口8080
怎么写？？批处理 VBS都行

我要单机拨号连接的代理，不是区域网！！！！！！

[ 本帖最后由 sexfio 于 2009-4-24 09:22 编辑 ]

Batcher

@echo off
rem 设置代理地址
set ProxyAddr=192.168.0.1
rem 设置代理端口
set ProxyPort=8080
reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyEnable /t REG_DWORD /d 1 /f
reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings" /v ProxyServer /d %ProxyAddr%:%ProxyPort% /f
rem 重启IE使代理生效
taskkill /f im iexplore.exe
start iexplore.exe bbs.bathome.net
复制代码

tireless

经测试，无效。

可以先导出 HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Connections，然后手工设置代理后，再导出。

Batcher

能说说你的详细测试步骤么？我明天到公司按照你的步骤测一下。

tireless

2楼的代码我测试过多次，是无效的。

因为 HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Connections 下的值是二进制的，批处理没办法修改吧。所以可以先手工设置ie代理，然后把这个项导出来，下次要切换时再导入......

这个代理可以访问： 88.191.62.207，端口 3128
要翻墙的网站： http://psydk.org/PngOptimizer.php

[ 本帖最后由 tireless 于 2009-4-23 00:45 编辑 ]

lxzzr

wmic path win32_proxy Where ServerName='jin224' call setproxysetting "8080","192.168.1.59"
复制代码

一个例子而已

[ 本帖最后由 lxzzr 于 2009-4-23 01:52 编辑 ]

tireless

原来 2 楼和 6 楼设置的是局域网的代理，对于拨号连接用户无效。

sexfio

是啊，实验了，是局域网的代理
怎么写拨号连接的代理呀

Batcher

你到底要设置什么代理？请在顶楼更新需求！

forkxj

是啊，怎么写啊，我好想知道啊，我百度了十几天都没有找到啊啊啊啊啊啊啊

Batcher

能把你的IE选项中“连接”选项卡的内容截图贴出来看看么？

everest79

原帖由 tireless 于 2009-4-23 00:37 发表
2楼的代码我测试过多次，是无效的。

因为 HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Connections 下的值是二进制的，批处理没办法修改吧。所以可以先手工设置ie代理，然后 ...

 
@echo off
setlocal enabledelayedexpansion
::3c标 01计数器  03(01)是(否)启用代理 FF行偏移量&h10(ip+prot字符串长度,变量cs)
set "head=3C0000000100000003000000FF000000"
set "regp="HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Connections""
set "pbkp=%ALLUSERSPROFILE%\Application Data\Microsoft\Network\Connections\Pbk"
call :input
call :binary 0
echo %head% %hex%x
reg add %regp% /v %name% /t REG_BINARY /d %head%%hex% /f
pause
goto :eof
:input
for /f "delims=[]" %%i in ('findstr /b /e \[.*\] "%pbkp%\rasphone.pbk"') do (
set/a num+=1
set Connections!num!=%%i
echo !num!.%%i
)
set/p name=选择宽带连接:
if not defined Connections%name% goto input
set name=!Connections%name%!
set/p ip=代理服务器地址IP Address OR Domain Name:
echo %ip%|findstr /b /e [1-9][0-9]*\.[0-9]*\.[0-9]*\.[0-9]*||call :toip||cls&&goto input
set/p port=端口Port:
set ip=%ip%:%port%
echo %ip%|findstr /b /e [1-9][0-9]*\.[0-9]*\.[0-9]*\.[0-9]*\:[0-9]*||cls&&goto input
goto :eof
:binary
set var=!ip:~%cs%,1!||set hex=%hex:.=2E%&& set hex=!hex::=3A!&&goto :eof
if %var%. GEQ 0 set /a var+=30
set hex=%hex%%var%
set /a cs+=1
call :binary %cs%
goto :eof
:toip 
for /f "tokens=2 delims=[]" %%i in ('ping %ip%  /n 1^|findstr \[.*\]') do set ip=%%i
:if not errorlevel 0 goto :eof
goto :eof
复制代码

[ 本帖最后由 everest79 于 2009-5-4 00:51 编辑 ]

sexfio

楼上的高手，请问代理IP和端口号要放在你的代码的那一行呀
我是复制党，找了半天看不明白呀，麻烦说明 谢谢

everest79

@echo off
setlocal enabledelayedexpansion
::3c标 01计数器  03(01)是(否)启用代理 FF行偏移量&h10(ip+prot字符串长度,变量cs)
set "head=3C0000000100000003000000FF000000"
set "regp="HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Connections""
set ip=1.1.1.1:80
::上边设置代理IP与端口
set name=ADSL
::上边设置宽连接名称

call :binary 0
reg add %regp% /v %name% /t REG_BINARY /d %head%%hex% /f
pause
goto :eof

:binary
set var=!ip:~%cs%,1!||set hex=%hex:.=2E%&& set hex=!hex::=3A!&&goto :eof
if %var%. GEQ 0 set /a var+=30
set hex=%hex%%var%
set /a cs+=1
call :binary %cs%
goto :eof
复制代码

sexfio

谢谢楼上的，你的14楼的代码可以用呀，呵呵！
不过问下你12楼发的那是什么代码呀，运行后提示1或2，1那里是乱码，看不清是写的啥，2写的是VPN
我1和2都选过，然后填了IP和port,可结果貌似什么都没出现，就给我返回几个长串数字
能说下怎么用嘛？还有我运行了没什么反应不会有事吧