[文本处理] 批处理怎样将电话号码每200个整理为一个文本文件？

wany_cao

各位大侠好,我在论坛找到如下这段代码：

@echo off
(for /f "delims=" %%a in (某市某类人电话号码.txt) do (
    set /p =%%a;<nul
))>2.txt
复制代码

是将一个TXT文件中的每行排列一个电话号码更改为不再换行，每行后面加一个分号；
电话号码数字固定为11个数字，加分号一共12个字符
现想将输出内容整理为每200个电话号码为一个TXT文件，
命名方式为200(1).txt，200(2).txt，200(3).txt……以此类推；
请教各如如何可以实现以上结果。

[ 本帖最后由 wany_cao 于 2011-2-27 13:56 编辑 ]

随风

如果你的源文件都是一行的话，估计已经超过变量的最大上限8192字符，纯批无法处理了。

wany_cao

十分无耻的再次请求各位前辈指教#55555555
座等结果

weichenxiehou

@echo off&setlocal enabledelayedexpansion
set n=
set m=1
for /f "delims=" %%i in (某市某类人电话号码.txt) do (
        set /a n+=1
        if !n! equ 201 set /a n=0,m+=1
        set /p=%%i;<nul 1>>"200(!m!).txt"
)
复制代码

前提是要把这个批处理文件放到"某市某类人电话号码.txt"相同的文件夹下。生成的文本文件还是只有一行内容哦，号码间以分号分隔。

[ 本帖最后由 weichenxiehou 于 2011-2-27 16:16 编辑 ]

wany_cao

谢谢2楼提醒，我的原文件每行一个电话号码，少的一两千条，多的七八千甚至上万条；因此需要每200个整理为一个另外的TXT

随风

源文件每行一个电话号码

@echo off&setlocal enabledelayedexpansion
md temp
set /a m=1
for /f "delims=" %%i in (a.txt) do (
   set /a n=n%%200+1
   echo %%i>>temp\200^(!m!^).txt
   set /a m+="^!(n%%3^)"
)
start "" "temp"
复制代码

cjiabing

搞不懂为什么 %1 不成功？？

@echo off&setlocal enabledelayedexpansion
set /p wj=请输入文件：
echo 拖入文本文件为：%1&pause
echo waiting...
set m=1
set q=0
:a
set /a m+=1
set /a p=%q%+200
for /f "tokens=1,* delims=:" %%a in ('findstr /n .* %wj%^|^|exit') do (if %%a geq %q% if %%a leq %p% echo %%b>>%m%.txt)
set /a q+=200
if exist %m%.txt goto a
echo OK
pause
复制代码

terse

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in (a.txt) do (
   set /a m=n/200+1,n+=1
   >>"200(!m!).txt" echo %%i
)
pause
复制代码

CrLf

所有的号码都在一行时的笨办法：

for /l %%i in (1 1 100) do (
set /a n+=1,m=n/8+1
for /f "eol= tokens=1-25* delims=;" %%a in (all.txt) do (
(for %%z in (a b c d e f g h i j k l m n o p q r s t u v w x y) do echo;%%z)>!m!.txt
>all.txt echo;%%z
))
set /p all=<all.txt
if defined all %0
复制代码

[ 本帖最后由 zm900612 于 2011-2-27 18:50 编辑 ]