[系统相关] 绿坝-花季护航批处理绿色版（无需重启即装即用即删）

fastslz

工业和信息化部下发《关于计算机预装绿色上网过滤软件的通知》，要求2009年7月1日之后，在我国销售的所有个人电脑出厂时预装一款名为“绿坝·花季护航”的绿色上网过滤软件。此次绿色上网过滤软件采购采用的是竞争性谈判，使用中央财政资金购买，成交价为4170万元一年使用权及相关服务采购。

关于绿坝的是非、功能、效果、及敏感话题我们一概不讨论。
关于绿坝-花季护航软件技术分析看如下链接
http://www.douban.com/group/topic/6900726/

本来是挑战绿坝-花季护航清理代码的，没想到赢政天下如此之快在6月12日已经完成此代码，现在就挑战将其绿化吧。

fastslz

因为软件的特殊性不提供打包下载，请先安装后运行代码！！
LuBa安装.bat

@echo off
ver|find "98" >nul
if errorlevel 0 if not errorlevel 1 exit
md LuBaExec 2>nul
if not exist .\LuBaExec\xstring.s2g (echo/因为软件的特殊性不提供打包下载，请先安装后运行代码！&pause&exit)
if not exist LuBaList.txt (
   cd.>LuBaList.txt
   for /f "tokens=1,2 delims==," %%i in ('type .\LuBaExec\xstring.s2g') do (
       if /i "%%i"=="File" (
          SetLocal EnableDelayedExpansion
          set "var=%%j"
          set "var=!var:%%WinDir%%=%WinDir%!"
          set "var=!var:%%WinSysDir%%=%WinDir%\System32!"
          >>LuBaList.txt echo/!var!
          EndLocal)
   )
)
md %windir%\snap 2>nul
md %windir%\scrsnap 2>nul
md %windir%\HNCLIB 2>nul
md %windir%\images 2>nul
md %windir%\drivrs 2>nul
md %windir%\log 2>nul
md %windir%\system32\images 2>nul
md %windir%\system32\sysdir 2>nul&<nul set /p =^>
for /f "delims=" %%i in (LuBaList.txt) do (
    if exist ".\LuBaExec\%%~nxi" (xcopy /a/r/h/y ".\LuBaExec\%%~nxi" "%%~dpi" >nul 2>nul&<nul set /p =^>)
)
cls
goldlock.exe -i&<nul set /p =^>
regsvr32.exe /s %windir%\MPSvcPS.dll&<nul set /p =^>
MPSvcC.exe -installjh
ver|find /i " 6.">nul&&(regedit /s .\LuBaExec\winvista.reg&&<nul set /p =^>)
ver|find /i " 5.2">nul&&(regedit /s .\LuBaExec\winxpSpi.reg&&<nul set /p =^>)
ver|find /i " 5.1">nul&&(regedit /s .\LuBaExec\winxpSpi.reg&&<nul set /p =^>)
ver|find /i " 5.0">nul&&(regedit /s .\LuBaExec\win2kspi.reg&&<nul set /p =^>)
hnceng.exe -install
regsvr32.exe /s %windir%\hncengps.dll&<nul set /p =^>
net start MsPowerSvc >nul 2>nul&<nul set /p =^>
net start 280D4C48-4FA2-4274-ACEC-1582EFA5DA7D >nul 2>nul&<nul set /p =^>
netsh firewall add allowedprogram %windir%\system32\xnet2.exe 绿坝花季护航  enable >nul 2>nul&<nul set /p =^>
netsh firewall add allowedprogram %windir%\system32\XDaemon.exe  绿坝花季护航服务  enable >nul 2>nul&<nul set /p =^>
call start "" Xdaemon.exe&<nul set /p =^>
call start "" Msg %UserName% /Time:5 "          绿坝-花季护航已安装..."
复制代码

LuBa卸载.bat

@echo off
ver|find "98" >nul
if errorlevel 0 if not errorlevel 1 exit
md LuBaExec 2>nul
if not exist %WinDir%\xstring.s2g (echo/因为软件的特殊性不提供打包下载，请先安装后运行代码！&pause&exit)
if not exist LuBaList.txt (
   cd.>LuBaList.txt
   for /f "tokens=1,2 delims==," %%i in ('type %WinDir%\xstring.s2g') do (
       if /i "%%i"=="File" (
          SetLocal EnableDelayedExpansion
          set "var=%%j"
          set "var=!var:%%WinDir%%=%WinDir%!"
          set "var=!var:%%WinSysDir%%=%WinDir%\System32!"
          >>LuBaList.txt echo/!var!
          EndLocal)
   )
)
<nul set /p =^>
if exist %windir%\MPSvcC.exe MPSvcC.exe -removejh
<nul set /p =^>
if exist %windir%\hnceng.exe hnceng.exe -remove
taskkill /im XNet2.exe /f >nul 2>nul&<nul set /p =^>
taskkill /im XDaemon.exe /f >nul 2>nul&<nul set /p =^>
taskkill /im gn.exe /f >nul 2>nul&<nul set /p =^>
regsvr32.exe /u /s %windir%\hncengps.dll&<nul set /p =^>
regsvr32.exe /u /s %windir%\MPSvcPS.dll&<nul set /p =^>
reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run" /v "Xnet2" /f >nul 2>nul&<nul set /p =^>
cls
for /f "delims=" %%i in (LuBaList.txt) do (
    if not exist ".\LuBaExec\%%~nxi" (if exist "%%i" xcopy /a/r/h/y "%%i" .\LuBaExec >nul)
    if exist "%%i" del /a/f/q "%%i" >nul 2>nul&<nul set /p =^>
)
rd /q/s %windir%\snap 2>nul
rd /q/s %windir%\scrsnap 2>nul
rd /q/s %windir%\HNCLIB 2>nul
rd /q/s %windir%\images 2>nul
rd /q/s %windir%\drivrs 2>nul
rd /q/s %windir%\log 2>nul
rd %windir%\system32\images 2>nul
rd %windir%\system32\sysdir 2>nul&<nul set /p =^>
netsh firewall delete allowedprogram %windir%\system32\xnet2.exe >nul 2>nul&<nul set /p =^>
netsh firewall delete allowedprogram %windir%\system32\XDaemon.exe >nul 2>nul&<nul set /p =^>
call start "" Msg %UserName% /Time:5 "         绿坝-花季护航已卸载. . ."
复制代码

keen

本站已经人转贴了：

http://www.bathome.net/viewthread ... hlight=%BB%A4%BA%BD

fastslz

代码测试有效（比我想象中更不堪一击）
结论：如此“绿坝”并不“霸”

fastslz

残废绿坝其实很简单（自带移除参数能移除注册表项）

MPSvcC.exe -removejh
hnceng.exe -remove
复制代码

安装后关闭端口（降低隐私风险）

netsh firewall delete allowedprogram %windir%\system32\xnet2.exe
netsh firewall delete allowedprogram %windir%\system32\XDaemon.exe
复制代码