[文本处理] [已解决]如何写 批量替换指定的文件的文字？

ik22

哥们，你们好！  
   有一个文本a.txt   里面列出了一批html文件的路径 如:
D:\www\2010\1230\372.html
E:\www\2010\1120\211.html
G:\www\2010\1123\83.html
D:\www\2010\0130\1265.html
D:\www\2010\0230\22073.html
.................

另一个文件 b.txt 写了一些关键字，每行一个(大概上百个吧)。

现在我想写个批处理，能够把b.txt里面所说的关键字从a.txt里面的文件中批量替换为***        请问怎么写比较好？

小弟先谢谢了..

 
@echo off
(for /f "usebackq delims=" %%a in ("b.txt") do (
    set /p =""%%a" "<nul
)) >.tmp
set /p KeywordList=<.tmp

for /f "usebackq tokens=*" %%f in ("a.txt") do (
    findstr /n .* "%%f" >.tmp
    (for /f "tokens=*" %%a in (.tmp) do (
        set var=%%a
        SetLocal EnableDelayedExpansion
        for %%w in (!KeywordList!) do set var=!var:%%~w=***!
        echo,!var:*:=!
        EndLocal
    )) >"%%f"
)

del .tmp
echo 完成！按任意键退出...
pause >nul
复制代码

[ 本帖最后由 ik22 于 2011-1-16 19:50 编辑 ]

yhcbird

楼下的强大。。。。。。

[ 本帖最后由 yhcbird 于 2011-1-16 20:31 编辑 ]

tmplinshi

@echo off
(for /f "usebackq delims=" %%a in ("b.txt") do (
    set /p =""%%a" "<nul
)) >.tmp
set /p KeywordList=<.tmp

for /f "usebackq tokens=*" %%f in ("a.txt") do (
    findstr /n .* "%%f" >.tmp
    (for /f "tokens=*" %%a in (.tmp) do (
        set var=%%a
        SetLocal EnableDelayedExpansion
        for %%w in (!KeywordList!) do set var=!var:%%~w=***!
        echo,!var:*:=!
        EndLocal
    )) >"%%f"
)

del .tmp
echo 完成！按任意键退出...
pause >nul
复制代码

ik22

谢谢  tmplinshi 版主..