[文件操作] 求助，打开bat后有几个选项根据选项更改文件的某一行，之后重启某个进程

三世三繁锦

就是打开bat后有几个数字选项，1更改ip为xxxx 2更改ip为xxxx 3更改ip为xxxx
文件的位置在C:\MFPC_Client\MFPC_Client.ini
文件内容为：

[Setting]
PublicComputer=0
ServerIP=x.x.x.x
复制代码

这里的x.x.x.x 每个部门的不一样，所以得改这一行的内容，
然后改完之后自动重启MFPC_Client.exe这个进程（这个我倒是知道）

@echo off
@tasklist|find "MFPC_Client.exe"
@if %errorlevel%==0 taskkill.exe /IM MFPC_Client.exe /t /f
@start C:\MFPC_Client\MFPC_Client.exe
@exit
复制代码

求助各位大神~~~

zaqmlp

@echo off
set info=互助互利,支付宝扫码头像,感谢打赏
rem 有问题,可加QQ956535081及时沟通
title %info%
:input
for %%a in (
    "1=192.168.1.1"
    "2=192.168.1.55"
    "3=192.168.1.66"
) do (
    set "#%%~a"
    for /f "tokens=1* delims==" %%b in (%%a) do echo;%%b、更改ip为%%c
)

set "c="
set /p c=输入数字序号:
set "inifile=C:\MFPC_Client\MFPC_Client.ini"

if not defined #%c% (echo;input error&goto end)
if not exist "%inifile%" (echo;"%inifile%" not found&goto end)

(for /f "delims=" %%a in ('type "%inifile%"') do (
    set "line=%%a"
    setlocal enabledelayedexpansion
    if /i "!line:~,9!" equ "ServerIP=" (
        echo;ServerIP=!#%c%!
    ) else echo;!line!
    endlocal
))>"%tmp%\t.t"

move "%tmp%\t.t" "%inifile%"

call echo;%%#%c%%%
taskkill /im MFPC_Client.exe /t /f
start "" "C:\MFPC_Client\MFPC_Client.exe"
:end
echo;%info%
pause
复制代码