【练习-017】批处理根据输入值进行数值计算

batman

出题目的：
        掌握数值计算
解题要求：
        代码通用、高效
        尽量简洁
        不生成临时文件
加分规则：
        1 新手完成前六个步骤的加分10分
　　 2 新手完成前七个步骤的加分15分
　　 3 老手完成第七个步骤的加分10分
　　 4 老手完成第七、第八步骤的加分15分
题目如下：
　　通过批处理实现如下操作（要求适应于1－9的输入数）

解题限制：
　　请老手不要写出前六个步骤的代码（不要求老手完成）
　　高手只需完成第八个步骤
-------------------------------------------------------------------------
螺旋矩阵的解见：18楼我的解和19楼terse的解

lengmoke

@echo off
setlocal EnableDelayedExpansion
set /a length=20 & set /a width=23
set /a max=length*width
call :len %max% maxlength
set /a i=1 & set /a j=1 & set /a idelta=0 & set /a jdelta=1 & set /a imax=length & set /a jmax=width & set /a count=0 & set /a imin=2 & set /a jmin=1
:setvalue
    set /a count+=1
    call :loop temp %count% %maxlength%
    set matrix[%i%][%j%]=%temp%
    if "%idelta%,%jdelta%"=="0,1" ( if %j%==%jmax% ( set /a idelta=1 & set /a jdelta=0 & set /a jmax-=1 ))
    if "%idelta%,%jdelta%"=="1,0" ( if %i%==%imax% ( set /a idelta=0 & set /a jdelta=-1 & set /a imax-=1))
    if "%idelta%,%jdelta%"=="0,-1" ( if %j%==%jmin% ( set /a idelta=-1 & set /a jdelta=0 & set /a jmin+=1))
    if "%idelta%,%jdelta%"=="-1,0" ( if %i%==%imin% ( set /a idelta=0 & set /a jdelta=1 & set /a imin+=1))
    set /a i+=idelta & set /a j+=jdelta
    if %count% lss %max% ( 
        goto:setvalue
    )
for /l %%i in (1,1,%length%) do (
    set str=!matrix[%%i][1]!
    for /l %%j in (2,1,%width%) do ( set "str=!str! !matrix[%%i][%%j]!" )
    echo !str!
)
exit

:loop
   set number=         %2
   set %1=!number:~-%3!
goto :eof

:len
   set Tempstrs=%~1 & Set Tempnum=0
   :下一位
      set Tempstr=!Tempstrs:~%Tempnum%,1!
      if defined Tempstr ( set /a Tempnum+=1 & goto :下一位 )
      set /a %~2=%Tempnum%-1
goto :eof
复制代码

437153

求点评~~~
1-6：

@echo off&setlocal enabledelayedexpansion
set /p "p=请输入要操作的数（1-9）："
set j=1
for /l %%a in (1,1,%p%) do (
	set /a p2=%%a*%%a
	set /a p3=%%a*%%a*%%a
	set /a h=!h!+%%a
	set /a j=%%a*!j!
	set /a ph=!ph!+!p2!
	set /a lh=!lh!+!p3!
)
echo %p%的平方：%p2%
echo %p%的立方：%p3%
echo 从1到%p%的和：%h%
echo 从1到%p%的积：%j%
echo 从1到%p%的平方和：%ph%
echo 从1到%p%的立方和：%lh%
复制代码

数列：

@echo off&setlocal enabledelayedexpansion
set /p "p=请输入要操作的数（1-9）："
for /l %%a in (1,1,%p%) do (
	for /l %%i in (1,1,%p%) do (
		set /a n+=1
		set /p=!n!	<nul
	)
	echo;
)
复制代码

螺纹:

@echo off&setlocal enabledelayedexpansion
set /p p=输入：
set /a x=1,num=%p%,sum=%p%*%p%
set yuns=--
for /l %%y in (1,1,%num%) do (set/a n+=1,y+=1&set _%x%_%%y=!n!)
:lp
set /a num-=1
for /l %%a in (1,1,%num%) do (set/a n+=1,x=!x!%yuns%1&set _!x!_!y!=!n!)
set yuns=-%yuns%
for /l %%a in (1,1,%num%) do (set/a n+=1,y=!y!%yuns%1,ys+=1&set _!x!_!y!=!n!)
if not %n% equ %sum% goto :lp
for /l %%a in (1,1,%p%) do (
	for /l %%b in (1,1,%p%) do (
		set /p=!_%%a_%%b!	<nul
	)
	echo;
)
复制代码

asd821089612

第一到第六题。

@echo off
set /p no=请输入想要操作的数  (1-9) :
set /a no1=%no%*%no%
set /a no2=%no%*%no%*%no%
for /l %%i in (1 1 %no%) do (set /a no3+=%%i)
set no4=1
for /l %%i in (1 1 %no%) do (set /a no4*=%%i)
for /l %%i in (1 1 %no%) do (set /a no5+=%%i*%%i)
for /l %%i in (1 1 %no%) do (set /a no6+=%%i*%%i*%%i)
echo %no%的平方为：%no1%
echo %no%的立方为：%no2%
echo 1到%no%的和为：%no3%
echo 1到%no%的积为：%no4%
echo 1到%no%的平方和为：%no5%
echo 1到%no%的立方和为：%no6%
pause>nul
复制代码

Hello123World

第7题格式上有点问题：

@echo off&Setlocal EnableDelayedExpansion
For /l %%i in (1 1 16) do (Set a=%%i
Set /p =!a! <nul
Set /a b=!a!%%4
If !b!==0 Echo\) 
pause
复制代码

Hello123World

1# batman
1-6题：

@echo off & setlocal enabledelayedexpansion
Set /p a=请输入要操作的数（1-9）：
Set /a b=%a%*%a%
Set /a c=%a%*%a%*%a%
Set e=1
For /l %%i in (1 1 %a%) do (Set /a d+=%%i & Set /a e*=%%i 
Set f=%%i & Set /a f*=!f! & Set /a g+=!f!
Set f=%%i
Set /a h=!f!*!f!*!f! & Set /a m+=!h!
)
Echo %a%的平方：%b%
Echo %a%的立方：%c%
Echo 1到%a%的和：%d%
Echo 1到%a%的积：%e%
Echo 1到%a%的平方和：%g%
Echo 1到%a%的立方和：%m%
pause
复制代码

hanyeguxing

使用对角分割解螺旋方阵：

@echo off
:s
setlocal enabledelayedexpansion&cls
set/p n=输入阶数:
if %n% gtr 46340 goto:s
set/a k=n*n&set k= !k!
for /l %%a in (1,1,11) do if not "!k:~%%a,1!"=="" set q=%%a&set "s=!s! "
for /l %%a in (1,1,%n%) do (
        for /l %%b in (1,1,%n%) do (
                set/a k=n+1-%%a
                if %%b geq %%a if %%b leq !k! set/a "p=4*(n-%%a)*%%a-4*n+7*%%a+%%b-3"
                if %%b leq %%a if %%b gtr !k! set/a "p=4*(n-%%a)*%%a-2*n+5*%%a-%%b-1"
                if %%b gtr %%a if %%b gtr !k! set/a "p=4*(n-%%b)*%%b-2*n+%%a+3*%%b-1"
                if %%b lss %%a if %%b leq !k! set/a "p=4*(n-%%b)*%%b-%%a+%%b+1"
                set p=%s%!p!&set/p"=!p:~-%q%! "<nul
        )
        echo;
)
pause&endlocal&goto:s
复制代码

JS版：

<script>
hy(20);
function hy( n)
{ var i,j; 
document.write("<body bgcolor=#008000><center><table border=1 bgcolor=#B0E2FF bordercolor=#fff000> ");
for(i=1;i<=n;i++){document.write("<tr>");
for(j=1;j<=n;j++){
var Han=4*(n-i)*i-4*n+7*i+j-3;
var Ye=4*(n-j)*j-2*n+i+3*j-1;
var Gu=4*(n-i)*i-2*n+5*i-j-1;
var Xing=4*(n-j)*j+-i+j+1;
document.write("<td>"+((i<=j&&i+j<=n+1)?Han:(i<j&&i+j>n+1)?Ye:(i>=j&&i+j>n+1)?Gu:Xing)+"</td>");} document.write("</tr>");}
document.write("</table> ");
}
</script>
复制代码

[ 本帖最后由 hanyeguxing 于 2011-2-8 11:15 编辑 ]

netbenton

@echo off&Setlocal EnableDelayedExpansion
Set /p k=19内阶数:
Set /a all=k*k,t1=1,h1=1,sk=k,ck=k,m=1,n=1,x=0,y=1,a=1

set str1=n sk 1 0 t1 1
set str2=m ck 0 -1 sk -1
set str3=n h1 -1 0 ck -1
set str0=m t1 0 1 h1 1

for /l %%a in (1,1,!all!) do (
        set #!m!.!n!=%%a
        set/a m+=x,n+=y
        for %%b in (!a!) do (
                for /f "tokens=1-6" %%c in ("!str%%b!") do (
                        if !%%c! equ !%%d! set/a x=%%e,y=%%f,%%g+=%%h,a+=1,a=a%%4
)        )        )

for /l %%a in (1,1,!k!) do (
        set str=
        for /l %%b in (1,1,!k!) do (set one=   !#%%a.%%b!&set str=!str!!one:~-4!)
        echo !str!
)
pause

keen

看了19楼的代码，原来是通过定位坐标的方式，形成螺旋阵列。

我知道还有通过坐标定位的另一种方式，只是不知道，具体怎么写。

坐标定位，好像是：
1-1 1-2 1-3 1-4
2-1 2-2 2-3 2-4

继续学习，继续研究！

keen

既然设定整个代码不断循环，就要把tempnum在下一次循环时，清零。要么就不要进行循环。

xmaoh234

pp 是立方，你写的是平方。。。。。

keen

第7题：

@echo off&setlocal enabledelayedexpansion
set /p num=请输入要操作的数，范围是1-9：
echo\&echo %num%行%num%列数列：
for /l %%i in (1 1 %num%) do (
    for /l %%j in (1 1 %num%) do (
         set /a sum7+=1&set sum7= !sum7!&set /p=!sum7:~-2! <nul
)
echo\
)
echo\&pause
复制代码

keen

1-6：

@echo off
set /p num=请输入要操作的数，范围是1-9：
set sum4=1
for /l %%i in (1 1 %num%) do (
     set /a sum1=%%i*%%i,sum2=sum1*%%i,sum3+=%%i,sum4*=%%i,sum5+=sum1,sum6+=sum2
)
echo\
echo %num%的平方是：%sum1%
echo %num%的立方是：%sum2%
echo 从1到%num%的和：%sum3%
echo 从1到%num%的积：%sum4%
echo 从1到%num%的平方和：%sum5%
echo 从1到%num%的立方和：%sum6%
echo\&pause
复制代码

everest79

骗分

@echo off&Setlocal EnableDelayedExpansion
Set /p N=num:
Set /a ALL=N*N,w=0,h=w,s=h,c=s,l=n-1
For /l %%a in (1,1,%all%) Do (Set _o!h!!w!=%%a
if !c! EQU 0 (call :c w + GEQ 1 "l-s") else  if !c! EQU 1 (call :c h + GEQ 2 "l-s"
) else if !c! EQU 2 (call :c w - LEQ 3 "s") else  if !c! EQU 3 call :c h - LEQ "0,s+=1" "s+1")
for /f "tokens=1,2 delims==" %%a in ('set _o^|sort') do (
Set/P=%%b	<nul&Set /a count+=1,1/^(count%%%N%^)2>nul||echo.)
pause >nul&goto :eof
:c
Set /a %1%2=1,tmp=%~5
if !%1! %3 %tmp% Set /a %1=tmp,c=%~4
goto :eof
复制代码

shqf

代码竟是如此短啊！可怜我还是难以理解其精妙之处。除了佩服，只剩穷顶。

[ 本帖最后由 shqf 于 2008-8-29 08:22 编辑 ]