[数值计算] 批处理生成100个不重复的随机数

xxx3212

设置100个变量 n1 - n100 每个变量的值为一个1-100的随机数 没有一个重复
查看是否有重复代码

for /l %%a in (1,1,100) do (
 set error=0
 for /l %%b in (1,1,100) do (
  if not %%a==%%b if !n%%a!==!n%%b! set error=1
  if !error!==1 echo %%a和%%b重复!
  )
 )
复制代码

liuchong.net

先排序，然后检测相邻的数字是否相同不就得了？

dahual

@echo off & setlocal enabledelayedexpansion
for /l %%a in (1,1,100) do set ".!random!-%%a=%%a"
for /f "tokens=2 delims==" %%a in ('set .') do set /p=%%a<nul & echo.
pause>nul
复制代码

看来的，请大家给解释下，谢谢。

netbenton

@echo off & setlocal enabledelayedexpansion
for /l %%i in (1 1 100) do set num%%i=%%i
for /l %%i in (100 -1 1) do (
    set /a rnd=!random!%%%%i+1,n+=1
    for %%a in (!rnd!) do echo !n!=!num%%a!&set/a num!rnd!=num%%i
)
pause>nul
复制代码

youxi01

哦?
他没要求变量名不能等于 其对应的值  吧?!

随风

测试youxi　18楼更新后的代码，出现重复现象，见附件。
代码仍未十分看懂，就象绕口令，绕的我有点头晕，暂时不知道出错原因，有空再研究。
错误应该是随机数，随机数重复时应该会出错。
测试代码如下：
:

@echo off & setlocal enabledelayedexpansion
for /l %%i in (1 1 100) do set num%%i=%%i
for /l %%i in (1 1 100) do (
    set /a rnd=100!random:~-2!%%100+1,var=!num%%i!
    call set num%%i=%%num!rnd!%%
    set num!rnd!=!var!
)
for /l %%i in (1 1 100) do if "%%i"=="!num%%i!" echo %%i=!num%%i!
pause 
复制代码

[attach]72[/attach]

youxi01

观察17F的代码，思路其实和if defined差不多，基本原理是检测
z%n%是否已经被 赋值 为1，如果是则说明已经重复...，然后goto（呵呵，不知道说的对不对）
个人觉得，这种办法效率会较低，数值越多，效率越低（因为数值越多，重复的可能性越多）...

youxi01

呵呵，这句出了点问题（可能为0）
set /a rnd=100!random:~-2!%%100,var=!num%%i!

改成：
set /a rnd=100!random:~-2!%%100+1,var=!num%%i!
即可！！
18F已更新！！

foxJL

楼上厉害呀.不用一个IF,
不过刚才测试了一下会出现值为空的情况,不知道是什么原因.

youxi01

呵呵，工作做完了，也贴一段玩玩（其实是原来写的那个10位数的，稍做修改）

@echo off & setlocal enabledelayedexpansion
for /l %%i in (1 1 100) do set num%%i=%%i
for /l %%i in (1 1 100) do (
    set /a rnd=100!random:~-2!%%100+1,var=!num%%i!
    call set num%%i=%%num!rnd!%%
    set num!rnd!=!var!
)
for /l %%i in (1 1 100) do echo %%i=!num%%i!
pause>nul
复制代码

foxJL

变量名和值各不重复且值1-100之间不重复
大家测试看看代码有没有问题

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1,1,100) do (call :ran %%i&echo %%i=!%%i!)
pause>nul&exit
:ran
set /a n=%random% %% 101
if %n% equ 0 (goto ran) else (
        if !z%n%! equ 0 (
                if %n% equ %1 (goto ran) else (
                set %1=%n%&set /a z%n%+=1
                )
        ) else (goto ran)
)
goto :eof
复制代码

[ 本帖最后由 foxJL 于 2008-1-16 09:59 编辑 ]

xxx3212

行:43
字符:5
错误:缺少对象

xxx3212

版主怎么不把主页里的错误修补 我早就提过了的

xxx3212

主页有错误 对象不可用

youxi01

完全正确...
我当初写 那个 10位数的时候采取的就是这种思想
让它们随机交换数据,呵呵...