[原创] 批处理命令set截取字符详解

namejm

　　在批处理中，set的功能有点繁杂：设置变量、显示环境变量的名及值、做算术运算、等待用户的输入、字符串截取、替换字符串，是我们常用的命令之一。

　　在字符串截取方面，新手因为没能注意到偏移量的问题，很容易提取到错误的字符串，因此，特开此帖，详细解释 set 截取字符的用法。

　　我们先来看一个例子：

　　set str=123456789

　　现在，我需要提取变量 str 中的第一个字符，那么，该怎么写命令呢？

　　set var=%str:~1,1%？我想，这很可能是很多粗懂set用法的新手们的第一反应，实际上，这条语句提取到的是字符"2"，并不是我们想要的"1"，也就是说，set var=%str:~1,1% 提取到的是字符串第二位上的字符，而不是第一位上的，这是什么原因呢？

　　原来，set 命令从左到右做字符截取的时候，是以整个字符串的第一个字符为起点来计算要截取字符的偏移量的，也就是说，截取字符的时候，set 会计算提取后字符串的第一个字符相对于整个字符串第一个字符偏移了多少字符的长度。请注意，set 是按偏移量而不是字符的绝对位置来提取字符的，这一点非常重要。只要牢记这一点，大家在截取字符的时候，将会不再在这个问题上犯错。

　　现在，我们可以把截取字符的命令用一条语句模式来表示，那就是：set var=%str:~偏移量,长度%。

　　我们来详细解读这条语句模式的含义：

　　首先，我们需要把要操作的字符串赋予一个变量，在这条语句中，是把字符串赋予了变量 str ；然后，我们需要确定一下我们想提取的字符串是哪一部分，比如说要提取字符串第2个字符及其之后的3个字符，或是提取字符串第5个字符及其之后的4个字符……，最后，计算偏移量及长度，比如要提取字符串第2个字符及其之后的3个字符，那么，也就是提取相对于第一个字符偏移量为1、提取后的字符串长度为4的字符串，写成语句就是：set var=%str:~1,4%。

　　到目前为止，我们只谈到了很简单的截取操作，如果碰到比较复杂的提取需求，比如：提取第2个字符及其之后的所有字符、提取最后的3个字符、提取倒数第2个及其之前的3个字符、提取除了最后4个字符的字符串……那又该怎么办呢？别着急，set 命令在设计的时候就已经充分考虑到我们的复杂需求，只要对刚才我们提到的字符截取语句稍做改动，就可以很轻松地完成任务。

　　我们知道，数字的正负可以用+-符号来表示，同样的，方向的正反也可以用+-来标注。在 set 做字符截取的时候，引入了+-符号来表示字符截取的方向：从左到右截取为+，从右到左截取为-，所以，set var=%str:~1,4% 也可以写成 set var=%str:~+1,+4% ，只是在从右到左截取的时候，情况发生了一点变化，那就是：偏移量的起点以整个字符串最后一个字符的后一位来计算。现在，我们可以来回答上一段中提出的一些问题：

　　提取最后的3个字符：set var=%str:~-3%
　　提取倒数第2个及其之前的3个字符：set var=%str:~-5,4%
　　提取除了最后4个字符的字符串：set var=%str:~0,-4%

　　看了上面三种需求的代码，大家可能又会产生新的疑问：第一条怎么只有一个数字啊？第三条最后一个数字是负号，又表示什么意思呢？

　　原来，在 set var=%str:~偏移量,长度% 这样的语句中，如果没有逗号及其之后的长度，就表示截取偏移量位置上及其之后的所有字符，如果长度的值为负数，则表示抛弃最后几个字符。

　　现在，我们可以对任意位置上的字符做提取工作了(假设 set str=123456789)：

　　① 提取1: set var=%str:~0,1% 或 set var=%str:~0,-8% 或 set var=%str:~-9,1%
　　② 提取2: set var=%str:~1,1% 或 set var=%str:~1,-7% 或 set var=%str:~-8,1%
　　③ 提取9: set var=%str:~8,1% 或 set var=%str:~8% 或 set var=%str:~-1,1% 或 set var=%str:~-1%
　　④ 提取123：set var=%str:~0,3% 或 set var=%str:~0,-6% 或 set var=%str:~-9,3%
　　⑤ 提取234：set var=%str:~1,3% 或 set var=%str:~1,-5% 或 set var=%str:~-8,3%
　　⑥ 提取789：set var=%str:~6,3% 或 set var=%str:~6% 或 set var=%str:~-3,3% 或 set var=%str:~-3%

　　最后，我们来总结一下字符截取的规律：

　　1、截取字符串可以用 set var=%str:~数值1,数值2% 这样的语句来实现；
　　2、字符的截取是以偏移量来计算的，而不是以字符的绝对位置来计算；
　　3、当数值1为正数时，表示从左到右截取；当数值1为负数时，表示从右到左截取；
　　4、当数值2为正数时，表示要截取后字符串的长度；当为负数时，表示要抛弃的最后几个字符长度；
　　5、当数值2及其之前的逗号不存在时，表示截取的是第（数值1+1）个字符及其之后的所有字符；

——————————————————
        感谢halili 指出了第⑤点中的错误；
　　感谢woxingwoshu007指出了第②点中的错误；

zxlagyyy

不能完全看懂。

pda8888

虽然我是新人一枚，也斗胆发表一下见解：
%var~:n,m%,
其中，n是指起始位置，m是指取多少个字符。
1、如果n是正数，则从左边开始数，起始位置是0，如果n是负数，则从字符尾部开始数。
2、如果m是正数，是从左往右计数，如果m是负数，是从右往左计数。
这样更易理解和记忆，不知说对了没有。
反正就是定义起始位置和取多少个字符，不涉及到保留和舍弃的复杂理解和记忆。

ANSL

谢谢楼主，学习了！

yyz219

我不是怎么看得明白

allyn

感谢 学到了

750795191

回复 36# craig_we


    那个输出是23吧？？

shelluserwlb

%VAR:~数值1，数值2%
1.  数值1无论正负都表示开始截取起始位置。
2.  数值2若为正数表示截取个数，若此值超过剩余字符数，则会截取剩余的全部字符。
     数值2若为负数表示截取结束位置。
3.  若缺少数值2和其前面的逗号，则表示截取从数值1所指的位置开始到最后一个字符为止。
4.  正数：从左到右数（从0开始算）    负数：从右到左数（从0开始算但不能为0）。

ezaohaha

你的教程总是这么朴实 易懂  可惜你的一日一教学成了断章 后续的虎头蛇尾

citear

请允许我补充一丢丢：

对于数值1和数值2 的取值范围关系

当两者为负数的时候  数值1要小于数值2 否者为无效吧

wabata118

不错哦，学习了

James_vivi

收下了这set 命令

changedirectory

多谢！！！感谢大神！

suseek

谢谢指正
ECHO OFF
setlocal enabledelayedexpansion
set var=1234567890
for /l %%i in (1,2,9) do (

echo !var:~%%i,1!
)






)


pause

DAIC

回复 58# suseek


    不正确，你亲自测试一下就知道了。